StringRegExp to get time in miliseconds

[Hyflex]

Basically, I have a counter which counts down and i'm trying to get the time left in milliseconds...

Potential string formats:
Updates in: x hours xx minutes
Updates in: x hours xx minutes

Updates in: xx minutes xx seconds

Updates in: xx minutes xx seconds

Updates in: xx seconds

Updates in: x seconds

I've been trying a few things but none are working :/

$sResults = StringRegExp("Updates In: 22 hours, 13 minutes",'<b>Updates In:(.*)</b>',3)
$sSingleResult = $sResults[0]

If StringRegExp($sSingleResult, "hours") Then
ConsoleWrite(StringRegExp($sSingleResult, "(.*?)hours") & @CRLF)
$hours = True
EndIf
If StringRegExp($sSingleResult, "minutes") Then
ConsoleWrite(StringRegExp($sSingleResult, "minutes") & @CRLF)
$minutes = True
EndIf
If StringRegExp($sSingleResult, "(.*?) seconds") Then
ConsoleWrite(StringRegExp($sSingleResult, "(.*?)seconds") & @CRLF)
$seconds = True
EndIf
 
If StringMid($sSingleResult, 4, 5) = "hours" Then
$HoursIntoMiliseconds = StringMid($sSingleResult, 2, 1) * 3600000
$MinutesIntoMiliSeconds= StringMid($sSingleResult, 11, 2) * 60000
$TotalTime = $HoursIntoMiliseconds + $MinutesIntoMiliSeconds
Else
$MinutesIntoMiliSeconds = StringMid($sSingleResult, 2, 2) * 60000
EndIf

Edited June 3, 2013 by Hyflex

[jdelaney]

try this out:

$string = "Updates in: 12 hours 12 minutes"

$array = StringRegExp($string, "(\d+)\s(\w+)", 4)

$iMilli = 0
For $i = 0 To UBound($array)-1
    $aTemp = $array[$i]
    Switch $aTemp[2]
        Case "hours"
            $iAddition = $aTemp[1]*(60*60*1000)
        Case "minutes"
            $iAddition = $aTemp[1]*(60*1000)
        Case "seconds"
            $iAddition = $aTemp[1]*(1000)
        Case Else
            MsgBox(1,1,"this one is not a covered 'Case'...add it in, and re-run=[" & $aTemp[2] & "].")
            $iAddition = 0
    EndSwitch
    $iMilli += $iAddition
Next

ConsoleWrite($iMilli & @CRLF)

Edited June 3, 2013 by jdelaney

[Hyflex]

Works beautifully, I don't quite understand how you achieved that...

Could you explain how that was done, it's something to do with the regexp I assume. 

Edited June 3, 2013 by Hyflex

[jdelaney]

just looking for digits followed by letters.  Each grouping found is returned into it's own array (that's the option 4 on stringregexp)...then i loop through those returned groups, switch out based on the string, multiply, and add onto a variable.

Edit: I just added a fail checker as well...

Edited June 3, 2013 by jdelaney

[guinness]

There is also this site, which is a cheat sheet for regular expressions.

[Zedna]

@jdelaney

Very nice example for using StringRegExp() with mode 4!

This should be as example in Helpfile for StringRegExp()