_FindInFile()

[LurchMan]

Hey everyone -

Below is my version of a find in file program with example. Let me know your thoughts.

expandcollapse popup

#include <file.au3>
#include <array.au3>
 
#region===========Example
$sDir = @ScriptDir & "\test"
$sStringToFind = "you found me!"
 
$sRtn = _FindInFiles ($sDir, $sStringToFind) ;Search all files in dir, not case sensitive
 
If @error Then
    ConsoleWrite("return code: " & $sRtn & " @error: " & @error & @CRLF)
Else
    _ArrayDisplay ($sRtn)
EndIf
#endregion========Example
 
 
; #FUNCTION# ====================================================================================================================
; Name...........: _FindInFiles
; Description ...: Finds a specified string within all (or specified type of) files within a directory
; Syntax.........: _FindInFiles ($sPath, $sFindString[, $sFilter="*"[, $iCase=0]])
; Parameters ....: $sPath   - Directory to look in.
;                 $sFilter - Optional: the filter to use, default is *. Search the Autoit3 helpfile for the word "WildCards" For details.
;                 $iCase   - Optional: specifies whether search string is case sensitive
;                 |$iCase=0(Default) Not case sensitive
;                 |$iCase=1 Case sensitive
; Return values .: Failure: Returns 0 and sets @error:
;                           @error 1 = String not found
;                           @error 2 = No Files found with specified directory with specified file filter
;                 Success: Array containing results (See remarks for array format)
; Author ........: LurchMan
; Modified.......:
; Remarks .......: The array returned is two-dimensional and is made up as follows:
;                               $array[0][0] = Number of results
;                                $array[n][0] = Full path to file
;                               $array[n][1] = Line the search string appears in the file
;                               $array[n][2] = Position on the line
; Related .......:
; Link ..........:
; Example .......: Yes
; Note ..........:
; ===============================================================================================================================
Func _FindInFiles ($sPath, $sFindString, $sFilter="*", $iCase=0)
    Local $aReturn[1][3] = [["0","",""]]
 
    If StringRight ($sPath, 1) <> "\" Then $sPath &= "\"
 
    $aFiles = _FileListToArray ($sPath, $sFilter, 1)
    If @error Then
        SetError (2)
        Return 0
    EndIf
 
    For $iFile = 1 To $aFiles[0]
        $hFile = FileOpen ($sPath & $aFiles[$iFile], 0)
        $sRead = FileRead ($hFile)
        FileClose ($hFile)
 
        If StringInStr ($sRead, $sFindString, $iCase) Then
            $aSplit = StringSplit ($sRead, @LF)
            For $iLine = 1 To $aSplit[0]
                $iPOS = StringInStr ($aSplit[$iLine], $sFindString, $iCase)
                If $iPOS > 0 Then
                    ReDim $aReturn[UBound($aReturn)+1][3]
                    $aReturn[UBound($aReturn)-1][0] = $sPath & $aFiles[$iFile]
                    $aReturn[UBound($aReturn)-1][1] = $iLine
                    $aReturn[UBound($aReturn)-1][2] = $iPOS
                    $aReturn[0][0] = $aReturn[0][0] + 1
                EndIf
            Next
        EndIf
    Next
 
    If $aReturn[0][0] = 0 Then
        SetError(1)
        Return 0
    Else
        Return $aReturn
    EndIf
EndFunc

[guinness]

The function is OK, but a couple of points ... you should point out that it doesn't search in subdirectories and instead of ReDimming everytime by 1 why not reduce the number of ReDim's to multiplying by 2 and checking if a ReDim is required.

- This version can search in subdirectories too by using FindStr & explains how to use Arrays effectively when using the ReDim function in AutoIt, you will see the difference in speed.