dynamic vars, tabs and assign

[ReDFlaG]

Hello,

i'm trying to generate a various number of tabs that are each one "linked" to a variable name so that i can guiswitch.

i got issue when i try to switch between tabs because the variable are not declared.

here's the code

$mainwindow=GUICreate ('Fiber Switch Monitor',850,750,-1,-1,$WS_SIZEBOX+$WS_SYSMENU)
$hTab = GUICtrlCreateTab(5, 10,800, 700)
GUISetState()

For $i = 1 To UBound($arr_switch) - 1
    assign ("hTab_"&$i , GUICtrlCreateTabItem("Switch "&$arr_switch[$i][1]),2)
Next

;this popup ok and eval values are: 7 , 8 , 9 and 10. donno why.
For $i = 1 To UBound($arr_switch) - 1
        $temp=Eval("hTab_"&$i)
        If IsDeclared("hTab_"&$i) Then
           MsgBox(0, "hTab_"&$i&" declared", "eval: "&$temp)
        EndIf
Next

;this fail
GUISwitch($mainwindow, $hTab_1)
GUICtrlCreateCheckbox("port #",20,20,70,50)

If you can provide some help?

Thanks a lot

[BrewManNH]

Don't use eval and assign, use an array to hold the tab control ids, it's a lot easier.

[guinness]

Or an associative array?

#include <MsgBoxConstants.au3>

; Search Scripting.Dictionary on google or such-like.
Example()

Func Example()
    Local $hAssocArray = 0
    _AssociativeArray_Startup($hAssocArray, False) ; Create an associative array that is case-insensitive.
    For $i = 1 To 100
        $hAssocArray.Item($i) = 'Item_' & $i
    Next
    MsgBox($MB_SYSTEMMODAL, '', $hAssocArray.Item(Random(1, 100, 1))) ; Display random entry.
EndFunc   ;==>Example

Func _AssociativeArray_Startup(ByRef $aArray, $fIsCaseSensitive = False) ; Idea from MilesAhead.
    Local $fReturn = False
    $aArray = ObjCreate('Scripting.Dictionary')
    ObjEvent('AutoIt.Error', '__AssociativeArray_Error')
    If IsObj($aArray) Then
        $aArray.CompareMode = Int(Not $fIsCaseSensitive)
        $fReturn = True
    EndIf
    Return $fReturn
EndFunc   ;==>_AssociativeArray_Startup

Edited January 15, 2014 by guinness

[MHz]

If you use Assign, then you access with Eval. You did it in the loop yet you did not do it in GUISwitch().

GUISwitch($mainwindow, Eval("hTab_1"))

And these numbers below

 

;this popup ok and eval values are: 7 , 8 , 9 and 10. donno why.

are control ids. You store them so you can access the controls (tabs) by the id number.

[jdelaney]

Since you already have the array declared, you can add an additional count on the second dimention, which can house your controlid's.

ReDim $arr_switch[UBound($arr_switch)][UBound($arr_switch,2)+1]
For $i = 1 To UBound($arr_switch) - 1
    $arr_switch[$i][UBound($arr_switch)-1] = GUICtrlCreateTabItem("Switch "&$arr_switch[$i][1])
Next

A better way, so you can always reference the proper item in the array, in the future:

ReDim $arr_switch[UBound($arr_switch)][UBound($arr_switch,2)+1]
$iarr_switch_ControlID = UBound($arr_switch,2)-1
For $i = 1 To UBound($arr_switch) - 1
    $arr_switch[$i][$iarr_switch_ControlID] = GUICtrlCreateTabItem("Switch "&$arr_switch[$i][1])
Next

Edited January 15, 2014 by jdelaney

[ReDFlaG]

Many thanks for your answers! Each one had provided me the help i needed