Dropdown menu from INI file

[silver2002]

hi guys

im new here and need your help

i wanna create dropdown menu with list of keys from INI file and when i choose key i need to show Value outside of dropdown menu (like just show result)

i hope u understand what i need

example of ini

[Phone]
John Johnson=1234567890
Jack Jackson=2345678901
Dany Danson=0987654321

so in dropdown menu by selecting key (ex.John Johnson) i need see result on screen

i searching for some similar code but i cant find any

[careca]

The basic idea is to read the ini, and then grab that list and populate the drop down, then when you select the item in the dropdown, read it and put the value wherever you want.

I would start with IniReadSection, create the combo box with GUICtrlCreateCombo and go from there.

Edited January 11, 2019 by careca

[silver2002]

i dont know how... i need basic script

[TheXman]

11 minutes ago, silver2002 said:

i need basic script

The help file is FULL of example scripts.  You should start with example scripts for the functions that @careca suggested.  The more effort you show, the more help you're likely to get. 

[Subz]

Welcome to AutoIt, here is a basic script to get you started, use the help file to understand how it works.

#include <Array.au3>
#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $iUserList
    ;~ Get data from ini file
    Local $aUserInfo = IniReadSection(@ScriptDir & "\test.ini", "Phone")
        If @error Then Exit MsgBox(4096, "Error", "Error opening ini file")

    Local $hGUI = GUICreate("User Info", 305, 200)
    Local $idUserList = GUICtrlCreateCombo("Select User", 10, 10, 150, 20)
        ;~ Add names from the array.
        GUICtrlSetData($idUserList, _ArrayToString($aUserInfo, "|", 1, -1, "|", 0, 0), "Select User")
    Local $idUserPhone = GUICtrlCreateLabel("", 170, 13, 150, 20)
    GUICtrlSetFont(-1, 11, 800)
    Local $idButton_Close = GUICtrlCreateButton("Close", 210, 170, 85, 25)

    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idButton_Close
                ExitLoop
            Case $idUserList
                $iUserList = _GUICtrlComboBox_GetCurSel($idUserList)
                GUICtrlSetData($idUserPhone, $aUserInfo[$iUserList][1])
        EndSwitch
    WEnd
    GUIDelete($hGUI)
EndFunc

 

[silver2002]

thank you very much

ill analyze script now to see how it work...

[silver2002]

ok... now im stuck on another problem...

i dont know if that possible but i would like show some pic (splash screen) from ini file

i try this but not work:

#include <Array.au3>
#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $iUserList
    ;~ Get data from ini file
    Local $aUserInfo = IniReadSection(@ScriptDir & "\test.ini", "Phone")
        If @error Then Exit MsgBox(4096, "Error", "Error opening ini file")

    Local $hGUI = GUICreate("User Info", 305, 200)
    Local $idUserList = GUICtrlCreateCombo("Select User", 10, 10, 150, 20)
        ;~ Add names from the array.
        GUICtrlSetData($idUserList, _ArrayToString($aUserInfo, "|", 1, -1, "|", 0, 0), "Select User")
    Local $idUserPhone = GUICtrlCreateLabel("", 170, 13, 150, 20)
    GUICtrlSetFont(-1, 11, 800)
    Local $idButton_Close = GUICtrlCreateButton("Close", 210, 170, 85, 25)

    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idButton_Close
                ExitLoop
            Case $idUserList
                $iUserList = _GUICtrlComboBox_GetCurSel($idUserList)
                $showpic = GUICtrlSetData($idUserPhone, $aUserInfo[$iUserList][1])
                SplashImageOn("Splash Screen", $showpic, 400, 400, -1, -1, $DLG_NOTITLE)
                Sleep(5000)
        EndSwitch
    WEnd
    GUIDelete($hGUI)
EndFunc

and test.ini is:

[Phone]
John Johnson=john.bmp
Jack Jackson=jack.bmp
Dany Danson=dany.bmp

 

[Subz]

You would need to use the array item or use GuiCtrlRead for $idUserPhone.  You could also look at GuiCtrlCreatePic if you wanted it embedded in the Gui, just read the help file for more information.

Case $idUserList
                $iUserList = _GUICtrlComboBox_GetCurSel($idUserList)
                GUICtrlSetData($idUserPhone, $aUserInfo[$iUserList][1])
                SplashImageOn("Splash Screen", $aUserInfo[$iUserList][1], 400, 400, -1, -1, $DLG_NOTITLE)
                ;~ Or
                ;~ SplashImageOn("Splash Screen", GUICtrlRead($idUserPhone), 400, 400, -1, -1, $DLG_NOTITLE)
        EndSwitch

 

[silver2002]

thank you again !!!

i readed help file but i need a looottt of knowledge for sure...