when returning to an input box, how to highlight the text?

[kor]

I would like the text highlighted if a user types an incorrect password. This way, they can simply begin typing a new password without having to press backspace to clear the input field.

Here is my code.

expandcollapse popup

#include <GUIConstants.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>

$domain = "test.local"

GUICreate(" Enter Credentials", 203, 100, @DesktopWidth / 2 - 160, -1, $WS_CAPTION) ; , $WS_CAPTION
GUICtrlCreateLabel("Enter your Active Directory credentials", 8, 4, -1, 25)
GUICtrlCreateLabel("Username:", 8, 28, 64, 20) ; username label ; left, top, width, height
$input1 = GUICtrlCreateInput("", 70, 25, 125, 20) ; username input
GUICtrlCreateLabel("Password:", 9, 52, 64, 20) ; password label
$input2 = GUICtrlCreateInput("", 70, 49, 125, 20, $ES_PASSWORD)
$ok = GUICtrlCreateButton("&OK", -1, 75, 60, 20)
GUICtrlSetState($ok, 512) ; allows enter inside input boxes
GUISetState()

$msg = 0
While $msg <> $GUI_EVENT_CLOSE
    $msg = GUIGetMsg()
    Local $user = GUICtrlRead($input1)
    Local $pass = StringReplace(GUICtrlRead($input2), "ad\", "") ;removes leading ad\ 
    Select
        Case $msg = $ok
            ; this code will attempt to map a drive using credentials provided above
            ; if drive map is successfull it is assumed the username and password combo are good and continues
            If $user <> "" And $pass <> "" Then
                $strQueryDom = "netdom query /domain:" & $domain & " /userD:" & $user & " /passwordD:" & $pass & " dc"
                $strQueryDomResult = RunWait(@Comspec & " /C" & $strQueryDom,'',@SW_HIDE)
                If $strQueryDomResult <> 0 Then
                    MsgBox (16, "Error", "Password is incorrect")
                    GUICtrlSetState($pass, 256)
                Else
                    $Status = 1
                    ExitLoop
                EndIf
            Else
                Select
                    Case $user = "" And $pass = ""
                        MsgBox(16, "Error", "Username cannot be blank")
                    Case $pass = ""
                        MsgBox(16, "Error", "Password cannot be blank")
                        GUICtrlSetState($pass, 256)
                    Case $user = ""
                        MsgBox(16, "Error", "Username cannot be blank")
                        GUICtrlSetState($user, 256)
                EndSelect
            EndIf
        ;Case Else
        ;   Sleep(2000)
    EndSelect
WEnd

[GEOSoft]

GuiCtrlSetState($My_Input, $GUI_FOCUS)

[kor]

Awesome, I took the gui code from another example on the forum. After looking it looks like the persons code sets the gui flag as a value (256) in this instance. I wasn't sure what that did exactly.

[GEOSoft]

256 is the value of $GUI_FOCUS

[kor]

is there anywhere in the help file that compares the different flags to their value? I couldn't find anything that ties the two together.

[GEOSoft]

The Constants values are in the constants files in your Program Files\AutoIt3\Include folder. In this case it is in the GUIConstantsEx.au3 file.

[guinness]

And if you use SciTE4AutoIt you can also use Alt+I to open the Include File in SciTE. Make sure you cursor selects the Include line e.g. #include <Array.au3> and then hit the HotKey Alt+I

[kor]

Any suggestions to my code? Because I am already setting value 256 which is gui focus on the password input if the password in incorrect. However the GUI is not highlighting the password, it's only just going back to the box with the cursor at the end of the password.

I am trying to get it to return back to the password box with the entire password highlighted, so if a user begins typing it replaces the current password.

[Bowmore]

You were making the common mistake of using the value of the control rather than the control IDs $input2 and $input2 when setting the focus to the control. I've also added a line to set the contents of the password control to "" when the value is incorrect to save the user having to clear it themselves. It is little things like that that make a GUI a pleasure to use or just plain annoying.

expandcollapse popup

#include <GUIConstants.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>

$domain = "test.local"

GUICreate(" Enter Credentials", 203, 100, @DesktopWidth / 2 - 160, -1, $WS_CAPTION) ; , $WS_CAPTION
GUICtrlCreateLabel("Enter your Active Directory credentials", 8, 4, -1, 25)
GUICtrlCreateLabel("Username:", 8, 28, 64, 20) ; username label ; left, top, width, height
$input1 = GUICtrlCreateInput("", 70, 25, 125, 20) ; username input
GUICtrlCreateLabel("Password:", 9, 52, 64, 20) ; password label
$input2 = GUICtrlCreateInput("", 70, 49, 125, 20, $ES_PASSWORD)
$ok = GUICtrlCreateButton("&OK", -1, 75, 60, 20)
GUICtrlSetState($ok, 512) ; allows enter inside input boxes
GUISetState()

$msg = 0
While $msg <> $GUI_EVENT_CLOSE
    $msg = GUIGetMsg()
    Local $user = GUICtrlRead($input1)
    Local $pass = StringReplace(GUICtrlRead($input2), "ad\", "") ;removes leading ad\
    Select
        Case $msg = $ok
            ; this code will attempt to map a drive using credentials provided above
            ; if drive map is successfull it is assumed the username and password combo are good and continues
            If $user <> "" And $pass <> "" Then
                $strQueryDom = "netdom query /domain:" & $domain & " /userD:" & $user & " /passwordD:" & $pass & " dc"
                $strQueryDomResult = RunWait(@Comspec & " /C" & $strQueryDom,'',@SW_HIDE)
                If $strQueryDomResult <> 0 Then
                    MsgBox (16, "Error", "Password is incorrect")
                    GUICtrlSetData($input2, "") ;<<<<<<<<========= Clear the invlaid password ready for the user to retry
                    GUICtrlSetState($input2, 256) ;<<<<<<<<======= Set focus to the password box
                Else
                    $Status = 1
                    ExitLoop
                EndIf
            Else
                Select
                    Case $user = "" And $pass = ""
                        MsgBox(16, "Error", "Username cannot be blank")
                        GUICtrlSetState($input1, 256) ;<<<<<<<<======= Set focus to the user box
                    Case $pass = ""
                        MsgBox(16, "Error", "Password cannot be blank") ;<<<<<<<<======= Set focus to the password box
                        GUICtrlSetState($input2, 256)
                    Case $user = ""
                        MsgBox(16, "Error", "Username cannot be blank") ;<<<<<<<<======= Set focus to the user box
                        GUICtrlSetState($input1, 256)
                EndSelect
            EndIf
        ;Case Else
        ;   Sleep(2000)
    EndSelect
WEnd