Entering passwords

[Graeme]

I have code to enter password using the setting $ES_PASSWORD. It seems that with this setting you can't enter more than the letters that fill box. Can anyone tell me how to enter more characters?

GUICreate("Password Test",500,200)
    $Input = GUICtrlCreateInput("Password",10,20,40,50,$ES_PASSWORD)
GUISetState(@SW_SHOW,"Password Test")
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            GUISetState(@SW_HIDE,"Password Test")
            ExitLoop
    EndSwitch
WEnd
If GUICtrlRead($Input) <> "" Then MsgBox(0,GUICtrlRead($Input),"Done")

With this code you can only enter 4 characters of password.

[water]

With using $ES_Password you have dropped all other default style values. You need to add them using something like this:

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>

GUICreate("Password Test", 500, 200)
$Input = GUICtrlCreateInput("Password", 10, 20, 40, 20, BitOR($ES_PASSWORD, $ES_AUTOHSCROLL))
$OK = GUICtrlCreateButton("OK", 60, 20, 40, 20)
GUISetState(@SW_SHOW, "Password Test")
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            GUISetState(@SW_HIDE, "Password Test")
            ExitLoop
        Case $OK
            MsgBox(0, "Password", "Password has " & StringLen(GUICtrlRead($Input)) & " characters!")
    EndSwitch
WEnd

BTW: When posting code, please post a fully working script with all needed includes etc. Makes testing much easier und faster

[kylomas]

or

BitOR($ES_PASSWORD, $GUI_SS_DEFAULT_INPUT)

 

[water]

Even better and more flexible

[Graeme]

Thanks to both of you! Sorry about missing the includes.