Support variable number of buttons

[Lupo73]

I had some problems already to create the topic title. I'll try to be more clear with the post.

The idea is to create a GUI with some buttons, but not a defined number of buttons (in my case each button represents an action that can be done on a file and allowed actions vary in function of file itself).

So in this GUI I can have 2 or 3 or more of these buttons and I need to detect if they are clicked. The problem is that in the Switch selection of the While loop I don't have a defined number of items and so I cannot do something like this:

Case $Button1, $Button2, $Button3

So I tried the following solution, but the problem is that it works only sometimes (I think it works fine only when a button is clicked and $mCount is exactly that button):

expandcollapse popup

Func _MoreMatches($mMatches, $mFileName)
    Local $mEmptyDestination = "Empty-Destination"

    Local $mGUI, $mType, $mAdditional, $mCancel, $mButtons[$mMatches[0][0] + 1] = [0], $mCount = 0, $mRead = -1
    If Not IsArray($mMatches) Then Return SetError(1, 1, 0) ; Exit Function If Not An Array.
    $mGUI = GUICreate('Pattern Ambiguity', 280, 115 + 23 * $mMatches[0][0], -1, -1, -1, $WS_EX_TOOLWINDOW)

    GUICtrlCreateGroup('Loaded item:', 8, 6, 264, 40)
    GUICtrlCreateLabel($mFileName, 26, 24, 230, 20)
    GUICtrlSetTip($mFileName, 'This item fits with several patterns.')
    GUICtrlCreateGroup("", -99, -99, 1, 1)

    GUICtrlCreateGroup('Select what pattern to apply:', 8, 52, 264, 22 + 23 * $mMatches[0][0])

    For $A = 1 To $mMatches[0][0]
        $mType = StringRight($mMatches[$A][0], 2)
        $mAdditional = StringTrimRight($mMatches[$A][0], 2)
        $mButtons[$A] = GUICtrlCreateButton(" " & $mAdditional, 25, 46 + ($A * 23), 230, 22)
        $mButtons[0] += 1
    Next
    GUICtrlCreateGroup("", -99, -99, 1, 1)

    $mCancel = GUICtrlCreateButton('Cancel', 140 - 45, 82 + 23 * $mMatches[0][0], 90, 24)
    GUISetState(@SW_SHOW)

    While 1
        If $mCount = $mButtons[0] Then $mCount = 0
        $mCount += 1
        Sleep(50)

        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $mCancel
                $mRead = -1
                ExitLoop

            Case $mButtons[$mCount]
                $Global_Action = StringRight($mMatches[$mCount][0], 2) ; Set Action For This File/Folder.
                $mRead = $mMatches[$mCount][1]
                ExitLoop

        EndSwitch
    WEnd
    GUIDelete($mGUI)

    If $mRead = -1 Or $mRead = $mEmptyDestination Then Return SetError(1, 1, -1)
    Return $mRead
EndFunc   ;==>_MoreMatches

Edited March 5, 2011 by Lupo73

[Melba23]

Lupo73,

Why not create all the buttons each time and just hide the ones that are not valid for that particular file? Then you can have a universal Switch structure within your While...WEnd loop and the unwanted buttons will never fire because they are not visible to be clicked.

M23

[guinness]

Maybe something like this >>

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
_Main()

Func _Main()
    Local $aPatterns[5] = [4, "Pattern 1", "Pattern 2", "Pattern 3", "Pattern 4"], $aButtons[$aPatterns[0] + 1] = [0], $hMsg
    GUICreate("_Main()", 150, 255)
    For $i = 1 To $aPatterns[0]
        $aButtons[$i] = GUICtrlCreateButton($aPatterns[$i], 10, 30 * $i)
        $aButtons[0] += 1
    Next
    Local $iCancel = GUICtrlCreateButton("Cancel", 10, 30 * $i)
    GUISetState(@SW_SHOW)

    While 1
        $hMsg = GUIGetMsg()
        Switch $hMsg
            Case -3, $iCancel
                ExitLoop ; Exit While Loop!
            Case Else
                If $hMsg >= $aButtons[1] And $hMsg <= $aButtons[$aButtons[0]] Then
                    For $i = 1 To $aButtons[0]
                        If $hMsg = $aButtons[$i] Then
                            MsgBox(0, "You Chose >>", GUICtrlRead($aButtons[$i]))
                            ExitLoop 2 ; Exit For Loop & While Loop!
                        EndIf
                    Next
                    ExitLoop ; Exit While Loop!
                EndIf
        EndSwitch
    WEnd
EndFunc   ;==>_Main

Edited March 5, 2011 by guinness

[Lupo73]

Thanks! This solution works fine