Send Email - Very Simple

[MadaraUchiha]

Hello,

I like to send an email from my AutoIt script, and I like to have it as simple as possible.

I tried the example from the help file:

#include <Inet.au3>

Local $s_SmtpServer = "mysmtpserver.com.au"
Local $s_FromName = "My Name"
Local $s_FromAddress = "From eMail Address"
Local $s_ToAddress = "To eMail Address"
Local $s_Subject = "My Test UDF"
Local $as_Body[2]
$as_Body[0] = "Testing the new email udf"
$as_Body[1] = "Second Line"
Local $Response = _INetSmtpMail($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject, $as_Body)
Local $err = @error
If $Response = 1 Then
    MsgBox(0, "Success!", "Mail sent")
Else
    MsgBox(0, "Error!", "Mail failed with error code " & $err)
EndIf

It returns me: Mail failed with error code 50. 

Why is that?

Helpfile tells me about this:

 

@error: 1 - Invalid Parameters   2 - Unable to start TCP   3 - Unable to resolve IP   4 - Unable to create socket   5x - Cannot open SMTP session. x indicates the index number of last command issued to the SMTP server.   50x - Cannot send body. x indicates the line number of $as_Body (first line is 0).   5000 - Cannot close SMTP session

 

Where is my error? My credentials and email adress are correct (already checked that twice).

I know there are some large UDF's out there about email sending, but I like to have it as short/simple as possible, so I can understand it properly.

What's wrong with that code?

[water]

_INetSMTPMail has a trace flag. Maybe you get better debugging information?

[AdamUL]

I had a similar issue, try this.

Local $Response = _INetSmtpMail($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject, $as_Body, @ComputerName, -1) 

Adam

Edited November 20, 2013 by AdamUL

[BrewManNH]

Does your SMTP mail server require you to use a username and password? If it does, then that function will not work for you.

[MadaraUchiha]

This doesnt work for me:s

I have a gmail address.

I already have the big email UDF from Jos: '?do=embed' frameborder='0' data-embedContent>>

Its working fine.

But I like to make the email code very simple and clear to understand.

So I am looking for a short and qasy to understand solution.

_InetSmtpMail() doesn't work.

Are there other options?

[BrewManNH]

You already linked your only option.

I'm not sure why you think it's not simple to use, it's a single function, and all you have to do is supply it with the right information. Do you have any understanding of what _INetSMTPMail is doing? Yet you're willing to try and make that work (which it won't for what you want) but not willing to use a function that does work?

[rudi]

hi

use fileinstall() and blat.exe, it simply works, always...

regards, Rudi

[greichert]

On 11/20/2013 at 12:23 PM, AdamUL said:

I had a similar issue, try this.

 

 

Local $Response = _INetSmtpMail($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject, $as_Body, @ComputerName, -1)

Adam

I used the above code and receive the message that it was successful and mail was sent. Though I never receive an email. Any reason for this? could it be a firewall issue? If so how would I be able to find out?

[Jos]

This is a 5 years old thread.  
Send to which Email service? A local SMTP server or what else?

Jos

[xcaliber13]

I found this script awhile back on this forum.  This works great for me.  Simple to use and understand.  I use it in 100's of scripts. 

expandcollapse popup

;Send Email
; Variables
;##################################
$SmtpServer = ""                  ; address for the smtp-server to use - REQUIRED
$FromName = ""                    ; name from who the email was sent
$FromAddress = ""                 ; address from where the mail should come
$ToAddress = ""                   ; destination address of the email - REQUIRED
$Subject = ""                     ; subject from the email - can be anything you want it to be
$Body = ""                        ; the messagebody from the mail - can be left blank but then you get a blank mail
$AttachFiles = ""                 ; the file(s) you want to attach seperated with a ; (Semicolon) - leave blank if not needed
$CcAddress = ""                   ; address for cc - leave blank if not needed
$BccAddress = ""                  ; address for bcc - leave blank if not needed
$Importance = "Normal"            ; Send message priority: "High", "Normal", "Low"
$Username = ""                    ; username for the account used from where the mail gets sent - REQUIRED
$Password = ""                    ; password for the account used from where the mail gets sent - REQUIRED
$IPPort = 0                       ; port used for sending the mail
$ssl = 0                          ; enables/disables secure socket layer sending - put to 1 if using httpS
;~ $IPPort=465                    ; GMAIL port used for sending the mail
;~ $ssl=1                         ; GMAILenables/disables secure socket layer sending - put to 1 if using httpS


;##################################
; Script
;##################################
Global $oMyRet[2]
Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")
$rc = _INetSmtpMailCom($SmtpServer, $FromName, $FromAddress, $ToAddress, $Subject, $Body, $AttachFiles, $CcAddress, $BccAddress, $Importance, $Username, $Password, $IPPort, $ssl)
If @error Then
    MsgBox(0, "Error sending message", "Error code:" & @error & "  Description:" & $rc)
EndIf

; The UDF
Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $as_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $s_Importance="Normal", $s_Username = "", $s_Password = "", $IPPort = 25, $ssl = 0)
    Local $objEmail = ObjCreate("CDO.Message")
    $objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
    $objEmail.To = $s_ToAddress
    Local $i_Error = 0
    Local $i_Error_desciption = ""
    If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
    If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
    $objEmail.Subject = $s_Subject
    If StringInStr($as_Body, "<") And StringInStr($as_Body, ">") Then
        $objEmail.HTMLBody = $as_Body
    Else
        $objEmail.Textbody = $as_Body & @CRLF
    EndIf
    If $s_AttachFiles <> "" Then
        Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
        For $x = 1 To $S_Files2Attach[0]
            $S_Files2Attach[$x] = _PathFull($S_Files2Attach[$x])
;~          ConsoleWrite('@@ Debug : $S_Files2Attach[$x] = ' & $S_Files2Attach[$x] & @LF & '>Error code: ' & @error & @LF) ;### Debug Console
            If FileExists($S_Files2Attach[$x]) Then
                ConsoleWrite('+> File attachment added: ' & $S_Files2Attach[$x] & @LF)
                $objEmail.AddAttachment($S_Files2Attach[$x])
            Else
                ConsoleWrite('!> File not found to attach: ' & $S_Files2Attach[$x] & @LF)
                SetError(1)
                Return 0
            EndIf
        Next
    EndIf
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
    If Number($IPPort) = 0 then $IPPort = 25
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $IPPort
    ;Authenticated SMTP
    If $s_Username <> "" Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
    EndIf
    If $ssl Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
    EndIf
    ;Update settings
    $objEmail.Configuration.Fields.Update
    ; Set Email Importance
    Switch $s_Importance
        Case "High"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "High"
        Case "Normal"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "Normal"
        Case "Low"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "Low"
    EndSwitch
    $objEmail.Fields.Update
    ; Sent the Message
    $objEmail.Send
    If @error Then
        SetError(2)
        Return $oMyRet[1]
    EndIf
    $objEmail=""
EndFunc   ;==>_INetSmtpMailCom


;; Com Error Handler
Func MyErrFunc()
    $HexNumber = Hex($oMyError.number, 8)
    $oMyRet[0] = $HexNumber
    $oMyRet[1] = StringStripWS($oMyError.description, 3)
    ConsoleWrite("### COM Error !  Number: " & $HexNumber & "   ScriptLine: " & $oMyError.scriptline & "   Description:" & $oMyRet[1] & @LF)
    SetError(1); something to check for when this function returns
    Return
EndFunc   ;==>MyErrFunc

 

[Jos]

1 minute ago, xcaliber13 said:

I found this script awhile back on this forum.

Yea, wonder who made that 

[Juvigy]

Hi Jos,

I tried your code with my google account and $server = "smtp.google.com"

Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $s_Username = "", $s_Password = "", $IPPort = 465, $ssl = 1)

And i get an error:

Description:The transport failed to connect to the server.

Is it because i am behind a automatic proxy configuration script? Or maybe smtp traffic is disabled?  How can i check that?

I tried

telnet smtp.google.com 465

and it diesnt work.

[Jos]

I doubt it will ever work when your (companies) proxy doesn't allow port 465.

Jos