WM_HELP & Tooltip

[Yashied]

How I can remove the tooltip after its activation through WM_HELP message.

Thanks.

#include <GUIConstantsEx.au3>
#include <Misc.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

$Form = GUICreate("My GUI", 400, 400, -1, -1, BitOR($WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $DS_CONTEXTHELP), $WS_EX_CONTEXTHELP)

$Button = GUICtrlCreateButton("Exit", 165, 360, 70, 23)
GUIRegisterMsg($WM_HELP, '_WM_HELP')

GUISetState()

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case $Button, $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _WM_HELP($hWnd, $msgID, $wParam, $lParam)

    Local $tPOINT = _WinAPI_GetMousePos()
    Local $hHandle = _WinAPI_WindowFromPoint($tPOINT)
    Local $ID = _WinAPI_GetDlgCtrlID($hHandle)

    If _IsPressed(70) Then
        Switch $ID
            Case $Button
                Run('hh.exe ' & RegRead('HKLM\SOFTWARE\AutoIt v3\AutoIt', 'InstallDir') & '\AutoIt3.chm')
        EndSwitch   
    Else
        ToolTip('This is a tooltip', DllStructGetData($tPOINT, 1), DllStructGetData($tPOINT, 2), '', 0, 1)
    EndIf
EndFunc   ;==>_WM_HELP

[Zedna]

ToolTip("")

An empty string clears a displaying tooltip

[Yashied]

ToolTip("")

An empty string clears a displaying tooltip

I know it, but how to catch those moments when I need to remove the tooltip? I want to make sure how it works in Windows. For example, the standard Mouse Properties Dlg.

[Yashied]

I found this. Excellent work, but Tooltip more beautiful. Any ideas.

[KaFu]

Remove it with a Timer

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <Misc.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <Timers.au3>

$Form = GUICreate("My GUI", 400, 400, -1, -1, BitOR($WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $DS_CONTEXTHELP), $WS_EX_CONTEXTHELP)

$Button = GUICtrlCreateButton("Exit", 165, 360, 70, 23)
GUIRegisterMsg($WM_HELP, '_WM_HELP')

Global $bTooltipActive = False
Global $iTooltipTime
_Timer_SetTimer($Form, 250, "_Remove_WM_HELP_Tooltip")

GUISetState()

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case $Button, $GUI_EVENT_CLOSE
            _Timer_KillAllTimers($Form)
            Exit
    EndSwitch
WEnd

Func _WM_HELP($hWnd, $msgID, $wParam, $lParam)
    Local $tPOINT = _WinAPI_GetMousePos()
    Local $hHandle = _WinAPI_WindowFromPoint($tPOINT)
    Local $ID = _WinAPI_GetDlgCtrlID($hHandle)

    If _IsPressed(70) Then
        Switch $ID
            Case $Button
                Run('hh.exe ' & RegRead('HKLM\SOFTWARE\AutoIt v3\AutoIt', 'InstallDir') & '\AutoIt3.chm')
        EndSwitch
    Else
        $bTooltipActive = True
        $iTooltipTime = TimerInit()
        ToolTip('This is a tooltip', DllStructGetData($tPOINT, 1), DllStructGetData($tPOINT, 2), '', 0, 1)
    EndIf
EndFunc   ;==>_WM_HELP

Func _Remove_WM_HELP_Tooltip($hWnd, $Msg, $iIDTimer, $dwTime)
    #forceref $hWnd, $Msg, $iIDTimer, $dwTime
    if $bTooltipActive = True Then
        if TimerDiff($iTooltipTime) > 1000 Then
            ToolTip('')
            $bTooltipActive = False
        endif
    endif
EndFunc   ;==>_Remove_WM_HELP_Tooltip

[Yashied]

Thanks, but this is not the best way. I try using _WinAPI_SetWindowLong(), but also disappointed. I need to process too many messages.