Is it possible to convert text to dec?

[Divane]

Hello everyone. I need to convert any string to 3-digit decimal. It is possible to convert through online tools. Is there any way to do this in AutoIt.

For Example ;
8cdb3 = DECIMAL 056 099 100 098 051

Is it possible the conversion above by AutoIt? Thanks.

[jchd]

Look at StringToASCIIArray() and StringFormat().

Local $s = "8cdb3"  ; any non-empty Unicode string
Local $a = StringToASCIIArray($s)
Local $sOut = StringFormat("%03i", $a[0])

For $i = 1 To UBound($a) - 1
    $sOut &= StringFormat(" %03i", $a[$i])
Next

ConsoleWrite($sOut & @LF)

 

[Divane]

I can't thank you enough. Thank you very much for your prompt response. 

[Nine]

or this one liner :

$sTxt = "8cdb3"
$sText = Execute(StringTrimRight(StringRegExpReplace($sTxt, "(.)", "stringFormat('%03i',asc('$1'))&' '&"),5))
MsgBox ($MB_SYSTEMMODAL,"",$sText)

 

[jchd]

There are multiple ways to skin the same cat.

Local $s = "8cdb3"  ; any non-empty Unicode string
Local $a = StringToASCIIArray($s)
Local $sOut = _ArrayToString($a, " ")
$sOut = StringRegExpReplace($sOut, "(?<=^| )(\d\d)\b", "0$1")
ConsoleWrite($sOut & @LF)

Anyway, beware that Unicode characters > 0x3E7 will expand to 4 to 5 decimal digits.

AscW('€') yields 8364 and AscW('fi') gives 64257.