How to use _WinAPI_AddIconOverlay on my Scripts Tray Icon

[BigDaddyO]

I have a script that that connects to other computers using a shared network drive.

If access to that shared drive hasn't been updated in a while, or is gone, I want to update the System Tray Icon for my script to have a grey x or red x or green check overlayed on it for a short time.

I can do all this using the _WinAPI_AddIconOverlay example for an Icon in a GUI, but every time I try to apply the overlay to a tray icon I just get a generic system icon.

Is there even a way to save the overlayed icon to a new .ico file so I can set it using the TraySetIcon?

Any ideas?

Thanks,

Mike

[BrewManNH]

TraySetIcon will allow you to change the tray icon for your program.

[Yashied]

_WinAPI_SaveHICONToFile() allow you to create .ico file but there is a better way.

 

#Include <APIConstants.au3>
#Include <WinAPIEx.au3>

Opt('TrayMenuMode', 1)

$hAutoIt = WinGetHandle(AutoItWinGetTitle())

$Exit = TrayCreateItem('Exit')
TraySetClick(8)

$hIcon1 = _WinAPI_ShellExtractIcon(@SystemDir & '\shell32.dll', 77, 16, 16)
$hIcon2 = _WinAPI_ShellExtractIcon(@SystemDir & '\shell32.dll', 22, 16, 16)
$hIcon = _WinAPI_AddIconOverlay($hIcon1, $hIcon2)
_WinAPI_DestroyIcon($hIcon2)
_WinAPI_DestroyIcon($hIcon2)

$tNID = DllStructCreate($tagNOTIFYICONDATA)
DllStructSetData($tNID, 'Size', DllStructGetSize($tNID))
DllStructSetData($tNID, 'hWnd', $hAutoIt)
DllStructSetData($tNID, 'Flags', $NIF_ICON)
DllStructSetData($tNID, 'ID', 1)
DllStructSetData($tNID, 'hIcon', $hIcon)
_WinAPI_ShellNotifyIcon($NIM_MODIFY, $tNID)

While 1
    Switch TrayGetMsg()
        Case $Exit
            Exit
    EndSwitch
WEnd

Edited December 31, 2014 by Yashied

[BigDaddyO]

Thanks Yashied!

That DLLStruct stuff was exactly what I was missing.