picture in a Gui with a URL who can change

[Exoendables]

Helo

So here i am with... a probleme

I want in my Gui a part with an picture in fonction of URL (picture url), but thaht image can change (with the same URL) so can i do that ?

Thx for your answer !

BYE !

[UEZ]

Here an modified example from here:

expandcollapse popup

#include <GDIplus.au3>
#include <GUIConstantsEx.au3>
#Include <Memory.au3>

Opt("MustDeclareVars", 1)
_GDIPlus_Startup()
Global $hStream, $nMsg
Global $sUrls = "http://www.autoitscript.com/autoit3/files/graphics/autoit9_wall_1280x1024.jpg|http://autoit-script.ru/autoit_rv_ua/files/Pictures/autoit_builder_wall_1024x768.jpg|"  & _
                            "http://www.autoitscript.com/autoit3/files/graphics/autoit_matrix_wall_1920x1200.jpg|http://alex-imka.de/autoit/1.jpg|http://alex-imka.de/autoit/3.jpg"
Global $aURLS = StringSplit($sUrls, "|", 2)
Global $s = InetRead($aURLS[Random(0, UBound($aURLS) - 1, 1)])
Global $hMem = _MemGlobalAllocFromBinary($s)
Global $hImage = _GDIPlus_ImageLoadFromHGlobal($hMem)
Global $iWidth = Int(@DesktopWidth * 0.75)
Global $iHeight = Int(@DesktopHeight * 0.75)

Global $hWnd = GUICreate("Display image from internet", $iWidth, $iHeight)
GUISetState(@SW_SHOW)

Global $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hWnd)
_GDIPlus_GraphicsDrawImageRect ($hGraphics, $hImage, 0, 0, $iWidth, $iHeight);copy bitmap to GUI

GUISetState()

GUIRegisterMsg(0x0014, "WM_ERASEBKGND")
Global $timer = TimerInit()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            _GDIPlus_BitmapDispose($hImage)
            _GDIPlus_GraphicsDispose($hGraphics)
            _GDIPlus_Shutdown()
            GUIDelete($hWnd)
            Exit
    EndSwitch
    If TimerDiff($timer) > 5000 Then
        _GDIPlus_BitmapDispose($hImage)

         $s = InetRead($aURLS[Random(0, UBound($aURLS) - 1, 1)])
         $hMem = _MemGlobalAllocFromBinary($s)
         $hImage = _GDIPlus_ImageLoadFromHGlobal($hMem)

        _GDIPlus_GraphicsDrawImageRect ($hGraphics, $hImage, 0, 0, $iWidth, $iHeight)
        $timer = TimerInit()
    EndIf
WEnd

Func WM_ERASEBKGND($hWnd, $uMsgm, $wParam, $lParam)
    _GDIPlus_GraphicsDrawImageRect ($hGraphics, $hImage, 0, 0, $iWidth, $iHeight)
    Return True
EndFunc   ;==>WM_ERASEBKGND

; #FUNCTION# ====================================================================================================================
; Name...........: _GDIPlus_ImageLoadFromHGlobal
; Description ...: Creates an Image object based on movable HGlobal memory block
; Syntax.........: _GDIPlus_ImageLoadFromHGlobal($hGlobal)
; Parameters ....: $hGlobal - Handle of a movable HGlobal memory block
; Return values .: Success      - Pointer to a new Image object
;                  Failure      - 0 and either:
;                  |@error and @extended are set if DllCall failed:
;                  | -@error = 1 if could not create IStream
;                  | -@error = 2 if DLLCall to create image failed
;                  |$GDIP_STATUS contains a non zero value specifying the error code
; Author ........: ProgAndy
; Modified.......:
; Remarks .......: After you are done with the object, call _GDIPlus_ImageDispose to release the object resources.
;                  The HGLOBAL will be owned by the image and freed automatically when the image is disposed.
; Related .......: _GDIPlus_ImageLoadFromStream, _GDIPlus_ImageDispose
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _GDIPlus_ImageLoadFromHGlobal($hGlobal)
    Local $aResult = DllCall("ole32.dll", "int", "CreateStreamOnHGlobal", "handle", $hGlobal, "bool", True, "ptr*", 0)
    If @error Or $aResult[0] <> 0 Or $aResult[3] = 0 Then Return SetError(1, @error, 0)
    Local $hBitmap = _GDIPlus_BitmapCreateFromStream($aResult[3])
    Local $error = @error
    Local $tVARIANT = DllStructCreate("word vt;word r1;word r2;word r3;ptr data; ptr")
    Local $aCall = DllCall("oleaut32.dll", "long", "DispCallFunc", "ptr", $aResult[3], "dword", 8 + 8 * @AutoItX64, "dword", 4, "dword", 23, "dword", 0, "ptr", 0, "ptr", 0, "ptr", DllStructGetPtr($tVARIANT))
    If $error Then Return SetError(2, $error, 0)
    Return $hBitmap
EndFunc   ;==>_GDIPlus_ImageLoadFromHGlobal

; #FUNCTION# ====================================================================================================================
; Name...........: _MemGlobalAllocFromBinary
; Description ...: Greates a movable HGLOBAL memory block from binary data
; Syntax.........: _MemGlobalAllocFromBinary($bBinary)
; Parameters ....: $bBinary - Binary data
; Return values .: Success      - Handle of a new movable HGLOBAL
;                  Failure      - 0 and set @error:
;                  |1  - no data
;                  |2  - could not allocate memory
;                  |3  - could not set data to memory
; Author ........: ProgAndy
; Modified.......:
; Remarks .......:
; Related .......: _MemGlobalAlloc, _MemGlobalFree, _MemGlobalLock
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _MemGlobalAllocFromBinary(Const $bBinary)
    Local $iLen = BinaryLen($bBinary)
    If $iLen = 0 Then Return SetError(1, 0, 0)
    Local $hMem = _MemGlobalAlloc($iLen, $GMEM_MOVEABLE)
    If @error Or Not $hMem Then Return SetError(2, 0, 0)
    DllStructSetData(DllStructCreate("byte[" & $iLen & "]", _MemGlobalLock($hMem)), 1, $bBinary)
    If @error Then
        _MemGlobalUnlock($hMem)
        _MemGlobalFree($hMem)
        Return SetError(3, 0, 0)
    EndIf
    _MemGlobalUnlock($hMem)
    Return $hMem
EndFunc   ;==>_MemGlobalAllocFromBinary

; #FUNCTION# ====================================================================================================================
; Name...........: _GDIPlus_BitmapCreateFromStream
; Description ...: Creates a Bitmap object based on an IStream COM interface
; Syntax.........: _GDIPlus_BitmapCreateFromStream($pStream)
; Parameters ....: $pStream - Pointer to an IStream COM interface
; Return values .: Success      - Returns a handle to a new Bitmap object
;                  Failure      - 0 and either:
;                  |@error and @extended are set if DllCall failed
;                  |$GDIP_STATUS contains a non zero value specifying the error code
; Remarks .......: After you are done with the object, call _GDIPlus_ImageDispose to release the object resources
; Related .......: _GDIPlus_ImageDispose, _WinAPI_CreateStreamOnHGlobal
; Link ..........; @@MsdnLink@@ GdipCreateBitmapFromStream
; Example .......; Yes
; ===============================================================================================================================
Func _GDIPlus_BitmapCreateFromStream($pStream)
    Local $aResult = DllCall($ghGDIPDll, "uint", "GdipCreateBitmapFromStream", "ptr", $pStream, "int*", 0)
    If @error Then Return SetError(@error, @extended, 0)
    Return $aResult[2]
EndFunc   ;==>_GDIPlus_BitmapCreateFromStream

Might be helpful for you.

Br,

UEZ

[guinness]

I don't know if this is what you are looking for >>

Edit: UEZ had the same idea

Edited March 2, 2011 by guinness

[Exoendables]

Sorry mistake the URL can change like that :

https://img.****.com/*****/_cf_****/_wallpaper_img-(5143652999042943026).png

And i want download this url in a page how i can do ?

and the number in this ( ) can change but it's only one image and with your programme that don't work you know why ?

Sorry for my mistake

Edited March 3, 2011 by Exoendables