Help with file renaming

[dickep 0]

OK, I have a lot of files I renamed to the same name using Windows XP file rename. they are renamed "filename (0).ext" through "filename (213).ext"

However, when I do anything with them, they are not sorted correctly. 1 has 10 after it and so on.

SO, my thought was to try to rename all the numbers to 3 digits - the 1- 9 being 001 - 009 and, well you get the idea.

I just can't get my hands on how to rename the actual file name like this. I can get the file name but how to rename it????

Make sense - probably not but would appreciate any help I can get.

the main reason for renaming the files is the ArraySort routine does not sort it correctly. XP does, but that does not stay sorted.

Thanks

E

Edited February 17, 2011 by dickep

[Varian 7]

$File = @DesktopDir & '\New Text Document (2).txt'

$Digit = StringRegExpReplace($File, '^(.+)\((\d+)\)(.+)$', '$2')

$NewFileName = StringRegExpReplace($File, '^(.+)\((\d+)\)(.+)$', '$1(' & StringFormat('%03u', $Digit) & ')$3')

MsgBox(0, 'Results', 'Digit(s) = ' & $Digit & @LF & 'New Name = ' & $NewFileName)

[dickep 0]

But does this actually replace the file name on the hard disk??? Maybe I am missing something but I don't see anything in this to change the actual file name and that is what I really need to do.

Thanks for the insight as to how to change the read file name.

E

[guinness 1,478]

Look at FileMove() too. I (and Varian probably) presumed that you knew how to Rename Files in AutoIt E.G.

FileMove($File, $NewFileName, 8)

Edited February 17, 2011 by guinness

[Varian 7]

Look at FileMove() too. I (and Varian probably) presumed that you knew how to Rename Files in AutoIt E.G.

FileMove($File, $NewFileName, 8)

yeah, I assumed the problem was how to get the naming structure correct. Try this, replacing $Directory with the directory you which to search for your files...this is not a recursive search, BTW.

#include <Array.au3>
#include <File.au3>

Local $Directory = "YourDirectoryToSearch"

Local $fArray = _FileListToArray($Directory, "*", 1)
If @error Then Exit

For $i = $fArray[0] To 1 Step -1
    If Not StringRegExp($fArray[$i], '\(\d+\)', 0) Then _ArrayDelete($fArray, $i)   ;check if the file has "(some digit(s))" in it
Next
$fArray[0] = UBound($fArray) - 1
If $fArray[0] = 0 Then Exit
_ArrayDisplay($fArray, "List of Files to be Renamed")

For $i = 1 To $fArray[0]
    If Not StringRegExp($fArray[$i], '\(\d+\)', 0) Then ContinueLoop    ;check if the file has "(some digit(s))" in it
    If Not _RenameFile($fArray[$i]) Then msgBox(262208, "Issue", "Failed renaming " & $fArray[$i])
Next


Func _RenameFile($iFile)
    Local $Digit = StringRegExpReplace($iFile, '^(.+)\((\d+)\)(.+)$', '$2')
    Local $NewFileName = StringRegExpReplace($iFile, '^(.+)\((\d+)\)(.+)$', '$1(' & StringFormat('%03u', $Digit) & ')$3')
    If $NewFileName <> $iFile And Not FileExists($NewFileName) Then
        Return FileMove($iFile, $NewFileName)
    EndIf
EndFunc