how to add ScrollBar to GUICtrlCreatePic

[jakalspop 0]

how to add ScrollBar to GUICtrlCreatePic

if pic bigger then GUICtrlCreatePic() will show pic full size

not just part of pic

[guinness 1,518]

Melba23 has a UDF for what you need >> Scrollbars

[jakalspop 0]

i try but all _GUIScrollbars_Generate can be add just for GUI not for GUICtrlCreatePic()

[Melba23 3,457]

jakalspop,

You need to create child GUI to hold the Pic control.

Here is an example using labels to fill the child - you will have to replace them with a Pic control containing your image:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include "GUIScrollbars_Ex.au3"

; Create the main GUI
$hGUI = GUICreate("Test", 500, 500)

GUISetState()

; Create the child
$hChild_GUI = GUICreate("Child", 300, 300, 100, 100, $WS_POPUP, $WS_EX_MDICHILD, $hGUI)

; Set coloured labels to show the scrolling
GUISetBkColor(0xFF0000)
GUICtrlCreateLabel("", 100, 100, 400, 400)
GUICtrlSetBkColor(-1, 0x00FF00)
GUICtrlCreateLabel("", 200, 200, 300, 300)
GUICtrlSetBkColor(-1, 0x0000FF)
GUICtrlCreateLabel("", 300, 300, 200, 200)
GUICtrlSetBkColor(-1, 0xFF0000)
GUICtrlCreateLabel("", 400, 400, 100, 100)
GUICtrlSetBkColor(-1, 0x00FF00)

GUISetState()

; Create the scrollbars in the child
$aAperture = _GUIScrollbars_Generate($hChild_GUI, 500, 500)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

All clear?

M23

[guinness 1,518]

Melba23 you beat me to it

[Melba23 3,457]

guinness,

Had I known I would have let you have the pleasure of replying!

M23

[guinness 1,518]

I think your Example said it better then mine would've.

Edited June 21, 2011 by guinness

[Melba23 3,457]

guinness,

Well, it is my UDF!

M23

[jakalspop 0]

here Example to show pic in any size

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include "GUIScrollbars_Ex.au3"
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#Include <GDIPlus.au3>
#include <WindowsConstants.au3>
; Create the main GUI
$hGUI = GUICreate("Test", 500, 500)
$File = "C:\Users\Public\Pictures\Sample Pictures\Penguins.jpg"
GUISetState()
_GDIPlus_Startup ()
$hImage =  _GDIPlus_ImageLoadFromFile($File)
$Width = _GDIPlus_ImageGetWidth($hImage)
$Height = _GDIPlus_ImageGetHeight($hImage)
_GDIPlus_ImageDispose($hImage)
_GDIPlus_ShutDown ()
MsgBox(0,$Height,$Width)
; Create the child
$hChild_GUI = GUICreate("Child", 300, 300, 100, 100, $WS_POPUP, $WS_EX_MDICHILD, $hGUI)
$Pic1 = GUICtrlCreatePic("", -1, -1,$Width, $Height)
GUICtrlSetImage(-1, $File)

GUISetState()

; Create the scrollbars in the child
$aAperture = _GUIScrollbars_Generate($hChild_GUI, $Width, $Height)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Edited June 21, 2011 by jakalspop

[Melba23 3,457]

jakalspop,

Does that mean you are happy with the code or do you still have problems?

M23

[jakalspop 0]

What you mean

Edited June 21, 2011 by jakalspop

[Melba23 3,457]

jakalspop,

but that example doesn't sport FTP Upload and HTTP Upload

Is that a question?

M23

Edit: I see you posted in the wrong thread. Glad you got your scrollbars working.

Edited June 21, 2011 by Melba23

[jakalspop 0]

now how to remove

$aAperture = _GUIScrollbars_Generate($hChild_GUI, $Width, $Height)

and back to real size of

$Pic1 = GUICtrlCreatePic("", -1, -1,400, 400)

[jakalspop 0]

sorry i forget how to re size of

GUICtrlCreatePic("", -1, -1, 721, 321)

to

GUICtrlCreatePic("", -1, -1, 400, 400)

[Melba23 3,457]

jakalspop,

1. To replace the scrollable GUI, just delete it and recreate a new Pic control in its place.

2. To resize a control, use GUICtrlSetPos.

This script shows how you do it with labels - you just use Pics:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include "GUIScrollbars_Ex.au3"

; Create the main GUI
$hGUI = GUICreate("Test", 500, 500)

$hButton_1 = GUICtrlCreateButton("Delete", 10, 10, 80, 30)
$hButton_2 = GUICtrlCreateButton("Resize", 410, 10, 80, 30)
GUICtrlSetState($hButton_2, $GUI_DISABLE)

GUISetState()

; Create the child
$hChild_GUI = GUICreate("Child", 300, 300, 100, 100, $WS_POPUP, $WS_EX_MDICHILD, $hGUI)

; Set coloured labels to show the scrolling
GUISetBkColor(0xFF0000)
GUICtrlCreateLabel("", 100, 100, 400, 400)
GUICtrlSetBkColor(-1, 0x00FF00)
GUICtrlCreateLabel("", 200, 200, 300, 300)
GUICtrlSetBkColor(-1, 0x0000FF)
GUICtrlCreateLabel("", 300, 300, 200, 200)
GUICtrlSetBkColor(-1, 0xFF0000)
GUICtrlCreateLabel("", 400, 400, 100, 100)
GUICtrlSetBkColor(-1, 0x00FF00)

GUISetState()

; Create the scrollbars in the child
$aAperture = _GUIScrollbars_Generate($hChild_GUI, 500, 500)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton_1
            GUIDelete($hChild_GUI)
            $hLabel = GUICtrlCreateLabel("", 100, 100, 300, 300)
            GUICtrlSetBkColor(-1, 0xFF0000)
            GUICtrlSetState($hButton_2, $GUI_ENABLE)
        Case $hButton_2
            GUICtrlSetPos($hLabel, 200, 200, 100, 100)
    EndSwitch
WEnd

All clear?

M23