How to validate if the data you give me is a number?

[ElPandaRojo1]

I need help, how can I find out if the information they give me is a number.
Example I have the InputBox give me any number as I do to know if in a number, instead of it being some letter or some word

Help.au3

[water]

IsNumber?

[TheXman]

One way could be to create a function that tests the value.  The example below assumes that floating point values are assumed to be numeric.  If you only want integers, then you can modify as needed.

ConsoleWrite('IsNumeric(0)             = ' & IsNumeric(0) & @CRLF)
ConsoleWrite('IsNumeric(798)           = ' & IsNumeric(798) & @CRLF)
ConsoleWrite('IsNumeric("")            = ' & IsNumeric("") & @CRLF)
ConsoleWrite('IsNumeric("7 ")          = ' & IsNumeric("7 ") & @CRLF)
ConsoleWrite('IsNumeric("7")           = ' & IsNumeric("7") & @CRLF)
ConsoleWrite('IsNumeric("7a")          = ' & IsNumeric("7a") & @CRLF)
ConsoleWrite('IsNumeric("1,234.00")    = ' & IsNumeric("1,234.00") & @CRLF)
ConsoleWrite('IsNumeric("1234.00")     = ' & IsNumeric("1234.00") & @CRLF)
ConsoleWrite('IsNumeric("1234.00.23")  = ' & IsNumeric("1234.00.23") & @CRLF)
ConsoleWrite('IsNumeric("1234.")       = ' & IsNumeric("1234.") & @CRLF)

Func IsNumeric($sValue)
    If StringRegExp($sValue, "^\d+(\.\d*)?$") Then
        Return True
    Else
        Return False
    EndIf
EndFunc

Output:

IsNumeric(0)             = True
IsNumeric(798)           = True
IsNumeric("")            = False
IsNumeric("7 ")          = False
IsNumeric("7")           = True
IsNumeric("7a")          = False
IsNumeric("1,234.00")    = False
IsNumeric("1234.00")     = True
IsNumeric("1234.00.23")  = False
IsNumeric("1234.")       = True

 

$sInput = InputBox("Test", "Enter data")
If IsNumeric($sInput) Then
    MsgBox(0, "Test", $sInput & " is numeric")
Else
    MsgBox(0, "Test", $sInput & " is not numeric")
EndIf

Func IsNumeric($sValue)
    If StringRegExp($sValue, "^\d+(\.\d*)?$") Then Return True
EndFunc

 

Edited April 7, 2020 by TheXman

[TheXman]

13 minutes ago, water said:

IsNumber?

@water

I don't think IsNumber will work in this case.  IsNumber tells you if the variable's base type is a number.  InputBox returns a string.  So IsNumber will always be False.

Edited April 7, 2020 by TheXman

[ElPandaRojo1]

Thank you so much @water for your answer, but @TheXman is right in what he says.

 

Thank you so much @TheXman your function serves me.

[water]

Based on your example I suggest the following (non-RegExp) solution:

$sInput = InputBox("Test", "Enter data")    ; Returns input as a string
$vInput = Number($sInput)                   ; Return the numeric representation of the input. Means: Drop all non-numeric characters
If String($vInput) == $sInput Then          ; Translate the number to a string and compare with the original input. When not equal then the input is not numeric
    MsgBox(0, "Test", $sInput & " is a number")
Else
    MsgBox(0, "Test", $sInput & " contains non-numeric characters")
EndIf

 

[jchd]

Beware of "003" != "3" as well as "5e-1" != "0.5" as well as "+8" != "8" as well as "-0" != "0" or some "0.0" != "0" and "1.20" != "1.2"

Users can be either vicious or surprising.

 

Edited April 7, 2020 by jchd

[water]

Seems we need more information about the range of valid input

[dmob]

14 minutes ago, jchd said:

Users can be either vicious or surprising.

I found out in very unpleasant ways Einstein's quote came alive

[BrewManNH]

I'd suggest using a GUI and an input control created with GUICtrlCreateInput, then  you can specify that it would only accept numbers with the style $ES_NUMBER set.

[MrCreatoR]

$sRet = InputBox('Number', 'Enter number')

If Not @error Then
    MsgBox(64, @ScriptName, 'Is Number: ' & _StringIsNumber($sRet))
EndIf

Func _StringIsNumber($sString, $bFloat = True)
    Return StringIsDigit($sString) Or StringIsInt($sString) Or ($bFloat And StringIsFloat($sString))
    ;Or as suggested by water
    ;Return String($sString) == Number($sString)
EndFunc

 

Edited April 7, 2020 by MrCreatoR

[Zedna]

There are function that can be used in this case:

StringIsDigit()

StringIsFloat()

[water]

Already used in the example by MrCreatoR in the above post

[FrancescoDiMuro]

Seems that the closest one was by @TheXman, since no one of the above works with a floating number with a comma instead of a dot as decimal separator.
One flavour could be something like this:

#include <MsgBoxConstants.au3>
#include <StringConstants.au3>

Global $strUserInput = InputBox("_IsNumber?", "Type whatever you want: ")

If Not @error Then
    MsgBox($MB_ICONQUESTION, "The answer:", "Is " & $strUserInput & " a number? " & _IsNumber($strUserInput))
EndIf


Func _IsNumber($varUserInput)
    Return StringRegExp($varUserInput, '^(?:[-+])?\d+(?:[.,]\d*)?(?:[.,]\d*)?$', $STR_REGEXPMATCH) = 1
EndFunc

It supports number with sign, decimal separator and thousand separator as dot or comma 

P.S.: As @jchd said, the cases of what should be considered as number are a lot 

Numbers format supported:

Spoiler

+000.5
-01.16
+5
-10
15,1
15.5
+20.2
-100,5
1.000,4
1,000.5
+50.000,56
-12,12345.00

 

Edited April 8, 2020 by FrancescoDiMuro

[Colduction]

You can also use this alternative method:

$sText = "Example Text 123"
If StringRegExp($sText, "^[0-9]") Then
    ConsoleWrite("Yes!" & @CRLF)
Else
    ConsoleWrite("No, it's not digit!" & @CRLF)
EndIf

 

[jchd]

Too naive as other posts above showed.

Consider:
+5
-1
33333333333333333333333333333333333333333
1.0
1.1
and many more.

The OP needs to be more precise about what he can allow: floating-point or integer, sign, range.

Edited April 8, 2020 by jchd

[MrCreatoR]

3 hours ago, FrancescoDiMuro said:

no one of the above works with a floating number with a comma instead of a dot as decimal separator

It's not a number then. Floating number separated with dot, not with comma, otherwise it's a string.

You (as a programmer) should define the format for the input. If it's not in defined format, it's considered wrong (unsupported) input.

Edited April 8, 2020 by MrCreatoR