Jump to content
kurtykurtyboy

GuiFlatButton UDF : Change Colors of Regular Buttons

Recommended Posts

GuiFlatButton is a UDF to easily create regular buttons with different colors for background, foreground, border, hover, focus, etc..

This started as an effort to change the background color of a button and eventually grew into a full UDF.

If you've looked around forums for changing button background colors, you have probably noticed that each proposed workaround has its own set of issues/side-effects. The answers usually circle back to 'use ownerdrawn buttons' and 'not worth it'. Well, now it is possible for anyone to easily create ownerdrawn buttons - totally worth it!

Some issues with other workarounds such as drawing with GDI+ or using a colored label as a 'button':

  • Not 'real' buttons so you lose built-in functionality that windows gives to buttons
  • Messy / inefficient code in the main while loop to check for mouse position
  • Slow to respond to click, paint, etc...
  • Having to deal with GUIRegisterMsg messages
  • Not straight-forward to implement

GuiFlatButton is not a workaround; it is a technique to respond to Windows' built-in owner-drawn button events.
With minimal effort, we can now create true simple colored buttons.

The idea is to create an owner-drawn button using GUICtrlCreateButton then subclass the GUI and controls to handle the button-specific events to paint it however we want.
This UDF magically does all of this for us! No need to worry about event handling or main while loop logic.

 

How to use

It couldn't be any easier! Simply create a new button using the familiar syntax. This creates an ownerdrawn button with default colors.

$mybutton1 = GuiFlatButton_Create("Button 1", 78, 20, 120, 40)

If you want to change the background and text colors:

GuiFlatButton_SetBkColor(-1, 0x5555FF)
GuiFlatButton_SetColor(-1, 0xFFFFFF)

Advanced Usage

Set background/text/border all at once

GuiFlatButton_SetColors(-1, 0x0000FF, 0xFFFFFF, 0x9999FF)

Set ALL colors for ALL button states! (normal, focus, hover, selected)

Local $aColorsEx = [0x0000FF, 0xFFFFFF, -2, 0x4444FF, 0xFFFFFF, 0xAAAAFF, 0x6666FF, 0xFFFFFF, 0xCCCCFF, 0x0000EE, 0xFFFFFF, 0x7777EE]
GuiFlatButton_SetColorsEx(-1, $aColorsEx)

Set default colors to apply to any future buttons

;set colors
GuiFlatButton_SetDefaultColors(0x0000FF, 0xFFFFFF, 0x9999FF)
;create buttons
$mybutton1 = GuiFlatButton_Create("Button 1", 12, 20, 120, 40)
$mybutton2 = GuiFlatButton_Create("Button 2", 143, 20, 120, 40)

Set ALL color defaults

;set colors
Local $aColorsEx = [0x0000FF, 0xFFFFFF, -2, 0x4444FF, 0xFFFFFF, 0xAAAAFF, 0x6666FF, 0xFFFFFF, 0xCCCCFF, 0x0000EE, 0xFFFFFF, 0x7777EE]
GuiFlatButton_SetDefaultColorsEx($aColorsEx)
;create buttons
$mybutton1 = GuiFlatButton_Create("Button 1", 12, 20, 120, 40)
$mybutton2 = GuiFlatButton_Create("Button 2", 143, 20, 120, 40)

 

Available Functions

Spoiler

;  GuiFlatButton_Create ................: Create a new flat button
;  GuiFlatButton_Read ..................: Read the display text of the button
;  GuiFlatButton_SetData ...............: Set the display text of the button
;  GuiFlatButton_SetBkColor ............: Set button background color
;  GuiFlatButton_SetColor ..............: Set button foreground/text color
;  GuiFlatButton_SetColors .............: Set background, foreground, border colors at the same time
;  GuiFlatButton_SetColorsEx ...........: Set background, foreground, border colors for ALL states at the same time
;  GuiFlatButton_SetDefaultColors ......: Set background, foreground, border colors to be used for all future buttons
;  GuiFlatButton_SetDefaultColorsEx ....: Set background, foreground, border colors for ALL states to be used for all future buttons
;  GuiFlatButton_GetState ..............: Get the state of the button
;  GuiFlatButton_SetState ..............: Set the state of the button
;  GuiFlatButton_Delete ................: Remove subclasses and delete the control
;  GuiFlatButton_SetPos ................: Changes the position of a control

 

Simple Example
image.png.7d6038f62647449282e67cdc1fa4a8b2.png

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include "GuiFlatButton.au3"

Example()

;GUI with one button
Func Example()

    Local $hGUI, $mybutton1

    $hGUI = GUICreate("GuiFlatButton Ex0", 275, 120)
    GUISetBkColor(0x333333)

    $idLabel = GUICtrlCreateLabel("Click the button", 10, 100, 150, 30)
    GUICtrlSetColor(-1, 0xFFFFFF)

    ;create new button then set the background and foreground colors
    $mybutton1 = GuiFlatButton_Create("Button 1", 78, 20, 120, 40)
    GuiFlatButton_SetBkColor(-1, 0x5555FF)
    GuiFlatButton_SetColor(-1, 0xFFFFFF)

    GUISetState(@SW_SHOW, $hGUI)

    Local $i = 0
    Local $iMsg
    While 1
        $iMsg = GUIGetMsg()

        Switch $iMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $mybutton1
                $i += 1
                GUICtrlSetData($idLabel, $i)
                ConsoleWrite($i & @CRLF)
        EndSwitch

        Sleep(10)
    WEnd

    GUIDelete()
EndFunc   ;==>Example


Menu/Toolbar Example
image.png.a039ca4a859fa1f2691d743ca0f0cf57.png

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include "GuiFlatButton.au3"

Example()

;Example GUI with toolbar
Func Example()

    Local $hGUI, $idLabel, $aButtons, $iTbSize

    $hGUI = GUICreate("GuiFlatButton Ex2", 300, 200)
    GUISetBkColor(0x444444)

    $idLabel = GUICtrlCreateLabel("Click a button", 10, 180, 150, 30)
    GUICtrlSetColor(-1, 0xFFFFFF)

    $aButtons = createToolbar()
    $iTbSize = UBound($aButtons)

    GUISetState(@SW_SHOW, $hGUI)

    Local $i = 0
    Local $iMsg
    While 1
        $iMsg = GUIGetMsg()

        Switch $iMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $aButtons[0] To $aButtons[$iTbSize - 1]
                ConsoleWrite("1")
                GUICtrlSetData($idLabel, GuiFlatButton_Read($iMsg))

        EndSwitch

        Sleep(10)
    WEnd

    GUIDelete()
EndFunc   ;==>Example


Func createToolbar()
    Local $aButtons[6]
    Local $bkColor = 0x777777
    Local $textColor = 0xFFFFFF
    Local $borderColor = 0x999999
    Local $aBtnClrs[12] = [0x777777, 0xFFFFFF, $GUI_BKCOLOR_TRANSPARENT, 0x888888, 0xFFFFFF, $GUI_BKCOLOR_TRANSPARENT, 0x999999, 0xFFFFFF, $GUI_BKCOLOR_TRANSPARENT, 0x666666, 0xFFFFFF, $GUI_BKCOLOR_TRANSPARENT]

    For $i = 0 To UBound($aButtons) - 1
        $aButtons[$i] = GuiFlatButton_Create("B" & $i, $i * 50, 0, 50, 17)
        GuiFlatButton_SetColorsEx($aButtons[$i], $aBtnClrs)
    Next

    Return $aButtons
EndFunc   ;==>createToolbar

 

Icon Example
You can even easily add icons to your buttons -- just create a new button and send it an icon!

image.png.875340f295b0a17f10774b95c05a1673.png

#include <GDIPlus.au3>
#include "GuiFlatButton.au3"

Example()

;buttons with Icon images
Func Example()

    ;get images for demonstration
    _GDIPlus_Startup() ;initialize GDI+
    Local $hIcon = _WinAPI_ShellExtractIcon(@SystemDir & '\shell32.dll', 258, 24, 24)   ;extract the 'Save' icon
    Local $hBitmap = _GDIPlus_BitmapCreateFromHICON($hIcon)                             ;Create Bitmap from Icon (for demonstration)
    Local $hHBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap)                  ;Create HBitmap from Bitmap
    _GDIPlus_BitmapDispose($hBitmap)                                                    ;dispose the bitmap
    _GDIPlus_Shutdown() ;done with GDI+

    Local $hGUI = GUICreate("GuiFlatButton Ex5", 255, 400)
    GUISetBkColor(0xEEEEEE)

    ;set default colors of future buttons
    Local $aColorsEx = _
    [0xE2E5E8, 0X000000, 0x888888, _    ; normal    : Background, Text, Border
     0xE2E5E8, 0X000000, 0x333333, _    ; focus     : Background, Text, Border
     0xE8E8E8, 0X000000, 0x666666, _    ; hover     : Background, Text, Border
     0xDDDDDD, 0X000000, 0xAAAAAA]      ; selected  : Background, Text, Border
    GuiFlatButton_SetDefaultColorsEx($aColorsEx)

    ;normal button with icon
    $label1 = GUICtrlCreateLabel( "$BS_TOOLBUTTON -->", 5, 10)
    GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
    Local $mybutton1 = GuiFlatButton_Create("Save", 130, 5, 50, 48, $BS_TOOLBUTTON)
    _WinAPI_DeleteObject(_SendMessage(GUICtrlGetHandle($mybutton1), $BM_SETIMAGE, $IMAGE_ICON, $hIcon))

    ;align top
    Local $mybuttonT = GuiFlatButton_Create("Top", 5, 65, 120, 55, $BS_TOP)
    _WinAPI_DeleteObject(_SendMessage(GUICtrlGetHandle($mybuttonT), $BM_SETIMAGE, $IMAGE_ICON, $hIcon))

    ;align top-left
    Local $mybuttonTL = GuiFlatButton_Create("Top-Left", 5, 125, 120, 55, BITOR($BS_TOP, $BS_LEFT))
    _WinAPI_DeleteObject(_SendMessage(GUICtrlGetHandle($mybuttonTL), $BM_SETIMAGE, $IMAGE_ICON, $hIcon))

    ;align top-right
    Local $mybuttonTR = GuiFlatButton_Create("Top-Right", 5, 185, 120, 55, BITOR($BS_TOP, $BS_RIGHT))
    _WinAPI_DeleteObject(_SendMessage(GUICtrlGetHandle($mybuttonTR), $BM_SETIMAGE, $IMAGE_ICON, $hIcon))

    ;align left
    Local $mybuttonL = GuiFlatButton_Create("Left", 5, 245, 120, 55, $BS_LEFT)
    _WinAPI_DeleteObject(_SendMessage(GUICtrlGetHandle($mybuttonL), $BM_SETIMAGE, $IMAGE_ICON, $hIcon))

    ;align bottom
    Local $mybuttonB = GuiFlatButton_Create("Bottom", 130, 65, 120, 55, $BS_BOTTOM)
    _WinAPI_DeleteObject(_SendMessage(GUICtrlGetHandle($mybuttonB), $BM_SETIMAGE, $IMAGE_ICON, $hIcon))

    ;align bottom-left
    Local $mybuttonBL = GuiFlatButton_Create("Bottom-Left", 130, 125, 120, 55, BITOR($BS_BOTTOM, $BS_LEFT))
    _WinAPI_DeleteObject(_SendMessage(GUICtrlGetHandle($mybuttonBL), $BM_SETIMAGE, $IMAGE_ICON, $hIcon))

    ;align bottom-right
    Local $mybuttonBR = GuiFlatButton_Create("Bottom-Right", 130, 185, 120, 55, BITOR($BS_BOTTOM, $BS_RIGHT))
    _WinAPI_DeleteObject(_SendMessage(GUICtrlGetHandle($mybuttonBR), $BM_SETIMAGE, $IMAGE_ICON, $hIcon))

    ;align right
    Local $mybuttonR = GuiFlatButton_Create("Right", 130, 245, 120, 55, $BS_RIGHT)
    _WinAPI_DeleteObject(_SendMessage(GUICtrlGetHandle($mybuttonR), $BM_SETIMAGE, $IMAGE_ICON, $hIcon))
    GuiFlatButton_SetState($mybuttonR, $GUI_DISABLE )

    ;disabled
    Local $mybuttonDisable = GuiFlatButton_Create("Disabled", 130, 310, 120, 55, $BS_TOOLBUTTON)
    _WinAPI_DeleteObject(_SendMessage(GUICtrlGetHandle($mybuttonDisable), $BM_SETIMAGE, $IMAGE_BITMAP, $hHBitmap))
    GuiFlatButton_SetState($mybuttonDisable, $GUI_DISABLE )


    ;clean up!
    _WinAPI_DestroyIcon( $hIcon )
    _WinAPI_DeleteObject( $hHBitmap )

    GUISetState(@SW_SHOW, $hGUI)

    Local $iMsg
    While 1
        $iMsg = GUIGetMsg()

        Switch $iMsg
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch

        Sleep(10)
    WEnd

    GUIDelete()
EndFunc   ;==>Example

 

I'm sure there are some use-cases I've forgotten, so feedback is welcome!

 

Download the UDF and several more examples: GuiFlatButton_20190414.zip

Update 2019-04-14
Fixed bug, not showing pressed down state when clicking rapidly
Added Icon/Bitmap support!
Added function GuiFlatButton_SetPos to change the position and/or size of a button

Update 2019-02-09
Added 2 new functions to set the button colors globally for all future buttons.
GuiFlatButton_SetDefaultColors 
GuiFlatButton_SetDefaultColorsEx

Credits to:
Melba23 (UDF template)
LarsJ (general subclassing code)
4ggr35510n (TrackMouseEvent example)
binhnx (disable dragging with $WS_EX_CONTROLPARENT)
GUIRegisterMsg in AutoIt Help (owner-draw button example)
funkey (_WinAPI_DrawState example)

Edited by kurtykurtyboy
Updates

Share this post


Link to post
Share on other sites

Looks great! Should be part of the default button creation. :P


Spoiler

Renamer - Rename files and folders, remove portions of text from the filename etc.

GPO Tool - Export/Import Group policy settings.

MirrorDir - Synchronize/Backup/Mirror Folders

BeatsPlayer - Music player.

Params Tool - Right click an exe to see it's parameters or execute them.

String Trigger - Triggers pasting text or applications or internet links on specific strings.

Inconspicuous - Hide files in plain sight, not fully encrypted.

Regedit Control - Registry browsing history, quickly jump into any saved key.

Time4Shutdown - Write the time for shutdown in minutes.

Power Profiles Tool - Set a profile as active, delete, duplicate, export and import.

Finished Task Shutdown - Shuts down pc when specified window/Wndl/process closes.

NetworkSpeedShutdown - Shuts down pc if download speed goes under "X" Kb/s.

IUIAutomation - Topic with framework and examples

Au3Record.exe

Share this post


Link to post
Share on other sites

Impressive!   Thanks for this.

The only "improvement" that comes to mind is to add a two-button example that makes clear (by direct comparison) the capabilities of GuiFlatButton_SetColorsEx ... and maybe include a couple of commented-out alternative lines that show some of the more effective uses you've tested.

 

Share this post


Link to post
Share on other sites

In working with the UDF, I've settled on a default (my default) look for buttons that will work on many screens. As a test, I've edited the Button_Create function as follows:

;fill the array with the default values
    $aGuiFlatButton[$i][0] = $i
    $aGuiFlatButton[$i][4] = False
    $aGuiFlatButton[$i][5] = 13357056               ; bk color
    $aGuiFlatButton[$i][6] = 0x00000000             ; color of text
    $aGuiFlatButton[$i][17] = $sText
    For $j = 7 To 16
        $aGuiFlatButton[$i][$j] = -1
    Next

Should I be looking at a different method for this? Have you thought of adding some sort of SetTheme function that can predefine several of the settings prior to any Button_Create calls?

5c5bb8c5e31e1_DefaultButton.PNG.10d6eb4d7966c633e51c86473886a6ce.PNG

Edited by qwert

Share this post


Link to post
Share on other sites

@qwert Your wish is my command!

Added functions to set default colors:
GuiFlatButton_SetDefaultColors
GuiFlatButton_SetDefaultColorsEx

See first post for how to use. A new example was added to the zip as well.

Share this post


Link to post
Share on other sites

Thanks for adding those.  I haven't had time to delve into the code, so can you spot the reason these two buttons come up with different colors?

In my simple way of thinking, the two create calls would use the same colors.

5c60b3b00b30c_Defaultcolortest.thumb.PNG.4a5da39e5ff2a19926665599390d7000.PNG

Share this post


Link to post
Share on other sites

Well, yes, I can see that now.

While you're still looking at this, can you tell me where the white border is coming from (on a hover), when I've set all the border colors to 0x000000?

5c619ca18a409_BorderDifference.PNG.e952a02078ff5abfcd8f430428482f5d.PNG

Share this post


Link to post
Share on other sites
Quote

I hope you don't mind

Not at all.  Thanks for keeping at it.  This is going to be a very useful UDF!  Styles and such on websites have led users to expect this sort of thing ... which Autoit scripts are now going to be able to deliver.

Share this post


Link to post
Share on other sites

First post updated.

Changes include:
Fixed bug, not showing pressed down state when clicking rapidly
Added Icon/Bitmap support!
Added function GuiFlatButton_SetPos to change the position and/or size of a button

Share this post


Link to post
Share on other sites
Quote

I specifically want to commend you for placing the file date in the file name. Most files are posted without any indication. (Worse, of course, is posting a later version down in the thread!)

I've lost count of the number of times I'd had to figure out which version of a zip or au3 was the latest.

Thanks for your good work. These are nice features.

 

Share this post


Link to post
Share on other sites

Hello,

I have two questions, 

Is there anyway to set and manipulate the text on buttons? (Font, size and position)

When it comes to icons on buttons, can I use an ico file (and can the position be set)? Does it only support icons? 
If you can give some examples, I would be grateful,

Thank you again for this beautiful work.

 

Share this post


Link to post
Share on other sites
On 4/15/2019 at 4:33 AM, kurtykurtyboy said:

First post updated.

Changes include:
Fixed bug, not showing pressed down state when clicking rapidly
Added Icon/Bitmap support!
Added function GuiFlatButton_SetPos to change the position and/or size of a button

Hello,

I have two questions, 

Is there anyway to set and manipulate the text on buttons? (Font, size and position)

When it comes to icons on buttons, can I use an ico file (and can the position be set)? Does it only support icons? 
If you can give some examples, I would be grateful,

Thank you again for this beautiful work.

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now

  • Similar Content

    • By ozymandius257
      This is probably a very simple question (I hope!)
      I'm looking to use a UDF to access a SQL database, and have found ADO.au3, but I can't seem to work out how to use it.
      I've copied the files ado.au3 and ado_constants.au3 into the folder C:\Program Files (x86)\AutoIt3\Include, then opened SciTe and started a new project.
      But when I type #include<AD - I don't get offered ADO.au3.
      (I know I should be using the folder C:\Program Files (x86)\AutoIt3\UserInclude, but when it didn't work from there, I tried the above).
      What am I doing wrong?
       
    • By BetaLeaf
      What is Rollbar?
      Rollbar provides real-time error alerting & debugging tools for developers. Learn more about it at https://rollbar.com/product/
      Demo: https://rollbar.com/demo/demo/
      Screenshot:
      Instructions: (RollbarTest.au3)
      ; Include RollbarSDK #include "RollbarSDK.au3" ;Turns on ConsoleWrite debugging override. ;Global $Rollbar_Debug=False ; Initialize RollbarSDK with the project's API key. ; Parameters ....: $__Rollbar_sToken - [Required] Go to https://rollbar.com/<User>/<ProjectName>/settings/access_tokens/ for your project. Use the token for post_server_item. _Rollbar_Init("eaa8464a4082eeabd9454465b8f0c0af") ; Write code that causes an error you want to catch, then call ; _Rollbar_Send ; Parameters ....: $__Rollbar_sErrorLevel - [Required] Must be one of the following values: Debug, Info, Warning, Error, Critical. ; $__Rollbar_sMessage - [Required] The message to be sent. This should contain any useful debugging info that will help you debug. ; $__Rollbar_sMessageSummary - [Optional] A string that will be used as the title of the Item occurrences will be grouped into. Max length 255 characters. If omitted, Rollbar will determine this on the backend. _Rollbar_Send("Debug", "This is an debug message. If you received this, you were successful!", "Debug Message") _Rollbar_Send("Info", "This is a test message. If you received this, you were successful!", "Info Message") _Rollbar_Send("Warning", "This is an warning message. If you received this, you were successful!", "Warning Message") _Rollbar_Send("Error", "This is an error message. If you received this, you were successful!", "Error Message") _Rollbar_Send("Critical", "This is an critical message. If you received this, you were successful!", "Critical Message") _Rollbar_Send("Info", "This is a test message. If you received this, you were successful!") ;No Message ; Rollbar_Send's helper functions ; Parameters ....: $__Rollbar_sMessage - [Required] The message to be sent. This should contain any useful debugging info that will help you debug. ; $__Rollbar_sMessageSummary - [Optional] A string that will be used as the title of the Item occurrences will be grouped into. Max length 255 characters. If omitted, Rollbar will determine this on the backend. _Rollbar_SendDebug("This is an debug message. If you received this, you were successful!", "Debug Message") _Rollbar_SendInfo("This is a test message. If you received this, you were successful!", "Info Message") _Rollbar_SendWarning("This is an warning message. If you received this, you were successful!", "Warning Message") _Rollbar_SendError("This is an error message. If you received this, you were successful!", "Error Message") _Rollbar_SendCritical("This is an critical message. If you received this, you were successful!", "Critical Message") ; Usable Example Local $sImportantFile = "C:\NOTAREALFILE_1234554321.txt" Switch FileExists($sImportantFile) Case True MsgBox(0, "Example Script", "An important file was found. Continuing...") Case Else _Rollbar_SendCritical('An important file was missing. Halting... File: "' & $sImportantFile & '"', 'Important file "' & $sImportantFile & '" is missing.') EndSwitch Notes: Please comment your feedback, advice, & suggestions below. While this is only a proof of concept, I will expand its feature set for everyone to use. 
      Right now, it is fully functional but not tested in production.
       
       
      Changelog:
      RollbarSDK.au3
      RollbarTest.au3
      v0.2
       
      v0.1.1
       
    • By MFrancisca
      Hello! 
      I've been checking the logging UDFs in the wiki, mostly Log4a and Loga and I wanted to ask which one would you recommend for a script that will be executed remotely through PSExec. My main question is where the logs are located in that situation and if I can change that location to a custom one., because I need to retrieve them at the end of execution.
      So in a rough description the process is
      Open PSExec
      Send compiled AutoIT script to remote machine
      Execute script
      Copy logs from the remote to the local machine.
       
      Any opinions? 
    • By caramen
      I watched _OL_ItemSend&_OL_ItemFind&_OL_ItemCreate in OutlookEx UDF but hmmm
       
      Since it use the test environnement i cant get the orders of the mail creation
       
      Can someone make me win some time of reading all exemples script and lead me how to do one ?
      That whould be lovely.
      Gnight
    • By Tersion
      Here the this wiki page with list of available UDFs for data compression. For my tasks I only need ZIP support, so I started looking at pure AutoIt UDFs without any 3rd party dlls. And found out that most of available realizations uses standard ("native method") Windows dll - "zipfldr.dll". So for now I chose ZIP UDF by wraithdu. I've tested it on Windows 7 (x64) and it seem works fine. But here the comment from another topic where user says that Windows 10 discontinued support of "zipfldr.dll". Now I confused. I don't have around any Windows 10 machine to tested it. So maybe someone could confirm or deny that? Or maybe would better to switch to UDF with 7zip dll?
      I need an advice...
×
×
  • Create New...