StringRegExp expression help

[AutID]

Hello,

I have some strings and they are foramtted like this:

random1 - some random text

random2 - some other random text

againrandom - again random text

etc...etc

How can i delete everything from the minus sign and behind?

so a line like this: randomstart - some other random things become randomstart.

I know this must be easy but i never understood @replaces.

Cheers

 

[reb]

This will work

#include <Array.au3>

$a = "randomstart - some other random things become randomstart."
$array = StringSplit($a,"-")
_ArrayDisplay($array,"$array")
MsgBox(0,"Desired",$array[1])

REB

[PhoenixXL]

Example with Regex

#include <Array.au3>

$a = "randomstart - some other random things become randomstart." & @CRLF & "random2 - something more of random"
$Result = StringRegExp($a, "(?m)^([^ \-]+)", 3)
_ArrayDisplay($Result, "Result")

[Malkey]

Using StringRegExpReplace example.

Local $a = "randomstart - some other random things become randomstart." & @CRLF & _
        "random2 - something more of random" & @CRLF & _
        "againrandom - again random text" & @CRLF & _
        "etc...etc"

; Match everything you want to delete.
; \h* - Match all horizontal white spaces before a minus sign (if any Horiz. white spaces exist),
; -   - match the minus sign, and
; \V* - match all non-vertical white space characters (if any non-vert. white spaces exist).
; and replace the entire match with nothing.
$Result = StringRegExpReplace($a, "\h*-\V*", "")
;or
;$Result = StringRegExpReplace($a, "(?m)\h*-.*$", "") ; Using (?m) Multiline: ^ and $ matching start and end of line.

ConsoleWrite($Result & @LF)

#cs Returns:-
randomstart
random2
againrandom
etc...etc
#ce

[AutID]

Thank you everyone.

I wanted to avoid using stringsplit. Malkey's solution seems the best one that fits to my needs.
 

[guinness]

Thank you everyone.

I wanted to avoid using stringsplit. Malkey's solution seems the best one that fits to my needs.

 

I enjoy regular expressions, but avoiding StringSplit() with no reason as to why is kind of silly.

[AutID]

I enjoy regular expressions, but avoiding StringSplit() with no reason as to why is kind of silly.

Silly things are for silly people, which i am not. But i am not sure if someone else here is. Since i am avoiding it there is a reason. And i didn't feel that i should explain it.

But if you can't live with that then i will let you know.

I don't want to turn a string into an array without having to. And that is also the reason why i marked Malkey's solution as solved and not Phoenixs' since they are both regular expressions.

Edited January 21, 2014 by AutID