Sign in to follow this  
Followers 0
Maffe811

Checkboxes... How do they work ?

8 posts in this topic

#1 ·  Posted (edited)

I decided to get started on my settings window, and i though i could try to use Koda.

Wich worked brilliantly.

Now, the next step is to add checkboxes.

I dont know how they work...

I get little to no help in the help file and forum searches is just as empty.

If someone can point me to a place in the help file that easily explains checkboxes or tell me how i can find out if a checkbox is checked or not.

I tried GuiCtrlGetState, but i think i used that in the wrong way.

Here is what i got, all i need is to get a value from the checkboxes.

Preferably a True/False value.

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)

#Region ### START Koda GUI section ### 
;Create GUI
$Gui = GUICreate("Settings", 358, 196)
;If window is closed then exit
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")

;Gui content
;Disable hide function
$CheckboxHide = GUICtrlCreateCheckbox("Disable Hide function", 16, 8, 321, 41)
GUICtrlSetOnEvent(-1, "_CheckboxHide")
;Disable Whats playing bubble
$CheckboxBubble = GUICtrlCreateCheckbox("Disable Whats playing bubble", 18, 45, 321, 41)
GUICtrlSetOnEvent(-1, "_CheckboxBubble")
;Empty disable box
$CheckboxDisabled = GUICtrlCreateCheckbox("Disabled", 16, 86, 321, 41)
GUICtrlSetState(-1, $GUI_DISABLE)
GUICtrlSetOnEvent(-1, "_CheckboxDisabled")
;OK button
$ButtonOk = GUICtrlCreateButton("Ok", 30, 144, 129, 41, $WS_GROUP)
GUICtrlSetOnEvent(-1, "_ButtonOk")
;Cancel button
$ButtonCancel = GUICtrlCreateButton("Cancel", 198, 144, 129, 41, $WS_GROUP)
GUICtrlSetOnEvent(-1, "_Exit")
;Show gui
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    Sleep(100)
WEnd

;Checkbox functions
;Hide function checkbox function
Func _CheckboxHide()

EndFunc
;Whats playing bubble checkbox function
Func _CheckboxBubble()

EndFunc
;Disabled checkbox function
Func _CheckboxDisabled()

EndFunc

;Ok button function
Func _ButtonOk()
    MsgBox(0,"", $CheckboxBubble & @CRLF & $CheckboxHide & @CRLF & $CheckboxDisabled)
EndFunc
;Cancel button is using the _Exit function!

;Exit function
Func _Exit()
    Exit
EndFunc
Edited by Maffe811

[font="helvetica, arial, sans-serif"]Hobby graphics artist, using gimp.Automating pc stuff, using AutoIt.Listening to music, using Grooveshark.[/font]Scripts:[spoiler]Simple ScreenshotSaves you alot of trouble when taking a screenshot!Don't remember what happened with this, but aperantly the exe is all i got.If you don't want to run it, simply don't._IsRun UDFIt figures out if the script has ben ran before based on the info in a ini file.If you don't want to use exactly what i wrote, you can use it as inspiration.[/spoiler]

Share this post


Link to post
Share on other sites



#2 ·  Posted (edited)

Help File and look under GUICtrlCreateCheckboxes() :huh2:

But if you want to know whether a Checkbox is Checked then you do it like this >>

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIConstantsEx.au3>

_Main()

Func _Main()
    Local $iCheckbox, $sData

    GUICreate("Quick Example Using GUIGetMsg()")
    $iCheckbox = GUICtrlCreateCheckbox("Hide TrayIcon", 10, 10, 120, 20)

    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit

            Case $iCheckbox
                If _IsChecked($iCheckbox) Then
                    $sData = "I'm Checked!, So I will Hide the TrayIcon"
                    TraySetState(2)
                Else
                    $sData = "I'm NOT Checked!, So I will Show the TrayIcon"
                    TraySetState(1)
                EndIf
                MsgBox(64, "What Is The State?", $sData)

        EndSwitch
    WEnd
EndFunc   ;==>_Main

Func _IsChecked($iControlID)
    Return BitAND(GUICtrlRead($iControlID), $GUI_CHECKED) = $GUI_CHECKED
EndFunc   ;==>_IsChecked
Edited by guinness

_AdapterConnections()_AlwaysRun()_AppMon()_AppMonEx()_BinaryBin()_CheckMsgBox()_CmdLineRaw()_ContextMenu()_ConvertLHWebColor()/_ConvertSHWebColor()_DesktopDimensions()_DisplayPassword()_DotNet_Load()/_DotNet_Unload()_Fibonacci()_FileCompare()_FileCompareContents()_FileNameByHandle()_FilePrefix/SRE()_FindInFile()_GetBackgroundColor()/_SetBackgroundColor()_GetConrolID()_GetCtrlClass()_GetDirectoryFormat()_GetDriveMediaType()_GetFilename()/_GetFilenameExt()_GetHardwareID()_GetIP()_GetIP_Country()_GetOSLanguage()_GetSavedSource()_GetStringSize()_GetSystemPaths()_GetURLImage()_GIFImage()_GoogleWeather()_GUICtrlCreateGroup()_GUICtrlListBox_CreateArray()_GUICtrlListView_CreateArray()_GUICtrlListView_SaveCSV()_GUICtrlListView_SaveHTML()_GUICtrlListView_SaveTxt()_GUICtrlListView_SaveXML()_GUICtrlMenu_Recent()_GUICtrlMenu_SetItemImage()_GUICtrlTreeView_CreateArray()_GUIDisable()_GUIImageList_SetIconFromHandle()_GUIRegisterMsg()_GUISetIcon()_Icon_Clear()/_Icon_Set()_IdleTime()_InetGet()_InetGetGUI()_InetGetProgress()_IPDetails()_IsFileOlder()_IsGUID()_IsHex()_IsPalindrome()_IsRegKey()_IsStringRegExp()_IsSystemDrive()_IsUPX()_IsValidType()_IsWebColor()_Language()_Log()_MicrosoftInternetConnectivity()_MSDNDataType()_PathFull/GetRelative/Split()_PathSplitEx()_PrintFromArray()_ProgressSetMarquee()_ReDim()_RockPaperScissors()/_RockPaperScissorsLizardSpock()_ScrollingCredits_SelfDelete()_SelfRename()_SelfUpdate()_SendTo()_ShellAll()_ShellFile()_ShellFolder()_SingletonHWID()_SingletonPID()_Startup()_StringCompact()_StringIsValid()_StringRegExpMetaCharacters()_StringReplaceWholeWord()_StringStripChars()_Temperature()_TrialPeriod()_UKToUSDate()/_USToUKDate()_WinAPI_Create_CTL_CODE()_WinAPI_CreateGUID()_WMIDateStringToDate()/_DateToWMIDateString()Au3 script parsingAutoIt SearchAutoIt3 PortableAutoIt3WrapperToPragmaAutoItWinGetTitle()/AutoItWinSetTitle()CodingDirToHTML5FileInstallrFileReadLastChars()GeoIP databaseGUI - Only Close ButtonGUI ExamplesGUICtrlDeleteImage()GUICtrlGetBkColor()GUICtrlGetStyle()GUIEventsGUIGetBkColor()Int_Parse() & Int_TryParse()IsISBN()LockFile()Mapping CtrlIDsOOP in AutoItParseHeadersToSciTE()PasswordValidPasteBinPosts Per DayPreExpandProtect GlobalsQueue()Resource UpdateResourcesExSciTE JumpSettings INISHELLHOOKShunting-YardSignature CreatorStack()Stopwatch()StringAddLF()/StringStripLF()StringEOLToCRLF()VSCROLLWM_COPYDATAMore Examples...

Updated: 04/09/2015

Share this post


Link to post
Share on other sites

Help File and look under GUICtrlCreateCheckboxes() :huh2:

Thats what i did, but it explained how to make a checkbox and not how to.. well.. use it. ;)

Can you explain how BitAnd is working?

Func _IsChecked($iControlID)
    Return BitAND(GUICtrlRead($iControlID), 1) = 1
EndFunc   ;==>_IsChecked

[font="helvetica, arial, sans-serif"]Hobby graphics artist, using gimp.Automating pc stuff, using AutoIt.Listening to music, using Grooveshark.[/font]Scripts:[spoiler]Simple ScreenshotSaves you alot of trouble when taking a screenshot!Don't remember what happened with this, but aperantly the exe is all i got.If you don't want to run it, simply don't._IsRun UDFIt figures out if the script has ben ran before based on the info in a ini file.If you don't want to use exactly what i wrote, you can use it as inspiration.[/spoiler]

Share this post


Link to post
Share on other sites

#4 ·  Posted (edited)

Well you can use this too, but as far I understood the BitAND Version will work even if the Checkbox has other Styles, what this Styles are I don't know?!

#include <GUIConstantsEx.au3>

Func _IsChecked($iControlID)
 Return GUICtrlRead($iControlID) = $GUI_CHECKED
EndFunc

Another Example with the Checkbox as a Button.

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


_Main()

Func _Main()
    Local $iCheckbox, $sData

    GUICreate("Quick Example Using GUIGetMsg()")
    $iCheckbox = GUICtrlCreateCheckbox("Hide TrayIcon", 10, 10, 120, 20, BitOR($BS_ICON, $BS_CHECKBOX, $BS_AUTOCHECKBOX, $BS_PUSHLIKE, $WS_TABSTOP))

    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit

            Case $iCheckbox
                ConsoleWrite("_IsChecked Shows >> " & _IsChecked($iCheckbox) & @CRLF)
                ConsoleWrite("_IsChecked_Other Shows >> " & _IsChecked_Other($iCheckbox) & @CRLF)
                If _IsChecked($iCheckbox) Then
                    $sData = "I'm Checked!, So I will Hide the TrayIcon"
                    TraySetState(2)
                Else
                    $sData = "I'm NOT Checked!, So I will Show the TrayIcon"
                    TraySetState(1)
                EndIf
                MsgBox(64, "What Is The State?", $sData)

        EndSwitch
    WEnd
EndFunc   ;==>_Main

Func _IsChecked($iControlID)
    Return BitAND(GUICtrlRead($iControlID), $GUI_CHECKED) = $GUI_CHECKED
EndFunc   ;==>_IsChecked

Func _IsChecked_Other($iControlID)
    Return GUICtrlRead($iControlID) = $GUI_CHECKED
EndFunc   ;==>_IsChecked_Other

BitAND() have a look at this >> http://www.cs.cf.ac.uk/Dave/PERL/node36.html

Edited by guinness

_AdapterConnections()_AlwaysRun()_AppMon()_AppMonEx()_BinaryBin()_CheckMsgBox()_CmdLineRaw()_ContextMenu()_ConvertLHWebColor()/_ConvertSHWebColor()_DesktopDimensions()_DisplayPassword()_DotNet_Load()/_DotNet_Unload()_Fibonacci()_FileCompare()_FileCompareContents()_FileNameByHandle()_FilePrefix/SRE()_FindInFile()_GetBackgroundColor()/_SetBackgroundColor()_GetConrolID()_GetCtrlClass()_GetDirectoryFormat()_GetDriveMediaType()_GetFilename()/_GetFilenameExt()_GetHardwareID()_GetIP()_GetIP_Country()_GetOSLanguage()_GetSavedSource()_GetStringSize()_GetSystemPaths()_GetURLImage()_GIFImage()_GoogleWeather()_GUICtrlCreateGroup()_GUICtrlListBox_CreateArray()_GUICtrlListView_CreateArray()_GUICtrlListView_SaveCSV()_GUICtrlListView_SaveHTML()_GUICtrlListView_SaveTxt()_GUICtrlListView_SaveXML()_GUICtrlMenu_Recent()_GUICtrlMenu_SetItemImage()_GUICtrlTreeView_CreateArray()_GUIDisable()_GUIImageList_SetIconFromHandle()_GUIRegisterMsg()_GUISetIcon()_Icon_Clear()/_Icon_Set()_IdleTime()_InetGet()_InetGetGUI()_InetGetProgress()_IPDetails()_IsFileOlder()_IsGUID()_IsHex()_IsPalindrome()_IsRegKey()_IsStringRegExp()_IsSystemDrive()_IsUPX()_IsValidType()_IsWebColor()_Language()_Log()_MicrosoftInternetConnectivity()_MSDNDataType()_PathFull/GetRelative/Split()_PathSplitEx()_PrintFromArray()_ProgressSetMarquee()_ReDim()_RockPaperScissors()/_RockPaperScissorsLizardSpock()_ScrollingCredits_SelfDelete()_SelfRename()_SelfUpdate()_SendTo()_ShellAll()_ShellFile()_ShellFolder()_SingletonHWID()_SingletonPID()_Startup()_StringCompact()_StringIsValid()_StringRegExpMetaCharacters()_StringReplaceWholeWord()_StringStripChars()_Temperature()_TrialPeriod()_UKToUSDate()/_USToUKDate()_WinAPI_Create_CTL_CODE()_WinAPI_CreateGUID()_WMIDateStringToDate()/_DateToWMIDateString()Au3 script parsingAutoIt SearchAutoIt3 PortableAutoIt3WrapperToPragmaAutoItWinGetTitle()/AutoItWinSetTitle()CodingDirToHTML5FileInstallrFileReadLastChars()GeoIP databaseGUI - Only Close ButtonGUI ExamplesGUICtrlDeleteImage()GUICtrlGetBkColor()GUICtrlGetStyle()GUIEventsGUIGetBkColor()Int_Parse() & Int_TryParse()IsISBN()LockFile()Mapping CtrlIDsOOP in AutoItParseHeadersToSciTE()PasswordValidPasteBinPosts Per DayPreExpandProtect GlobalsQueue()Resource UpdateResourcesExSciTE JumpSettings INISHELLHOOKShunting-YardSignature CreatorStack()Stopwatch()StringAddLF()/StringStripLF()StringEOLToCRLF()VSCROLLWM_COPYDATAMore Examples...

Updated: 04/09/2015

Share this post


Link to post
Share on other sites

what this Styles are I don't know?!

GUICtrlCreateCheckbox ( "text", left, top , width , height , style , exStyle )
Style ^

But thanks, il read! :huh2:


[font="helvetica, arial, sans-serif"]Hobby graphics artist, using gimp.Automating pc stuff, using AutoIt.Listening to music, using Grooveshark.[/font]Scripts:[spoiler]Simple ScreenshotSaves you alot of trouble when taking a screenshot!Don't remember what happened with this, but aperantly the exe is all i got.If you don't want to run it, simply don't._IsRun UDFIt figures out if the script has ben ran before based on the info in a ini file.If you don't want to use exactly what i wrote, you can use it as inspiration.[/spoiler]

Share this post


Link to post
Share on other sites

#6 ·  Posted (edited)

I understand what Styles are :huh2: I mean I don't know what combination of Styles will change the output if using GUICtrlRead(). Look at my second Example and you can see I implemented a couple (Styles) to change the Checkbox to a Button!

Edited by guinness

_AdapterConnections()_AlwaysRun()_AppMon()_AppMonEx()_BinaryBin()_CheckMsgBox()_CmdLineRaw()_ContextMenu()_ConvertLHWebColor()/_ConvertSHWebColor()_DesktopDimensions()_DisplayPassword()_DotNet_Load()/_DotNet_Unload()_Fibonacci()_FileCompare()_FileCompareContents()_FileNameByHandle()_FilePrefix/SRE()_FindInFile()_GetBackgroundColor()/_SetBackgroundColor()_GetConrolID()_GetCtrlClass()_GetDirectoryFormat()_GetDriveMediaType()_GetFilename()/_GetFilenameExt()_GetHardwareID()_GetIP()_GetIP_Country()_GetOSLanguage()_GetSavedSource()_GetStringSize()_GetSystemPaths()_GetURLImage()_GIFImage()_GoogleWeather()_GUICtrlCreateGroup()_GUICtrlListBox_CreateArray()_GUICtrlListView_CreateArray()_GUICtrlListView_SaveCSV()_GUICtrlListView_SaveHTML()_GUICtrlListView_SaveTxt()_GUICtrlListView_SaveXML()_GUICtrlMenu_Recent()_GUICtrlMenu_SetItemImage()_GUICtrlTreeView_CreateArray()_GUIDisable()_GUIImageList_SetIconFromHandle()_GUIRegisterMsg()_GUISetIcon()_Icon_Clear()/_Icon_Set()_IdleTime()_InetGet()_InetGetGUI()_InetGetProgress()_IPDetails()_IsFileOlder()_IsGUID()_IsHex()_IsPalindrome()_IsRegKey()_IsStringRegExp()_IsSystemDrive()_IsUPX()_IsValidType()_IsWebColor()_Language()_Log()_MicrosoftInternetConnectivity()_MSDNDataType()_PathFull/GetRelative/Split()_PathSplitEx()_PrintFromArray()_ProgressSetMarquee()_ReDim()_RockPaperScissors()/_RockPaperScissorsLizardSpock()_ScrollingCredits_SelfDelete()_SelfRename()_SelfUpdate()_SendTo()_ShellAll()_ShellFile()_ShellFolder()_SingletonHWID()_SingletonPID()_Startup()_StringCompact()_StringIsValid()_StringRegExpMetaCharacters()_StringReplaceWholeWord()_StringStripChars()_Temperature()_TrialPeriod()_UKToUSDate()/_USToUKDate()_WinAPI_Create_CTL_CODE()_WinAPI_CreateGUID()_WMIDateStringToDate()/_DateToWMIDateString()Au3 script parsingAutoIt SearchAutoIt3 PortableAutoIt3WrapperToPragmaAutoItWinGetTitle()/AutoItWinSetTitle()CodingDirToHTML5FileInstallrFileReadLastChars()GeoIP databaseGUI - Only Close ButtonGUI ExamplesGUICtrlDeleteImage()GUICtrlGetBkColor()GUICtrlGetStyle()GUIEventsGUIGetBkColor()Int_Parse() & Int_TryParse()IsISBN()LockFile()Mapping CtrlIDsOOP in AutoItParseHeadersToSciTE()PasswordValidPasteBinPosts Per DayPreExpandProtect GlobalsQueue()Resource UpdateResourcesExSciTE JumpSettings INISHELLHOOKShunting-YardSignature CreatorStack()Stopwatch()StringAddLF()/StringStripLF()StringEOLToCRLF()VSCROLLWM_COPYDATAMore Examples...

Updated: 04/09/2015

Share this post


Link to post
Share on other sites

I understand what Styles are ;) I mean I don't know what combination of Styles will change the output if using GUICtrlRead(). Look at my second Example and you can see I implemented a couple (Styles) to change the Checkbox to a Button!

Yes, i saw that.

Its probably there just to cover an unforseen event :huh2:

But thanks for the help.

I now think i got BitOr and BitAnd covered.

Also my program is now setup in a way i can easily add new checkboxes and feed them into the mix.

I could probably make it even more efficient by making it into arrays, but im not safe enough with arrays yet.

Here is the final code,everything nicely commented:

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#NoTrayIcon
Opt("GUIOnEventMode", 1)

#Region ### START Koda GUI section ###
;Create GUI
$Gui = GUICreate("Settings", 358, 196)
;If window is closed then exit
GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")

;Gui content
;Disable hide function
$CheckboxHide = GUICtrlCreateCheckbox("Disable Hide function", 16, 8, 321, 41)
;Disable Whats playing bubble
$CheckboxBubble = GUICtrlCreateCheckbox("Disable Whats playing bubble", 18, 45, 321, 41)
;Empty disable box
$CheckboxDisabled = GUICtrlCreateCheckbox("Disabled", 16, 86, 321, 41)
GUICtrlSetState(-1, $GUI_DISABLE)
;OK button
$ButtonOk = GUICtrlCreateButton("Ok", 30, 144, 129, 41, $WS_GROUP)
GUICtrlSetOnEvent(-1, "_ButtonOk")
;Cancel button
$ButtonCancel = GUICtrlCreateButton("Cancel", 198, 144, 129, 41, $WS_GROUP)
GUICtrlSetOnEvent(-1, "_Exit")
;Show gui
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

;Check for checkedness
Func _IsChecked($iControlID)
    Return BitAND(GUICtrlRead($iControlID), 1) = 1
EndFunc;==>_IsChecked

;Ok button function. Will check for checkmarks
Func _ButtonOk()
    ;Is hidden checked?
    If _IsChecked($CheckboxHide) Then
        $CheckboxHideData = "checked."
    Else
        $CheckboxHideData = "not checked."
    EndIf
    ;Is bubble checked?
    If _IsChecked($CheckboxBubble) Then
        $CheckboxBubbleData = "checked."
    Else
        $CheckboxBubbleData = "not checked."
    EndIf
    ;Is disabled checked?
    If _IsChecked($CheckboxDisabled) Then
        $CheckboxDisabledData = "checked."
    Else
        $CheckboxDisabledData = "not checked."
    EndIf

    MsgBox(64, "Checked?", "Hide function is  " & $CheckboxHideData & @CRLF & "Bubble function is " & $CheckboxBubbleData & @CRLF &  "Disabled function is " & $CheckboxDisabledData & @CRLF)
    ConsoleWrite("Hide function is  " & $CheckboxHideData & @CRLF & "Bubble function is " & $CheckboxBubbleData & @CRLF &  "Disabled function is " & $CheckboxDisabledData & @CRLF)
    Exit
EndFunc;==>_ButtonOk




;Exit function. Both clicking the cancel button and closing the gui will use the _Exit function!
Func _Exit()
    Exit
EndFunc;==>_Exit

[font="helvetica, arial, sans-serif"]Hobby graphics artist, using gimp.Automating pc stuff, using AutoIt.Listening to music, using Grooveshark.[/font]Scripts:[spoiler]Simple ScreenshotSaves you alot of trouble when taking a screenshot!Don't remember what happened with this, but aperantly the exe is all i got.If you don't want to run it, simply don't._IsRun UDFIt figures out if the script has ben ran before based on the info in a ini file.If you don't want to use exactly what i wrote, you can use it as inspiration.[/spoiler]

Share this post


Link to post
Share on other sites

I could probably make it even more efficient by making it into arrays, but im not safe enough with arrays yet.

When you do feel "safe" just have a look at this :huh2:

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#NoTrayIcon
#include <GUIConstantsEx.au3>

_Main()

Func _Main()
    Local $aControlID[4][2] = [[3, 2],[-1, "Hide Function"],[-1, "Bubble Function"],[-1, "Disabled Function"]], $iButton, $sData ; Create a 2D Array to store the ControlID & Name of the Checkbox for Output.

    GUICreate("Quick Example Using GUIGetMsg()")
    For $A = 1 To $aControlID[0][0]
        $aControlID[$A][0] = GUICtrlCreateCheckbox($aControlID[$A][1], 10, $A * 25, 120, 20)
    Next
    $iButton = GUICtrlCreateButton("OK", 5, $A * 25, 75, 25)
    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit

            Case $iButton
                $sData = "" ; Reset Data.
                For $A = 1 To $aControlID[0][0] ; Loop through Array checking ControlID's and creating correct output.
                    $sData &=  $aControlID[$A][1] & " is "
                    If _IsChecked($aControlID[$A][0]) Then
                        $sData &= "Checked."
                    Else
                        $sData &= "Not Checked."
                    EndIf
                    $sData &= @CRLF
                Next
                MsgBox(64, "Checked?", $sData)

        EndSwitch
    WEnd
EndFunc   ;==>_Main

Func _IsChecked($iControlID)
    Return BitAND(GUICtrlRead($iControlID), $GUI_CHECKED) = $GUI_CHECKED
EndFunc   ;==>_IsChecked

_AdapterConnections()_AlwaysRun()_AppMon()_AppMonEx()_BinaryBin()_CheckMsgBox()_CmdLineRaw()_ContextMenu()_ConvertLHWebColor()/_ConvertSHWebColor()_DesktopDimensions()_DisplayPassword()_DotNet_Load()/_DotNet_Unload()_Fibonacci()_FileCompare()_FileCompareContents()_FileNameByHandle()_FilePrefix/SRE()_FindInFile()_GetBackgroundColor()/_SetBackgroundColor()_GetConrolID()_GetCtrlClass()_GetDirectoryFormat()_GetDriveMediaType()_GetFilename()/_GetFilenameExt()_GetHardwareID()_GetIP()_GetIP_Country()_GetOSLanguage()_GetSavedSource()_GetStringSize()_GetSystemPaths()_GetURLImage()_GIFImage()_GoogleWeather()_GUICtrlCreateGroup()_GUICtrlListBox_CreateArray()_GUICtrlListView_CreateArray()_GUICtrlListView_SaveCSV()_GUICtrlListView_SaveHTML()_GUICtrlListView_SaveTxt()_GUICtrlListView_SaveXML()_GUICtrlMenu_Recent()_GUICtrlMenu_SetItemImage()_GUICtrlTreeView_CreateArray()_GUIDisable()_GUIImageList_SetIconFromHandle()_GUIRegisterMsg()_GUISetIcon()_Icon_Clear()/_Icon_Set()_IdleTime()_InetGet()_InetGetGUI()_InetGetProgress()_IPDetails()_IsFileOlder()_IsGUID()_IsHex()_IsPalindrome()_IsRegKey()_IsStringRegExp()_IsSystemDrive()_IsUPX()_IsValidType()_IsWebColor()_Language()_Log()_MicrosoftInternetConnectivity()_MSDNDataType()_PathFull/GetRelative/Split()_PathSplitEx()_PrintFromArray()_ProgressSetMarquee()_ReDim()_RockPaperScissors()/_RockPaperScissorsLizardSpock()_ScrollingCredits_SelfDelete()_SelfRename()_SelfUpdate()_SendTo()_ShellAll()_ShellFile()_ShellFolder()_SingletonHWID()_SingletonPID()_Startup()_StringCompact()_StringIsValid()_StringRegExpMetaCharacters()_StringReplaceWholeWord()_StringStripChars()_Temperature()_TrialPeriod()_UKToUSDate()/_USToUKDate()_WinAPI_Create_CTL_CODE()_WinAPI_CreateGUID()_WMIDateStringToDate()/_DateToWMIDateString()Au3 script parsingAutoIt SearchAutoIt3 PortableAutoIt3WrapperToPragmaAutoItWinGetTitle()/AutoItWinSetTitle()CodingDirToHTML5FileInstallrFileReadLastChars()GeoIP databaseGUI - Only Close ButtonGUI ExamplesGUICtrlDeleteImage()GUICtrlGetBkColor()GUICtrlGetStyle()GUIEventsGUIGetBkColor()Int_Parse() & Int_TryParse()IsISBN()LockFile()Mapping CtrlIDsOOP in AutoItParseHeadersToSciTE()PasswordValidPasteBinPosts Per DayPreExpandProtect GlobalsQueue()Resource UpdateResourcesExSciTE JumpSettings INISHELLHOOKShunting-YardSignature CreatorStack()Stopwatch()StringAddLF()/StringStripLF()StringEOLToCRLF()VSCROLLWM_COPYDATAMore Examples...

Updated: 04/09/2015

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0