How to set hotkeys to work only in AutoIt GUI?

[Suppir]

I have created hotkeys for my AutoIt application. These hotkeys run some functions. But if I activate another application (notepad), my AutoIt hotkeys working in this Notepad (causes some problems). How to restrict Autoit hotkey to set them working only if AutoIt application is active?

[Yashied]

See GUISetAccelerators().

[Suppir]

See GUISetAccelerators().

Yashied I can set variables to accelerators, but functions do not work

[ProgAndy]

use GUICtrlCreateDummy and associate the function with the Dummy-Control

#include <GUIConstants.au3>

#region - GUI Create
GUICreate('test')
GUICtrlCreateLabel("Press ALT-A", 10, 10, 100, 30)
$iDummy = GUICtrlCreateDummy()

Dim $aAccel[1][2] = [ ["!a", $iDummy ]]
GUISetAccelerators($aAccel)
GUISetState()
#endregion

#region - GUI SelectLoop
While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            Exit
        Case $msg = $iDummy
            MsgBox(0, '', "Accelerator pressed")
    EndSelect
WEnd
#endregion

[Suppir]

Oh, very thanks! Now I understand, that I was trying to use accelerators in wrong way. The problem is completely solved!

Edited November 16, 2009 by Suppir

[Yashied]

Another way.

$hForm = GUICreate('MyGUI')
HotKeySet('^a', '_MyHotKeyFunc')
GUISetState()

Do
Until GUIGetMsg() = -3

Func _MyHotKeyFunc()
    If BitAND(WinGetState($hForm), 8) Then
        MsgBox(0, '', 'CTRL-A is pressed!')
        Return
    EndIf
    HotKeySet('^a')
    Send('^a')
    HotKeySet('^a', '_MyHotKeyFunc')
EndFunc   ;==>_MyHotKeyFunc

[Suppir]

Another way.

Thank's a lot, Yashied. I will try it.