Adding Text

[TheDcoder]

you are finding out why.

 

Hints Appreciated

TD

[water]

Can't you add this information at the end of the file? Or in a second file with the same name but a different filetype? Or in a ADS?

[TheDcoder]

Can't you add this information at the end of the file?

Yes, I can, but still I would like to know if there is a way....

Or in a ADS?

Would you mind expanding "ADS"?

TD

[water]

Alternate Data Streams. A feature of the NTFS filesystem.

[TheDcoder]

Thanks water, I want my log files to survive in ext file-systems too

[water]

As long as it is NTFS you are fine.

[JohnOne]

I do not think ADS survives transport from one disk to another does it?

[TheDcoder]

I do not think ADS survives transport from one disk to another does it?

If transferred internally using 2 hard-disk in the same system with NTFS file system being used in both hard-disks, It will survive....

(Or a USB formatted in NTFS would carry the file safely )

[water]

ADS is ignored "when the file is copied or moved to another file system without ADS support, attached to an e-mail, or uploaded to a website."

[BrewManNH]

Here is a VERY simple way to add something to the start of a text file.

#include <FileConstants.au3>
$sFilename = @ScriptDir & "\Test.txt"
$hFile = FileOpen($sFilename, 2) ; create new file
For $I = 1 to 10000
    FileWriteLine($hFile, "Line: " & $I) ; create 10,000 lines of text
Next
FileClose($hFile) ; close the file

; Only this part is needed to add something to the start of the file, the top part is just to create the test file.

$hFile = FileOpen($sFilename, 1) ; open file for append
FileSetPos($hFile, 0, $file_begin) ; move the file pointer to the start of the file
FileWriteLine($hFile, "I am line No. 1 now :P") ; write the line to the file
FileWriteLine($hFile, " "); write a blank line to the file
FileClose($hFile)

It never reads the file itself, so it doesn't matter how large it is.

[water]

When file was created:

Line: 1
Line: 2
Line: 3
Line: 4
Line: 5
Line: 6
Line: 7
...

 

After the script has ended:

I am line No. 1 now
 
Line: 4
Line: 5
Line: 6
Line: 7

...

 

So it doesn't insert lines but simply overwrites them.

[SadBunny]

Writing 5 years worth of log into a single file is extremely unwieldy. How about getting Cygwin and writing an awk or perl oneliner to divide the logfile into multiple files, say per day or per month? Or even make an autoitscript to do that? IMHO that would be a much better use of your time.

If I were you, I would go looking for a way to have the base application rotate its logfiles and/or reconfigure the logging properties. If not possible, plan B would be to write some sort of daily repeating operation (like a cronjob) to rename the logfile to another name (logfile.<date> comes to mind) as a sort of deus-ex-machina log rotation mechanism. Don't know if there's enough letters in the alphabet to assign a 5-years-old-but-still-active logfile a plan letter

[TheDcoder]

@SadBunny You can refer to >this post

TD

[mpower]

TheDcoder, did you even bother looking at the two links I posted?

expandcollapse popup

If Not FileExists(_CygwinDir()) Then ;if cygwin directory doesnt exist on system drive
    MsgBox(16, 'Error', 'Please install Cygwin [http://cygwin.com/install.html]')
    Exit
ElseIf Not FileExists(_CygwinDir() & '\bin\ed.exe') Then ;if ed.exe doesn't exist
    MsgBox(16, 'Error', 'Please ensure ed package for Cygwin is installed - it is located under Editors in the Cygwin installer [http://cygwin.com/install.html].')
    Exit
EndIf

$sFilename = _CygwinDir() & '\home\' & @UserName & '\test.txt'
$hFile = FileOpen($sFilename, 2) ; create new file
For $i = 1 to 10000
    FileWriteLine($hFile, "Line with some text: " & $i) ; create 10,000 lines of text
Next
FileClose($hFile) ; close the file

$myfile = 'test.txt'
$command = "ed -s "&$myfile&" << 'EOF'"&@CR&"0a"&@CR&"prepend these lines"&@CR&"to the beginning"&@CR&"."&@CR&"w"&@CR&"EOF"

$cygwin = ShellExecute(_CygwinDir() & '\Cygwin.bat') ;run cygwin
$hWnd = WinWaitActive('~') ;wait for console
ControlSend($hwnd, "", "", $command) ;send ed command
ControlSend($hwnd, "", "", "{ENTER}") ;execute command
Sleep(1000)
WinKill($hWnd)
MsgBox(0, 'Done', "Ta-Da!")
ShellExecute(_CygwinDir() & '\home\' & @UserName & '\') ;open the home directory

Func _CygwinDir()
    Local $CygwinDir
    Switch @OSArch
        Case "X86"
            $CygwinDir = "\cygwin"
        Case "X64"
            $CygwinDir = "\cygwin64"
    EndSwitch
    $systemdrive = EnvGet('systemdrive')
    Return $systemdrive & $CygwinDir
EndFunc

That's one way of doing it.

I'm sure its also doable without having the cygwin window visible (probably by just passing command as an argument) but it is beyond my autoit/programming skills.

Edited March 16, 2015 by mpower

[TheDcoder]

TheDcoder, did you even bother looking at the two links I posted?

Sorry mpower, When I saw the word "cygwin" my mind instantly ignored your post... Although your idea works but installing cygwin is a burden in itself. I need a more simple & universal way of doing it, hope you don't mind my ignorance or rude kind of behavior

Your work is greatly appreciated

TD

[BrewManNH]

Sorry about the post above, lack of proper testing on my part. This script will not overwrite the text in the file, but will add the new text above it.

;~ #include <FileConstants.au3>
#include <File.au3>
$sFilename = @ScriptDir & "\Test.txt"
$hFile = FileOpen($sFilename, 2) ; create new file
For $I = 1 To 10000
    FileWriteLine($hFile, "Line: " & $I) ; create 10,000 lines of text
Next
FileClose($hFile) ; close the file

; Only this part is needed to add something to the start of the file, the top part is just to create the test file.
$hFile1 = FileOpen(@ScriptDir & "\Dummy.txt", 2) ; create dummy file, can be deleted later in the script or reused for other files
FileWriteLine($hFile1, "I am line No. 1 now :P ") ; write the line to the file
FileWriteLine($hFile1, " ")
FileClose($hFile1) ; close the file
RunWait(@ComSpec & " /c copy /b " & @ScriptDir & "\Dummy.txt + " & $sFilename & " " & @ScriptDir & "\test1.txt", "", @SW_HIDE) ; copy the dummy file to the top of the text file and create a new temp file
FileMove(@ScriptDir & "\test1.txt", $sFilename, $FC_OVERWRITE) ; overwrite the original file with the temp file, deleting the temp file

[mpower]

 

Sorry about the post above, lack of proper testing on my part. This script will not overwrite the text in the file, but will add the new text above it.

;~ #include <FileConstants.au3>
#include <File.au3>
$sFilename = @ScriptDir & "\Test.txt"
$hFile = FileOpen($sFilename, 2) ; create new file
For $I = 1 To 10000
    FileWriteLine($hFile, "Line: " & $I) ; create 10,000 lines of text
Next
FileClose($hFile) ; close the file

; Only this part is needed to add something to the start of the file, the top part is just to create the test file.
$hFile1 = FileOpen(@ScriptDir & "\Dummy.txt", 2) ; create dummy file, can be deleted later in the script or reused for other files
FileWriteLine($hFile1, "I am line No. 1 now :P ") ; write the line to the file
FileWriteLine($hFile1, " ")
FileClose($hFile1) ; close the file
RunWait(@ComSpec & " /c copy /b " & @ScriptDir & "\Dummy.txt + " & $sFilename & " " & @ScriptDir & "\test1.txt", "", @SW_HIDE) ; copy the dummy file to the top of the text file and create a new temp file
FileMove(@ScriptDir & "\test1.txt", $sFilename, $FC_OVERWRITE) ; overwrite the original file with the temp file, deleting the temp file

This takes the cake, well done! I stand corrected, cygwin is not needed after all  

I thought your solution might have problems with larger files but after testing on a ~140mb file with 10,000,000 lines it took only 0.2 seconds to prepend the lines. I am confident it will work with much larger files without any issues also.