How to add leading zeros

[leuce]

Hello everyone

I saw in previous messages that one can use StringFormat to add leading zeros so a number so that the "number" (i.e. the string with leading zeros) always has a specific number of characters, but I'm afraid I don't understand how it works.  Can anyone here please tell me how?

At the moment, if I want to have leading zeros, I use something like this:

For $i = 1 to 100
$j = $i
If $i < 100000 Then
$j = "0" & $j
EndIf
If $i < 10000 Then
$j = "0" & $j
EndIf
If $i < 1000 Then
$j = "0" & $j
EndIf
If $i < 100 Then
$j = "0" & $j
EndIf
If $i < 10 Then
$j = "0" & $j
EndIf
Next

I use these numbers e.g. when creating file names and I want them to sort alphabetically correctly.  Thanks.

Samuel

[water]

This way?

For $i = 1 To 100
    $j = $i
    If $i < 100000 Then
        $j = "0" & $j
    EndIf
    If $i < 10000 Then
        $j = "0" & $j
    EndIf
    If $i < 1000 Then
        $j = "0" & $j
    EndIf
    If $i < 100 Then
        $j = "0" & $j
    EndIf
    If $i < 10 Then
        $j = "0" & $j
    EndIf
    ConsoleWrite($j & ", StringFormat: " & StringFormat("%06i", $i) & @CRLF)
Next

"%06i" can be interpreted as. "%" is a literal, flag "0" for leading zeroes, width "6" means result is 6 characters wide, type "i" stands for signed integer.

Edited October 19, 2019 by water

[Exit]

Or this way? 😉

For $i=1 To 100
    ConsoleWrite(StringTrimLeft(1000000+$i,1) & @CRLF)
    Next

 

[BigDaddyO]

I typically do something like this.

$sPadding = "0000000"   ;Fixed length of your value
$Value = 43             ;Length of the number you got

Consolewrite(StringRight($sPadding & $Value, 7) & @crlf)

 

[jchd]

Fails with negative values. StringFormat is more robust and flexible.

[leuce]

Thanks, everyone!

 

[TheSaint]

Something like what BigDaddyO suggested if you are dealing with a known fixed length.

I regularly use a variation of the following.

$num = StringRight("000" & $num, 4)

In that scenario, the initial source $num can be 1 to 1000 and you always get the correct 4 digit number with required leading zeroes.

EDIT - That 1000 might be misleading, as it could be as much as 9999 .... I was just illustrating in basic terms of 1 to 4 digits.

Edited October 26, 2019 by TheSaint

[iamtheky]

looks like a fun thought experiment 'if stringformat did not exist', this one seems to play nice with negatives and existing leading zeroes:

#include<string.au3>

$n = -0066
$length = 7

msgbox(0, '' , (number($n) < 0 ? "-" : "") &  _StringRepeat(0 , $length - stringlen(Abs($n))) & Abs($n))

 

Edited October 26, 2019 by iamtheky

[Deye]

@stretching Gum 

#include <String.au3>

MsgBox(0, '', IL(43, 6))

Func IL($Value = "", $iCount = 5, $lChar = 0)
    Return (Abs($Value) = $Value ? "" : "-") & _StringRepeat($lChar, $iCount - StringLen(Abs($Value))) & Abs($Value)
EndFunc   ;==>InsertLeading

 

[mikell]

  On 10/26/2019 at 6:09 PM, iamtheky said:

looks like a fun thought experiment 

Expand  

... and - of course - the regex version

#include<string.au3>

$n = -0066
$length = 7

$r = Execute(StringRegExpReplace($n, '(-?)0*(' & Abs($n) & ')', _ 
        "'$1' & _StringRepeat(0, $length - stringlen('$2')) & '$2' & ") & "''")
msgbox(0, '' , $r)

 

[TheSaint]

LOL. I love it when code gets taken to the extremes.

About time we had some more code contests.

1. The simplest way to do something.

2. The most complex way.

3. The cleverest.

4. The dumbest.

P.S. No doubt a good learning experience on occasion.

Edited October 28, 2019 by TheSaint

[FrancescoDiMuro]

@TheSaint

When another one of those?

[Gianni]

... just for fun, a version that does not use StringFormat() nor #include <string.au3> nor regex

$nr = -0066
$length = 7

MsgBox(0, '', Num_Len($nr, $length))

Func Num_Len($n, $length)
    Local $a[$length]
    Return (Number($n) < 0 ? "-" : "") & StringRight(StringReplace(StringFromASCIIArray($a), Chr(0), '0') & Abs($n), $length)
EndFunc   ;==>Num_Len

 

[TheSaint]

  On 10/28/2019 at 6:32 PM, FrancescoDiMuro said:

@TheSaint

When another one of those?

Expand  

@czardas - was the mover and shaker behind them. If you are keen for some more, maybe let him know.

[Deye]

Back to innocence example

#include <string.au3>
MsgBox(0, '', _ARLeadingZeros(-00066, True) & @CRLF & _ARLeadingZeros(-00066, False, 3))

Func _ARLeadingZeros($n, $bRemove = False, $length = 6)
    If $bRemove Or StringLen(Abs($n)) >= $length Then Return $n
    Local $nP = 1 & _StringRepeat(0, $length), $nN = "-" & StringTrimLeft($nP - $n, 1)
    Return $nN = $n ? $nN : StringTrimLeft($nP + $n, 1)
EndFunc   ;==>_AddRemoveLeadingZeros

 

Edited October 30, 2019 by Deye