RegExp to trim a part of a string?

[Gianni]

Hi all,

is there a regular expression pattern that can be used to remove part of a string based on the position of the substring, that is, by specifying the start and end characters of the block to remove? thus obtaining a new string without the "piece" indicated.

for example:

Global $sString = "Today I do not feel good"
; chars:           000000000111111111122222
;                  123456789012345678901234

; remove a chunk from char 9 to char 15
MsgBox(0, '', _StringTrimMid($sString, 9, 15))


; Returns the string trimmed by characters from $iStartCut to $iEndCut.
Func _StringTrimMid($sInput, $iStartCut, $iEndCut)

    Return StringLeft($sInput, $iStartCut - 1) & StringMid($sInput, $iEndCut + 1)

    ; can be done the same with a RegExp ??

EndFunc   ;==>_StringTrimMid

 

[Nine]

This ?

Func _StringTrimMid2($sInput, $iStartCut, $iEndCut)
  Return StringRegExpReplace ($sInput, "(.{" & $iStartCut-1 & "})(.{" & $iEndCut-$iStartCut+1 & "})(.{" & StringLen($sInput)-$iEndCut-1 & "})","$1$3")
EndFunc

 

[Danp2]

@Nine I was just about to post a very similar solution, which I translated from here. 😄

Here's what I came up with --

Func _StringTrimMid($sInput, $iStartCut, $iEndCut)

    Local $lFind = "^(.{" & $iStartCut - 1 & "}).{" & ($iEndCut - $iStartCut + 1) & "}"
    Local $lResult = StringRegExpReplace($sInput, $lFind, "\1")

    Return $lResult
EndFunc   ;==>_StringTrimMid

 

[Nine]

@Danp2  Nice.  And you are the fastest too 

[jchd]

I'd be tempted to prepend (?s) aka PCRE_DOTALL so that the dot matches newline sequences as well, if ever the case occurs. It all depends on the use case context.

[Gianni]

Thanks @Nine and @Danp2

31 minutes ago, jchd said:

I'd be tempted to prepend (?s) aka PCRE_DOTALL so that the dot matches newline sequences as well, if ever the case occurs. It all depends on the use case context.

Thanks @jchd

... the use case context should be as much as possible of general use ...
how is your pattern which also allows @cr / @crlf .. (and @tab?)

Thanks

[jchd]

By default . (dot) matches eveything except newlines. By prepending (?s) to the pattern, subsequent . will match newlines as well. TABs are matched by . in all cases. To be completely generic you may even want to add (*UCP) at the very start of the pattern: this way, extra Unicode newline sequences are matched as well when using (?s).

[Gianni]

21 minutes ago, jchd said:

By default . (dot) matches eveything except newlines. By prepending (?s) to the pattern, subsequent . will match newlines as well. TABs are matched by . in all cases. To be completely generic you may even want to add (*UCP) at the very start of the pattern: this way, extra Unicode newline sequences are matched as well when using (?s).

.... it would seem that you are right .....
... I'm kidding of course, ... I had no doubt about that

Thank You @jchd

Global $sString = "Today " & @CRLF & "I do not feel good"
; chars:           000000     00      011111111112222222
;                  123456     78      901234567890123456

; remove a chunk from char 11 to char 17
MsgBox(0, '', _StringTrimMid($sString, 11, 17))


; Returns the string trimmed by characters from $iStartCut to $iEndCut.
Func _StringTrimMid($sInput, $iStartCut, $iEndCut)

    Local $lFind = "(*UCP)(?s)" & "^(.{" & $iStartCut - 1 & "}).{" & ($iEndCut - $iStartCut + 1) & "}"
    Local $lResult = StringRegExpReplace($sInput, $lFind, "\1")

    Return $lResult

EndFunc   ;==>_StringTrimMid

 

Edited November 19, 2020 by Chimp

[Deye]

_StringWordTrimMid 

#include <Array.au3>

Global $sString = "Today " & @CRLF & @CRLF & "I do not feel good i won't quit!"

MsgBox(0, '', _StringWordTrimMid($sString, 2, 6))

; Returns the string trimmed by words from $iStartCut to $iEndCut.
Func _StringWordTrimMid($sInput, $iStartCut, $iEndCut)
    Local $a = StringRegExp($sInput, '[\H]+', 3)
    _ArrayDelete($a, $iStartCut & "-" & $iEndCut)
    Return _ArrayToString($a, " ")
EndFunc

 

[Gianni]

nice enough, thanks @Deye, but that's another movie.....

[mikell]

You might avoid the backreference by the use of \K - it's nothing but a detail 

Local $lFind = "(*UCP)(?s)" & "^.{" & $iStartCut - 1 & "}\K.{" & $iEndCut - $iStartCut + 1 & "}"
Local $lResult = StringRegExpReplace($sInput, $lFind, "")