Hide Close Button in an External Application

[leomoon 1]

Hello,

I need to disable close button on an application that will be displaying on a touch screen booth. They don't want ppl to be able to close the application.

I did some experiments but it only works on the running autoit application:

#include <GUIConstants.au3>
#include <WindowsConstants.au3>
AutoItSetOption("WinTitleMatchMode", 2)

$gui2 = GUICreate("dummy",100,60)
$iStyle1 = BitOr($WS_MAXIMIZEBOX, $WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU); Style with minimize box
$iStyle2 = BitOr($WS_EX_TOPMOST, $WS_EX_WINDOWEDGE); Style without minimize box

$gui = GUICreate('', 200, 200, -1, -1, $iStyle1)
$bt1 = GUICtrlCreateButton('Click me to enable', 5, 5, 120, 25)
$bt2 = GUICtrlCreateButton('Click me to disable', 5, 35, 120, 25)

GUISetState(4)

While 1
    $gm = GUIGetMsg()
    Switch $gm
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $bt1
            $handle = WinGetHandle("Notepad")
            ConsoleWrite($handle&@LF)
            GUISetStyle($iStyle1, '', $handle)
       Case $bt2
            $handle = WinGetHandle("Notepad")
            ConsoleWrite($handle&@LF)
            GUISetStyle($iStyle2, '', $handle)
    EndSwitch
WEnd

Any help/suggestions are welcome.

[computergroove 31]

Remove the line:

Case $GUI_EVENT_CLOSE
            ExitLoop <-- This one

[leomoon 1]

Hi,

I think I didn't explain well. I want to use this AutoIt script to hide the close button on another program or make that program not "closeable".

[LarryDalooza 37]

Use SetWindowLong APi (correctly) to change the window properties of the hWnd of the window. Then redraw it by using SetWindow or some other redraw API, I forget. Although... I think Alt + {F4} will still close the window.

Lar.

[guinness 1,430]

Or (I did a quick search!)

Quick MOD for Windows 7!

#NoTrayIcon
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("GUICloseOnESC", 0)

$iLast_X = 0
$iLast_Y = 0

Run("Notepad.exe")
WinWaitActive("Untitled - Notepad")

$hNotePad_Handle = WinGetHandle("Untitled - Notepad")

$hGUI = GUICreate("My [X]", 50,30, -1, -1, $WS_POPUP, BitOR($WS_EX_TOOLWINDOW, $WS_EX_TOPMOST))
$hPic = GUICtrlCreateLabel("", 0, 0, 50, 30)
GUICtrlSetBkColor(-1,0xFF0000)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hPic
            MsgBox(0, "Warning", "Someone is trying to exit!")
    EndSwitch

    Local $aNotePad_Pos = WinGetPos($hNotePad_Handle)
    If $aNotePad_Pos[0] <> $iLast_X Or $aNotePad_Pos[1] <> $iLast_Y Then
        $iLast_X = $aNotePad_Pos[0]
        $iLast_Y = $aNotePad_Pos[1]
        WinMove($hGUI, '', $aNotePad_Pos[0] + $aNotePad_Pos[2] - 55, $aNotePad_Pos[1])
    EndIf
WEnd

Edited January 13, 2011 by guinness