Combo box question.

[Simmy]

Hi guys,

I hope you are all well and can help.

I have the following code, which simply lists folders in a combo box.

What Id like it to do, is when you load the form, have the combo box have a message in the textbox area of the combo box, to indicate what to do.

I currently DO have this. It says "test".

But, it also lists "test" as a selection in the combo box, which I dont want.

Is there a way guys, to list it just in the textbox area of the combo box, but not listed as an option in the dropdown?

Ive attached a screenshot.

Any help greatly appreciated.

#Include <File.au3>
#Include <Array.au3>
#include <GUIComboBox.au3>
#include <GuiConstantsEx.au3>
#include <Constants.au3>

$FileList=_FileListToArray(@DesktopDir,"*.*", 2)


If @Error=1 Then
MsgBox (0,"","No Files\Folders Found.")
Exit
EndIf

GUICreate('SOMETITLE', 500, 300)
$combo = GuiCtrlCreateCombo("Select a folder",30, 75, 220, 200)

GuiCtrlSetData($combo, "|" & _ArrayToString($FileList))

$iIndex = _GUICtrlComboBox_AddString($combo, "test")
_GUICtrlComboBox_SetCurSel($combo, $iIndex)

GUISetState()
Do
    $msg = GUIGetMsg()
Until $msg = $GUI_EVENT_CLOSE

Edited June 15, 2011 by Simmy

[guinness]

Like this >>

#include <Array.au3>
#include <File.au3>
#include <GUIComboBox.au3>
#include <GUIConstantsEx.au3>

_Main()

Func _Main()
    Local $aFileList, $hCombo, $iCombo

    $aFileList = _FileListToArray(@DesktopDir, "*.*", 2)
    If @error Then
        MsgBox(0, "", "No Files\Folders Found.")
        Exit
    EndIf

    GUICreate('Example Combo', 500, 300)
    $iCombo = GUICtrlCreateCombo("Select A Folder", 30, 75, 220, 200)
    $hCombo = GUICtrlGetHandle(-1)

    GUICtrlSetData($iCombo, "|" & _ArrayToString($aFileList))
    _GUICtrlComboBox_SetEditText($hCombo, "Select A Folder")

    GUISetState(@SW_SHOW)
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

Edited June 15, 2011 by guinness

[Simmy]

Hi Guiness,

Thank you so much. That is brilliant!

There is only one thing Id like modified in this example, and that is, Im trying to work out how to remove the entry in the dropdown for the count of elements in the array.

Ive attached a screendump of what I mean.

Thanks so much for your great help.

[guinness]

Use this >>

GUICtrlSetData($iCombo, "|" & _ArrayToString($aFileList, "|", 1))

Or if you like to do things yourself without using the Array UDF then >>

#include <File.au3>
#include <GUIComboBox.au3>
#include <GUIConstantsEx.au3>

_Main()

Func _Main()
    Local $aFileList, $hCombo, $iCombo, $sString

    $aFileList = _FileListToArray(@DesktopDir, "*.*", 2)
    If @error Then
        MsgBox(0, "", "No Files\Folders Found.")
        Exit
    EndIf
    For $A = 1 To $aFileList[0]
        $sString &= $aFileList[$A] & "|"
    Next

    GUICreate('Example Combo', 500, 300)
    $iCombo = GUICtrlCreateCombo("Select A Folder", 30, 75, 220, 200)
    $hCombo = GUICtrlGetHandle(-1)
    GUICtrlSetData(-1, $sString)

    GUICtrlSetData($iCombo, "|" & $sString)
    _GUICtrlComboBox_SetEditText($hCombo, "Select A Folder")

    GUISetState(@SW_SHOW)
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

Edited June 15, 2011 by guinness

[Simmy]

Awesome guiness. Thank you again.

I hope its okay to post questions on here.

I am new to autoit but really love learning it and learning off you kind gurus.

[guinness]

learning off you kind gurus.

Not at all, I've learnt by asking, trying, trying again & reading the Help File, plus I'm still learning. Also MVP's are the true Guru's not me