SetItemChecked with progressbar

[bobbby]

I using "_GUICtrlListView_SetItemChecked" to select a whole list.

But i want a progressbar that show when it's done. How should i do this the fastest way?

I have used a for loop but that will add like +30 seconds. And if i use -1 it will go really fast.

Here is what i tested with, but maybe I'm in the wrong direction.

func docheck()
        local $diff
    $begin = TimerInit()
    ProgressOn("Progress", "")
    $start = _GUICtrlListView_SetItemChecked($hwnd, -1)
    do
        $diff = TimerDiff($begin)
        ProgressSet(int($diff /1000))
    until $start == true
EndFunc

[guinness]

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Check ClassName being passed to ListView functions, set to True and use a handle to another control to see it work

_Main()

Func _Main()
    Local $exStyles = BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES), $hListView, $iProgress, $iCount

    GUICreate("ListView Set Item Checked State", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    _GUICtrlListView_SetExtendedListViewStyle($hListView, $exStyles)
    $iProgress = GUICtrlCreateProgress(2, 272, 300, 10)
    GUISetState()

    ; Add columns
    _GUICtrlListView_AddColumn($hListView, "Column 1", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 2", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 3", 100)

    ; Add items
    For $A = 0 To 3000
        _GUICtrlListView_AddItem($hListView, "Row 1: Col 1", $A)
    Next

    Sleep(1000) ; <<<< Delay to Show ListView

    $iCount = _GUICtrlListView_GetItemCount($hListView)
    For $i = 0 To $iCount
        _GUICtrlListView_SetItemChecked($hListView, $i)
        GUICtrlSetData($iProgress, ($i / $iCount) * 100)
    Next

    ; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

Edited January 23, 2011 by guinness

[bobbby]

Works, but it's 13 seconds more with for loop.

And that's with a checklist with 10.000. I want it as fast i can get.

[guinness]

OK, I get about 4 seconds and it would be cool if you could provide some code of what you have.

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GuiConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; Check ClassName being passed to ListView functions, set to True and use a handle to another control to see it work

_Main()

Func _Main()
    Local $exStyles = BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES), $hListView, $iProgress, $iCount

    GUICreate("ListView Set Item Checked State", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    _GUICtrlListView_SetExtendedListViewStyle($hListView, $exStyles)
    $iProgress = GUICtrlCreateProgress(2, 272, 300, 10)
    GUISetState()

    ; Add columns
    _GUICtrlListView_AddColumn($hListView, "Column 1", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 2", 100)
    _GUICtrlListView_AddColumn($hListView, "Column 3", 100)

    ; Add items
    For $A = 0 To 10000
        _GUICtrlListView_AddItem($hListView, "Row 1: Col 1", $A)
    Next

    Sleep(1000) ; <<<< Delay to Show ListView

    Local $Begin = TimerInit()
    $iCount = _GUICtrlListView_GetItemCount($hListView)
    For $i = 0 To $iCount
        _GUICtrlListView_SetItemChecked($hListView, $i)
        GUICtrlSetData($iProgress, ($i / $iCount) * 100)
    Next
    ConsoleWrite(TimerDiff($Begin) & @CRLF)

    ; Loop until user exits
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

Edited January 23, 2011 by guinness

[bobbby]

OK, I get about 4 seconds and it would be cool if you could provide some code of what you have.

It looks like it goes really fast with a GUI created in Autoit.

But i select the checkboxes in another program. Maybe that's why it's so slow.

22.000 checkboxes and for loop = 24 seconds

22.000 checkboxes without for loop = 10 seconds

But I'm going to use for loop, it's the only way to use for progressbar i think. Thanks for the help

[guinness]

OK, I didn't know you were doing it for another Program and I suggest searching Progress Marquee on the Forum, because the GUICtrlSetData() is slowing the loop down at the moment.

Edited January 23, 2011 by guinness