Correct way to populate this 2-dimensional array?

[lavascript]

So... this doesn't work.

#include <Array.au3>

Local $aTest1[3] = ["Thing1 Thing2 Thing3","Thing4 Thing5 Thing6","Thing7 Thing8 Thing9"]

Local $aTest2[3][3]
For $i = 0 to UBound($aTest1)
$aTest2[$i] = StringSplit($aTest1[$i]," ")
Next

_ArrayDisplay($aTest2)

It seems that a 2-dimensional array is completely different from an array in which every element is an array.

The result I'm hoping for is:

$aTest2[0][0] = "Thing1"
$aTest2[0][1] = "Thing2"
$aTest2[0][2] = "Thing3"
$aTest2[1][0] = "Thing4"
$aTest2[1][1] = "Thing5"
$aTest2[1][2] = "Thing6"
$aTest2[2][0] = "Thing7"
$aTest2[2][1] = "Thing8"
$aTest2[2][2] = "Thing9"

[guinness]

#include <Array.au3>

Local $aArray_1[3] = ['Thing1 Thing2 Thing3', 'Thing4 Thing5 Thing6', 'Thing7 Thing8 Thing9']

Local Const $iUBound = UBound($aArray_1)
Local $aArray_2[3][3], $aSplit = 0
For $i = 0 To $iUBound - 1
    $aSplit = StringSplit($aArray_1[$i], ' ', 2)
    For $j = 0 To UBound($aSplit) - 1
        $aArray_2[$i][$j] = $aSplit[$j]
    Next
Next
_ArrayDisplay($aArray_2)

Edited February 28, 2013 by guinness

[Melba23]

lavascript,

You need to extract the elements before loading them into the array:

#include <Array.au3>

Local $aTest1[3] = ["Thing1 Thing2 Thing3", "Thing4 Thing5 Thing6", "Thing7 Thing8 Thing9"]

Local $aTest2[3][3]
For $i = 0 To UBound($aTest1) - 1
    $aTemp = StringSplit($aTest1[$i], " ", 2)
    For $j = 0 To UBound($aTemp) - 1
        $aTest2[$i][$j] = $aTemp[$j]
    Next
Next

_ArrayDisplay($aTest2)

All clear?

M23

[Nessie]

Try this:

#include <Array.au3>

Local $aTest1[3] = ["Thing1 Thing2 Thing3","Thing4 Thing5 Thing6","Thing7 Thing8 Thing9"]

Local $aTest2[3][3]
For $i = 0 to UBound($aTest1) - 1
$split = StringSplit($aTest1[$i]," ", 2)
For $x = 0 To UBound($split) - 1
$aTest2[$i][$x] = $split[$x]
Next
Next

_ArrayDisplay($aTest2)

Hi!

Edited February 28, 2013 by Nessie

[lavascript]

Thanks!

I knew I could do it with nested For loops, that just didn't seem like the "right" way.

[GMK]

Local $aTest1[3][3] = [["Thing1", "Thing2", "Thing3"], ["Thing4", "Thing5", "Thing6"], ["Thing7", "Thing8", "Thing9"]]

...or to make it more readable:

Local $aTest1[3][3] = [ _
     ["Thing1", "Thing2", "Thing3"], _
     ["Thing4", "Thing5", "Thing6"], _
     ["Thing7", "Thing8", "Thing9"] _
     ]