10 replies to this topic

[guinness]

If you set the Label background color with GUICtrlSetBkColor() and happen to forget the color you set it as, then why not try GUICtrlGetBkColor()

Note: Requires WinAPIEx.au3 to use GUICtrlGetBkColor().

To get the Hex value e.g. 00FF00 then use this little conversion >>

Local $iColor = GUICtrlGetBkColor($iLabel)
MsgBox(4096, '', 'The Hex value is...' & _ConvertToHexFormat($iColor))

Func _ConvertToHexFormat($bColor)
    Return Hex($bColor, 6)
EndFunc   ;==>_ConvertToHexFormat

Function:

; #FUNCTION# ====================================================================================================================
; Name ..........: GUICtrlGetBkColor
; Description ...: Retrieves the RGB value of the control background.
; Syntax ........: GUICtrlGetBkColor($hWnd)
; Parameters ....: $hWnd                - Control ID/Handle to the control
; Return values .: Success - RGB value
;                  Failure - 0
; Author ........: guinness
; Remarks .......: WinAPIEx is required.
; Example .......: Yes
; ===============================================================================================================================
Func GUICtrlGetBkColor($hWnd)
    If IsHWnd($hWnd) = 0 Then
        $hWnd = GUICtrlGetHandle($hWnd)
    EndIf
    Local $hDC = _WinAPI_GetDC($hWnd)
    Local $iColor = _WinAPI_GetPixel($hDC, 0, 0)
    _WinAPI_ReleaseDC($hWnd, $hDC)
    Return $iColor
EndFunc   ;==>GUICtrlGetBkColor

Example use of Function:

AutoIt        expandcollapse  popup

#include <WinAPIEx.au3> ; Required for _WinAPI_GetPixel()

#include 'GUICtrlGetBkColor.au3'

Example()

Func Example()
    Local $aColor[6] = [5, 0x0000FF, 0x8FFF9F, 0xEC4841, 0xB0E35D, 0x440BFD] ; Random Color Array.
    Local $iColor = 0

    Local $hGUI = GUICreate('GUICtrlGetBkColor() Example', 500, 350)
    Local $iLabel = GUICtrlCreateLabel('', 10, 10, 480, 330)
    GUISetState(@SW_SHOW, $hGUI)

    For $i = 1 To $aColor[0]
        GUICtrlSetBkColor($iLabel, $aColor[$i])
        Sleep(20)
        $iColor = GUICtrlGetBkColor($iLabel) ; Pass the Label ID to the Function.
        MsgBox(4096, '', 'Background Color: ' & _ConvertToHexFormat($aColor[$i]) & @CRLF & _
                'GUICtrlGetBkColor() Hex Format: ' & _ConvertToHexFormat($iColor) & @CRLF & _
                'GUICtrlGetBkColor() Returned: ' & $iColor, 0, $hGUI)
    Next
    GUIDelete($hGUI)
EndFunc   ;==>Example

Func _ConvertToHexFormat($bColor)
    Return Hex($bColor, 6)
EndFunc   ;==>_ConvertToHexFormat

Additional thanks to Yashied for pointing out the obvious in this forum message about _WinAPI_GetPixel() and the hint about returning a RGB number

Edited by guinness, 17 October 2012 - 08:09 PM.

[Aktonius]

you are awesome!

[guinness]

OK, well I'm flattered! But some of that flattery should go to Yashied as well

[Aktonius]

True, btw this function needs to be added to autoit by default

[guinness]

I think it's OK in the Example's Section.

[Aktonius]

don't be fake-modest guiness

[Liuzi]

Thank you!
It helped to me

[Liuzi]

It is great, but some small problems

If both of the controls set the color and background color

Then the function returns GUICtrlSetColor() not GUICtrlSetBkColor()

At this point can be modified:
$bGetBkColor = _WinAPI_GetPixel($hDC, 0, 0) ------------------> $bGetBkColor = _WinAPI_GetPixel($hDC, 1, 1)

[guinness]

But this is probably a rare occurrence?

[guinness]

I've updated the Examples and Code in GUIGetBkColor(), GUICtrlGetBkColor() & GUICtrlGetStyle(). Any comments or suggestions then please post below or in the respective threads. Thanks.

Edited by guinness, 19 June 2011 - 10:36 AM.

[guinness]

I've updated the example and function syntax. See above for more details. Thanks.