Sign in to follow this  
Followers 0
Chimp

_GUICtrlListView_Create inside a TabItem is it possible?

6 posts in this topic

hello,

I try to create a _GUICtrlListView_Create inside a Tabitem without success.

Am I wrong or is not possible?

thanks to who can help me.

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#Include <GuiEdit.au3>
Opt("GUIOnEventMode", 1)
$Form1_1 = GUICreate("Main Form", 623, 482, 354, 209)
$Input1 = GUICtrlCreateInput("", 8, 24, 57, 21)
GUICtrlSetOnEvent(-1, "Input1Change")
$Label1 = GUICtrlCreateLabel("Input box", 8, 5, 55, 17)

$Tab1 = GUICtrlCreateTab(8, 56, 601, 377)

$TabSheet1 = GUICtrlCreateTabItem("TabSheet1")

; the following _GUICtrlListView_Create DO NOT APPEAR

$lstview = _GUICtrlListView_Create($TabSheet1, "Column 0|Column 1|Column 2|Column 3|Column 4", 15, 90, 500, 300) ; x, y, w, h
_GUICtrlListView_SetColumnWidth($lstview, 0, 100) ; Column 0
_GUICtrlListView_SetColumnWidth($lstview, 1, 100) ; Column 1
_GUICtrlListView_SetColumnWidth($lstview, 2, 100) ; Column 2
_GUICtrlListView_SetColumnWidth($lstview, 3, 100) ; Column 3
_GUICtrlListView_SetColumnWidth($lstview, 4, 100) ; Column 4
_GUICtrlListView_SetExtendedListViewStyle($lstview, $LVS_EX_GRIDLINES) ; a grid inside the _GUICtrlListView

$TabSheet2 = GUICtrlCreateTabItem("TabSheet2")

$TabSheet3 = GUICtrlCreateTabItem("TabSheet3")

GUICtrlCreateTabItem("")

GUISetState(@SW_SHOW)
While 1
Sleep(100)
WEnd
Func Form1_1Close()
Exit
EndFunc
Func Input1Change()
_GUICtrlListView_AddItem($lstview, _GUICtrlEdit_GetText($Input1)) ; just a test
EndFunc

small minds discuss people average minds discuss events great minds discuss ideas.... and use AutoIt....

Share this post


Link to post
Share on other sites



#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#Include <GuiEdit.au3>
Opt("GUIOnEventMode", 1)
$Form1_1 = GUICreate("Main Form", 623, 482, 354, 209)
$Input1 = GUICtrlCreateInput("", 8, 24, 57, 21)
GUICtrlSetOnEvent(-1, "Input1Change")
$Label1 = GUICtrlCreateLabel("Input box", 8, 5, 55, 17)

$Tab1 = GUICtrlCreateTab(8, 56, 601, 377)

$TabSheet1 = GUICtrlCreateTabItem("TabSheet1")

; the following _GUICtrlListView_Create DO NOT APPEAR

$lstview = GUICtrlCreateListView("Column 0|Column 1|Column 2|Column 3|Column 4", 15, 90, 500, 300) ; x, y, w, h
_GUICtrlListView_SetColumnWidth($lstview, 0, 100) ; Column 0
_GUICtrlListView_SetColumnWidth($lstview, 1, 100) ; Column 1
_GUICtrlListView_SetColumnWidth($lstview, 2, 100) ; Column 2
_GUICtrlListView_SetColumnWidth($lstview, 3, 100) ; Column 3
_GUICtrlListView_SetColumnWidth($lstview, 4, 100) ; Column 4
_GUICtrlListView_SetExtendedListViewStyle($lstview, $LVS_EX_GRIDLINES) ; a grid inside the _GUICtrlListView

$TabSheet2 = GUICtrlCreateTabItem("TabSheet2")

$TabSheet3 = GUICtrlCreateTabItem("TabSheet3")

GUICtrlCreateTabItem("")

GUISetState(@SW_SHOW)
While 1
Sleep(100)
WEnd
Func Form1_1Close()
Exit
EndFunc
Func Input1Change()
_GUICtrlListView_AddItem($lstview, _GUICtrlEdit_GetText($Input1)) ; just a test
EndFunc

Share this post


Link to post
Share on other sites

Have you tried GUICtrlCreateListView? There are plenty of examples using Tabs and ListViews with the AutoIt native controls.


_AdapterConnections()_AlwaysRun()_AppMon()_AppMonEx()_BinaryBin()_CheckMsgBox()_CmdLineRaw()_ContextMenu()_ConvertLHWebColor()/_ConvertSHWebColor()_DesktopDimensions()_DisplayPassword()_DotNet_Load()/_DotNet_Unload()_Fibonacci()_FileCompare()_FileCompareContents()_FileNameByHandle()_FilePrefix/SRE()_FindInFile()_GetBackgroundColor()/_SetBackgroundColor()_GetConrolID()_GetCtrlClass()_GetDirectoryFormat()_GetDriveMediaType()_GetFilename()/_GetFilenameExt()_GetHardwareID()_GetIP()_GetIP_Country()_GetOSLanguage()_GetSavedSource()_GetStringSize()_GetSystemPaths()_GetURLImage()_GIFImage()_GoogleWeather()_GUICtrlCreateGroup()_GUICtrlListBox_CreateArray()_GUICtrlListView_CreateArray()_GUICtrlListView_SaveCSV()_GUICtrlListView_SaveHTML()_GUICtrlListView_SaveTxt()_GUICtrlListView_SaveXML()_GUICtrlMenu_Recent()_GUICtrlMenu_SetItemImage()_GUICtrlTreeView_CreateArray()_GUIDisable()_GUIImageList_SetIconFromHandle()_GUIRegisterMsg()_GUISetIcon()_Icon_Clear()/_Icon_Set()_IdleTime()_InetGet()_InetGetGUI()_InetGetProgress()_IPDetails()_IsFileOlder()_IsGUID()_IsHex()_IsPalindrome()_IsRegKey()_IsStringRegExp()_IsSystemDrive()_IsUPX()_IsValidType()_IsWebColor()_Language()_Log()_MicrosoftInternetConnectivity()_MSDNDataType()_PathFull/GetRelative/Split()_PathSplitEx()_PrintFromArray()_ProgressSetMarquee()_ReDim()_RockPaperScissors()/_RockPaperScissorsLizardSpock()_ScrollingCredits_SelfDelete()_SelfRename()_SelfUpdate()_SendTo()_ShellAll()_ShellFile()_ShellFolder()_SingletonHWID()_SingletonPID()_Startup()_StringCompact()_StringIsValid()_StringRegExpMetaCharacters()_StringReplaceWholeWord()_StringStripChars()_Temperature()_TrialPeriod()_UKToUSDate()/_USToUKDate()_WinAPI_Create_CTL_CODE()_WinAPI_CreateGUID()_WMIDateStringToDate()/_DateToWMIDateString()Au3 script parsingAutoIt SearchAutoIt3 PortableAutoIt3WrapperToPragmaAutoItWinGetTitle()/AutoItWinSetTitle()CodingDirToHTML5FileInstallrFileReadLastChars()GeoIP databaseGUI - Only Close ButtonGUI ExamplesGUICtrlDeleteImage()GUICtrlGetBkColor()GUICtrlGetStyle()GUIEventsGUIGetBkColor()Int_Parse() & Int_TryParse()IsISBN()LockFile()Mapping CtrlIDsOOP in AutoItParseHeadersToSciTE()PasswordValidPasteBinPosts Per DayPreExpandProtect GlobalsQueue()Resource UpdateResourcesExSciTE JumpSettings INISHELLHOOKShunting-YardSignature CreatorStack()Stopwatch()StringAddLF()/StringStripLF()StringEOLToCRLF()VSCROLLWM_COPYDATAMore Examples...

Updated: 04/09/2015

Share this post


Link to post
Share on other sites

Pincopanco,

If you use UDF-created controls you need to deal with the hide/show code yourself: :)

#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <GuiEdit.au3>

Opt("GUIOnEventMode", 1)

$Form1_1 = GUICreate("Main Form", 623, 482, 354, 209)
GUISetOnEvent($GUI_EVENT_CLOSE, "Form1_1Close")

$Input1 = GUICtrlCreateInput("", 8, 24, 57, 21)
GUICtrlSetOnEvent(-1, "Input1Change")

$Label1 = GUICtrlCreateLabel("Input box", 8, 5, 55, 17)

$Tab1 = GUICtrlCreateTab(8, 56, 601, 377)
GUICtrlSetOnEvent($Tab1, "_Tab_Toggle")

$TabSheet1 = GUICtrlCreateTabItem("TabSheet1")

$TabSheet2 = GUICtrlCreateTabItem("TabSheet2")

$TabSheet3 = GUICtrlCreateTabItem("TabSheet3")

GUICtrlCreateTabItem("")

$lstview = _GUICtrlListView_Create($Form1_1, "Column 0|Column 1|Column 2|Column 3|Column 4", 15, 90, 500, 300) ; x, y, w, h
_GUICtrlListView_SetColumnWidth($lstview, 0, 100) ; Column 0
_GUICtrlListView_SetColumnWidth($lstview, 1, 100) ; Column 1
_GUICtrlListView_SetColumnWidth($lstview, 2, 100) ; Column 2
_GUICtrlListView_SetColumnWidth($lstview, 3, 100) ; Column 3
_GUICtrlListView_SetColumnWidth($lstview, 4, 100) ; Column 4
_GUICtrlListView_SetExtendedListViewStyle($lstview, $LVS_EX_GRIDLINES) ; a grid inside the _GUICtrlListView

GUISetState(@SW_SHOW)

While 1
    Sleep(100)
WEnd

Func _Tab_Toggle()
    Switch GUICtrlRead($Tab1)
        Case 0
            ControlShow($Form1_1, "", $lstview)
        Case 1, 2
            ControlHide($Form1_1, "", $lstview)
    EndSwitch
EndFunc

Func Form1_1Close()
    Exit
EndFunc   ;==>Form1_1Close

Func Input1Change()
    _GUICtrlListView_AddItem($lstview, _GUICtrlEdit_GetText($Input1)) ; just a test
EndFunc   ;==>Input1Change

I recommend the Tabs tutorial in the Wiki if you want more information on how to work with tabs. ;)

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites

looking at the solutions, now the concept is more clear for me

Thank you all


small minds discuss people average minds discuss events great minds discuss ideas.... and use AutoIt....

Share this post


Link to post
Share on other sites

GREAT!

That's what I was looking for!

Anyways, it looks that listview borders are missing ! :mellow:

I've tried with _GUICtrlListView_SetExtendedListViewStyle() without luck... :

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0