25 replies to this topic

[guinness]

A question by Xenobiologist was asked in the _SelfDelete() thread of whether or not I could create a function to update the running executable, so here is the _SelfUpdate function.

Function: Using a Batch script. Save as _SelfUpdate.au3

AutoIt        expandcollapse  popup

#include-once
#include <Constants.au3>

; #FUNCTION# ====================================================================================================================
; Name ..........: _SelfUpdate
; Description ...: Update the running executable with another executable.
; Syntax ........: _SelfUpdate($sUpdatePath[, $fRestart = False[, $iDelay = 5[, $fUsePID = False]]])
; Parameters ....: $sUpdatePath         - Path string of the update file to overwrite the running executable.
;                  $fRestart            - [optional] Restart the application (True) or to not restart (False) after overwriting. Default is False.
;                  $iDelay              - [optional] An integer value for the delay to wait (in seconds) before stopping the process and deleting the executable.
;                                         If 0 is specified then the batch will wait indefinitely until the process no longer exits. Default is 5 (seconds).
;                  $fUsePID             - [optional] Use the process name (False) or PID (True). Default is False.
;                  $fBackupPath         - [optional] Backup the filepath. Default is True.
; Return values .: Success - Returns the PID of the batch file.
;                  Failure - Returns 0 & sets @error to non-zero
; Author ........: guinness
; Modified ......:
; Remarks .......: The current executable is renamed to AppName_Backup.exe if $fBackupPath is set to True.
; Example .......: Yes
; ===============================================================================================================================
Func _SelfUpdate($sUpdatePath, $fRestart = Default, $iDelay = 5, $fUsePID = Default, $fBackupPath = Default)
    If @Compiled = 0 Or FileExists($sUpdatePath) = 0 Then
        Return SetError(1, 0, 0)
    EndIf

    Local $sTempFileName = @ScriptName
    $sTempFileName = StringLeft($sTempFileName, StringInStr($sTempFileName, '.', $STR_NOCASESENSEBASIC, -1) - 1)

    Local Const $sScriptPath = @ScriptFullPath
    Local $sBackupPath = ''
    If $fBackupPath Or $fBackupPath = Default Then
        $sBackupPath = 'MOVE /Y ' & '"' & $sScriptPath & '"' & ' "' & @ScriptDir & '\' & $sTempFileName & '_Backup.exe' & '"' & @CRLF
    EndIf

    While FileExists(@TempDir & '\' & $sTempFileName & '.bat')
        $sTempFileName &= Chr(Random(65, 122, 1))
    WEnd
    $sTempFileName = @TempDir & '\' & $sTempFileName & '.bat'

    If $iDelay = Default Then
        $iDelay = 5
    EndIf

    $iDelay = Int($iDelay)
    Local $sDelay = ''
    If $iDelay > 0 Then
        $sDelay = 'IF %TIMER% GTR ' & $iDelay & ' GOTO DELETE'
    EndIf

    Local $sAppID = @ScriptName, $sImageName = 'IMAGENAME'
    If $fUsePID Then
        $sAppID = @AutoItPID
        $sImageName = 'PID'
    EndIf

    Local $sRestart = ''
    If $fRestart Then
        $sRestart = 'START "" "' & $sScriptPath & '"'
    EndIf

    Local Const $iInternalDelay = 2
    Local Const $sData = 'SET TIMER=0' & @CRLF _
             & ':START' & @CRLF _
             & 'PING -n ' & $iInternalDelay & ' 127.0.0.1 > nul' & @CRLF _
             & $sDelay & @CRLF _
             & 'SET /A TIMER+=1' & @CRLF _
             & @CRLF _
             & 'TASKLIST /NH /FI "' & $sImageName & ' EQ ' & $sAppID & '" | FIND /I "' & $sAppID & '" >nul && GOTO START' & @CRLF _
             & 'GOTO MOVE' & @CRLF _
             & @CRLF _
             & ':MOVE' & @CRLF _
             & 'TASKKILL /F /FI "' & $sImageName & ' EQ ' & $sAppID & '"' & @CRLF _
             & $sBackupPath & _
            'GOTO END' & @CRLF _
             & @CRLF _
             & ':END' & @CRLF _
             & 'MOVE /Y ' & '"' & $sUpdatePath & '"' & ' "' & $sScriptPath & '"' & @CRLF _
             & $sRestart & @CRLF _
             & 'DEL "' & $sTempFileName & '"'

    Local Const $hFileOpen = FileOpen($sTempFileName, $FO_OVERWRITE)
    If $hFileOpen = -1 Then
        Return SetError(2, 0, 0)
    EndIf
    FileWrite($hFileOpen, $sData)
    FileClose($hFileOpen)
    Return Run($sTempFileName, @TempDir, @SW_HIDE)
EndFunc   ;==>_SelfUpdate

Example use of Function:

#include <Constants.au3>
#include '_SelfUpdate.au3'

; Start the SelfUpdate batch file with a 30 second timer, using the process name rather than the PID and restart the application after updating.
_SelfUpdate(@ScriptDir & '\Test_Update.exe', True, 30, False)
If @error Then
    Exit MsgBox($MB_SYSTEMMODAL, '_SelfUpdate()', 'The script must be a compiled exe to work correctly or the update file must exist.') ; Display a warning if the script isn't compiled or the file doesn't exist.
EndIf

While 1
    Sleep(100) ; Wait or manually close the application via the traymenu icon.
WEnd

Edited by guinness, 03 April 2013 - 08:46 PM.

[Xenobiologist]

Hey, I already created the funtion on my own, but I'll test yours.
In your example you ve got a copy paste error : _selfDelete should be _selfUpdate right?!

Edit: I also had some problems with start in the bat file. I use call instead.

Edited by Xenobiologist, 01 March 2012 - 01:58 PM.

[guinness]

Hey, I already created the funtion on my own, but I'll test yours.
In your example you ve got a copy paste error : _selfDelete should be _selfUpdate right?!

Edit: I also had some problems with start in the bat file. I use call instead.

Thanks for the report, I updated the example an oversight on my part and I thought Call was meant for calling another batch script as Start has worked for me.

[funkey]

Nice, can be very useful! I have also my own SelfUpdate function, a lot easier than yours, but maybe not as powerfull. I will post it here tomorrow if you want.

[guinness]

By all means funkey please do, the more the merrier.

[SeF]

Mine is much more simpler too. I use it with Res_Fileversion_AutoIncrement=y (SciTE) here in my job's network and works just fine.

Func UpdateCheck($UpdatedVersionPath)
FileDelete(@ScriptDir & "\OLD.exe")
$CurrentVersion = FileGetVersion(@ScriptFullPath)
$LastVersion = FileGetVersion($UpdatedVersionPath & @ScriptName)
If $CurrentVersion < $LastVersion Then
  TrayTip("Updater", "Updating. . .", "", 2)
  FileCopy($UpdatedVersionPath & @ScriptName, @ScriptDir & "\NEW.exe")
  FileMove(@ScriptFullPath, @ScriptDir & "\OLD.exe")
  FileMove(@ScriptDir & "\NEW.exe", @ScriptFullPath)
  Run(@ScriptName)
  Exit
EndIf
EndFunc   ;==>UpdateCheck

[guinness]

SeF,

Of course it can be done that way too but I'm sure it's not a wise thing to rename the executable whilst it's running, though I could be wrong.

[funkey]

So, here comes my version!

While 1
    Sleep(1000)
    If _CheckUpdate() Then
        _selfupdate()
        Exit
    EndIf
WEnd

Func _CheckUpdate()
    If @Compiled And FileExists(@ScriptName & ".Update.exe") Then Return 1
    Return 0
EndFunc   ;==>_CheckUpdate

Func _selfupdate($iWait = 3000) ;wait 3000ms for default
    ;funkey
    Run(@ComSpec & " /c ping 0.0.0.1 -n 1 -w " & $iWait & ' & move "' & @ScriptName & '" "' & @ScriptName & '.Old.exe" & move "' & @ScriptName & '.Update.exe" "' & @ScriptName & '" & start "Title" "' & @ScriptName & '"', @ScriptDir, @SW_HIDE)
EndFunc   ;==>_selfupdate

[guinness]

Ah OK, the difference here is I monitor when the process closes and terminate if the timer is reached or not. Thanks for submitting.

By the way your function _CheckUpdate can be consolidated into one line.

ConsoleWrite(_CheckUpdate() & @LF)

Func _CheckUpdate()
   Return (@Compiled And FileExists(@ScriptName & ".Update.exe"))
EndFunc   ;==>_CheckUpdate

Edited by guinness, 02 March 2012 - 10:42 AM.

[guinness]

Updated the function. Now the Default keyword is supported too. Please see the original post for more details.

Note: I have changed $iUsePID and $iRestart to boolean values rather than the previous 0 or 1

[nolongthin]

Please i have a question on your selfUpdate program, if i don't know the name of the compiled script in a remote system am trying to update how can i update it?

[guinness]

Please i have a question on your selfUpdate program, if i don't know the name of the compiled script in a remote system am trying to update how can i update it?

If you don't know the file you're updating then I have no clue. Plus, this is for updating the current exe only.

[D4RKON3]

It's all clear to me, except this part:

$fUsePID - [optional] Use the process name (False) or PID (True). Default is False.

What's the usage of $fUsePID while my tests work in both modes (Both True and False for $fUsePID).

Also replacing $FO_OVERWRITE with its value is a good idea, no need to FileConstants any more.

Edit: What about making the creation of BackUp file optional?

Edited by D4RKON3, 18 October 2012 - 11:40 AM.

[guinness]

You can either monitor the process with it's name e.g. Example.exe or PID e.g. 1234. The name is more precise compared to the PID, because if you have multiple instances, the function will wait until all of them are closed. Whereas with the PID if that closes then it will continue and is more likely to cause an error, due to 'file in use.'

[code=auto:0]Edit: What about making the creation of BackUp file optional?

Done. See above for an update of the function.

I dislike using 'magic numbers' so I won't be changing $FO_OVERWRITE to 2, but by all means change your version.

[D4RKON3]

OK, it's crystal clear now, thank you for explaining.
However in some cases, for example when _SingleTon is used, using PID can be a wise choice.

$fBackupPath sounds great, thanks.

[guinness]

_Singleton doesn't use a PID.

[D4RKON3]

You have misunderstood me.

What you said:

because if you have multiple instances

What I said:

when _SingleTon is used, using PID can be a wise choice

[guinness]

Ah sorry, yes correct. If users limit their application to one instance then PID is a good option too.

[guinness]

Fixed a bug in the batch file in which it wouldn't update correctly.

[caleb41610]

guinness,

Thanks for posting this. It has helped very much!