Array delete blank element

[marshallprank 0]

Hi,

i have the following array with 2 blank elements:

dim $arr1[4]

$arr1[0]=""

$arr1[1]="ABC"

$arr1[2]=""

$arr1[3]="xyz"

i want now to delete the blank elements and put the result in a new Array --> this mean i will get in this case just two elemet in $arr2 and the length of the new array ($arr2) will be two:

$arr2[0]="ABC"

$arr2[1]="xyz"

any idea?

Thanks

Edited August 18, 2011 by marshallprank

[Melba23 3,457]

marshallprank,

Easy (when you know how)!

#include <Array.au3>

Global $Content_Subfolder_include[3] = ["", "ABC", ""]

; Copy the array
$arr_2 = $Content_Subfolder_include

; Move backwards through the array deleting the blank lines
For $i = UBound($arr_2) - 1 To 0 Step -1
    If $arr_2[$i] = "" Then
        _ArrayDelete($arr_2, $i)
    EndIf
Next

; Et voila!
_ArrayDisplay($arr_2)

Note you need to move backwards through the array when deleting lines or you end up with element indexing errors.

All clear?

M23

Edit: And it still works if you add an element to the initial array as you have just done in your edit. But do rermember to increase the dimension size of the initial array if you do that.

Edited August 18, 2011 by Melba23

[wakillon 403]

Something like this ?

#include <Array.au3>

dim $arr1[4]
$arr1[0]=""
$arr1[1]="ABC"
$arr1[2]=""
$arr1[3]="xyz"


$arr2 = _RemoveEmptyArrayElements ( $arr1 )
_ArrayDisplay ( $arr2 )

Func _RemoveEmptyArrayElements ( $_Array )
    Local $_Item
    For $_Element In $_Array
        If $_Element= '' Then
            _ArrayDelete ( $_Array, $_Item )
        Else
            $_Item+=1
        EndIf
    Next
    Return ( $_Array )
EndFunc ;==> _RemoveEmptyArrayElements ( )

[marshallprank 0]

thank you very much for help

[hannes08 39]

If you have big arrays I suggest you to do the following:

#include <array.au3>

dim $arr1[4]
$arr1[0]=""
$arr1[1]="ABC"
$arr1[2]=""
$arr1[3]="xyz"

$s_array = _ArrayToString($arr1, "|")
$s_array = StringReplace($s_array, "||", "|")

$arr2 = StringSplit($s_array, "|", 2)

It is much faster than _ArrayDelete() because you don't have to redim the array all the time.

[Melba23 3,457]

Hannes123,

Nice piece of lateral thinking there!

M23

[aNewLyfe 0]

If you have big arrays I suggest you to do the following:

#include <array.au3>

dim $arr1[4]
$arr1[0]=""
$arr1[1]="ABC"
$arr1[2]=""
$arr1[3]="xyz"

$s_array = _ArrayToString($arr1, "|")
$s_array = StringReplace($s_array, "||", "|")

$arr2 = StringSplit($s_array, "|", 2)

It is much faster than _ArrayDelete() because you don't have to redim the array all the time.

thanks for this

[Bowmore 97]

An example of how to remove blanks using only the original array.

Func _ArryRemoveBlanks(ByRef $arr)
  $idx = 0
  For $i = 0 To UBound($arr) - 1
    If $arr[$i] <> "" Then
      $arr[$idx] = $arr[$i]
      $idx += 1
    EndIf
  Next
  ReDim $arr[$idx]
EndFunc ;==>_ArryRemoveBlanks

;Some code just to show it working
#include <array.au3>
Dim $arr1[10]
$arr1[0] = ""
$arr1[1] = "ABC"
$arr1[2] = ""
$arr1[3] = "xyz"
$arr1[4] = "def"
$arr1[5] = ""
$arr1[6] = ""
$arr1[7] = "ffr"
$arr1[8] = ""
$arr1[9] = "Z33"

_ArrayDisplay($arr1, "Before")
_ArryRemoveBlanks($arr1)
_ArrayDisplay($arr1, "After")

Edited August 18, 2011 by Bowmore

[monoscout999 10]

An example of how to remove blanks using only the original array.

Func _ArryRemoveBlanks(ByRef $arr)
  $idx = 0
  For $i = 0 To UBound($arr) - 1
    If $arr[$i] <> "" Then
      $arr[$idx] = $arr[$i]
      $idx += 1
    EndIf
  Next
  ReDim $arr[$idx]
EndFunc ;==>_ArryRemoveBlanks

;Some code just to show it working
#include <array.au3>
Dim $arr1[10]
$arr1[0] = ""
$arr1[1] = "ABC"
$arr1[2] = ""
$arr1[3] = "xyz"
$arr1[4] = "def"
$arr1[5] = ""
$arr1[6] = ""
$arr1[7] = "ffr"
$arr1[8] = ""
$arr1[9] = "Z33"

_ArrayDisplay($arr1, "Before")
_ArryRemoveBlanks($arr1)
_ArrayDisplay($arr1, "After")

Nice Method i like this one

[Oblivionx 1]

If you have big arrays I suggest you to do the following:

#include <array.au3>

dim $arr1[4]
$arr1[0]=""
$arr1[1]="ABC"
$arr1[2]=""
$arr1[3]="xyz"

$s_array = _ArrayToString($arr1, "|")
$s_array = StringReplace($s_array, "||", "|")

$arr2 = StringSplit($s_array, "|", 2)

It is much faster than _ArrayDelete() because you don't have to redim the array all the time.

Have you tried it yet?In fact, it's slowest method when convert to string and redim new array )

[guinness 1,519]

Oblivionx,

Have you seen the date of that post? Try not to make a habit of necroing threads, especially when you have nothing useful to contribute. Thanks.

[atwolf359 1]

Old solution, new to me, thank you Bowmore.

for my own purposes i changed the the line

If $arr[$i] <> "" Then

  To:      

If StringStripWS($arr[$i], 8) <> "" Then

to remove white space which is not null

[iamtheky 927]

I think you should have gone back further to Hannes answer and then have some nested fun

#include <array.au3>

dim $arr1[5]
$arr1[0]=""
$arr1[1]="ABC"
$arr1[2]=""
$arr1[3]="xyz"
$arr1[4]=""

_ArrayDisplay(StringSplit(StringRegExpReplace(StringRegExpReplace(_ArrayToString($arr1, "|"), "(\A\|)|(\|\z)", "") , "(\|\|)" , "|") , "|" , 2))

 

[BrewManNH 1,305]

[iamtheky 927]

Because the forums are a veritable hotbed of activity today this will throw everything off, what were we thinking.

[Nas 2]

@Bowmore thank you so much for your script helped me a lot.