Simple Problem

[continyu]

Hi there,

I want to say, we have perfectly helpfull members in here. And i want to thank them all...

So my problem is;

FileFindFirstFile and FileFindNextFile works in current directory (as helpfile says)

i think current directory means script path .

But i want to get files from another path.

Here is the my scripts code, it's a file renamer (i know it's noobbish and there are millions of renamers but i want to write my own.)

#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.3.6.1
 Author:         Kontinyu
#ce
#include <file.au3>
#include <array.au3>
$var = FileSelectFolder("Choose a folder.", "",7)
FileOpen($var)
$search = FileFindFirstFile("*.*")
$i = 1
Dim $szDrive, $szDir, $szFName, $szExt
$ESCx = MsgBox(262433,"Sure?","Are you sure to start script" & @CRLF & "all files will be renamed in selected dir.")
If $ESCx = 2 Then
    Exit
    EndIf
While 1
FileOpen($var)
$file = FileFindNextFile($search)
IF @error Then
    FileClose($var)
    FileClose($search)
    Sleep(2900)
    MsgBox(1,"Done","Renaming Done...")

EndIf
$TestPath = _PathSplit($file, $szDrive, $szDir, $szFName, $szExt)
FileMove($var&"/"&$file,$var&"/"&$i&$szExt)
$i = $i + 1

WEnd

PS: This code doesn't works... :=)

[KaFu]

FileFindFirstFile("*.*") will match all files in current dir.

FileFindFirstFile("c:\*.*") will match all files in c:\.

[water]

Use the path like:

$var = FileSelectFolder("Choose a folder.", "",7)
$search = FileFindFirstFile($var & "\*.*")

[Melba23]

continyu,

A few syntax problems there.

Take a look at this version:

#cs ----------------------------------------------------------------------------

    AutoIt Version: 3.3.6.1
    Author:         Kontinyu
#ce
#include <file.au3>
;#include <array.au3> ; Why?

Global $szDrive, $szDir, $szFName, $szExt

$var = FileSelectFolder("Choose a folder.", "", 7)

$i = 1

If MsgBox(262433, "Sure?", "Are you sure to start script" & @CRLF & "all files will be renamed in selected dir.") = 2 Then
    Exit
EndIf

$search = FileFindFirstFile($var & "\*.*")

While 1

    $file = FileFindNextFile($search)
    If @error Then ExitLoop

    $TestPath = _PathSplit($file, $szDrive, $szDir, $szFName, $szExt)
    FileMove($var & "\" & $file, $var & "\" & $i & $szExt)
    $i += 1

WEnd

FileClose($search)
MsgBox(1, "Done", "Renaming Done...")

Please ask if anything is unclear.

M23

[continyu]

Thank all of you

IT's working like charm at the moment...

All problems solved (for this script )