INI File?

[Vegar]

Hello

I've have made a script that records how long the script have been running...

but i want it to start from where it ended last time, even if i restart the computer...

and i wanted to start learning to use INI files, and i think the explainasion in the help file was not to much of help..

so could someone explain to me how i use .INI files.. (How i make one, read one, and so on....)

[Valuater]

just because..

Global $ini_File = @ScriptDir & "\My.ini"
Global $Time_Keep = ""

$Wait = 5 ; seconds

If not FileExists($ini_File) Then
    IniWrite($ini_File, "History", "Timer", "")
Else
    $Time_Keep = IniRead($ini_File, "History", "Timer", "")
EndIf

$begin = TimerInit()

While 1
    
    Sleep(500)
    
    $Test_Time = Int(TimerDiff($begin) / 1000)
    
    ToolTip( $Test_Time + $Time_Keep , 20, 20)

    If $Test_Time >= $Wait Then
        IniWrite($ini_File, "History", "Timer", $Test_Time + $Time_Keep )
        Exit
    EndIf
    
WEnd

8)

[DaRam]

When your script ends, this fragment should run:

$IniFile =  StringRegExpReplace(@ScriptName, "\.au3|\.exe$", '') & '.Ini'
; Build your own time fragment
$LastTime =  @YEAR & @MON & @MDAY & "|" & @HOUR  & ":" &  @MIN & ":" & @SEC
IniWrite($IniFile, "LastRunEnd", @UserName, $LastTime)

When your script starts, this can be read back:

$LastTime =  IniRead($IniFile, "LastRunEnd", @UserName, "")
If StringLen($LastTime) > 0 Then
  ; You have Saved Run End Date/Time
  ; Do whatever...
EndIf

This is presuming $IniFile has been defined (as in first code fragment)

I notice Valuater has posted more relevant code. Your call

[GreenCan]

and this one will do it too:

GreenCan

; startup with a new Timer.ini with some stuff in it
If Not FileExists(@ScriptDir & "\Timer.ini") Then Create_ini()

; read the ini file
$Timer = IniRead (@ScriptDir & "\Timer.ini", "Global", "Timer_seconds", 0)
ConsoleWrite("Timer on start : " & $Timer & @cr)

$begin = TimerInit() ; initiate the stopwatch

; do your stuff here
msgbox(0,"","press ok to stop")

$Accumulated_time = (TimerDiff($begin)/1000) + $Timer ; stopwatch

ConsoleWrite("Accumulated time: " & $Accumulated_time & @CR)

$result = IniWrite(@ScriptDir & "\Timer.ini", "Global", "Timer_seconds", $Accumulated_time )
If $result = 0 Then
    msgbox(0,"Error","INI File not accessible")
EndIf


; new content
$Timer = IniRead (@ScriptDir & "\Timer.ini", "Global", "Timer_seconds", 0)
ConsoleWrite("new ini content: " & $Timer & @CR)


Func Create_ini()
    IniWrite(@ScriptDir & "\Timer.ini", "Global", "Timer_seconds", 0)
    Return
EndFunc  ;==>Create_ini

[Valuater]

enough explanation for you?

8)

[Vegar]

Yeah could not be better

thanx guys