Pic control not working?

[Damein 18]

For some reason I cannot get this to work:

$CurrentImage = GuiCtrlCreatePic(@ScriptDir & "/Images/Image1.png", 0, 15, 200, 200)

Is it because .png cannot be used? If so, I tried this as well:

(I am downloading the image off a website, and its default is .png)

I changed it using:

InetGet($OverViewImage[1], @ScriptDir & "\Images\Image1.png")

And I can see this image in the folder so I know its downloading. I tried chaing the .png to .jpg and tried using:

$CurrentImage = GuiCtrlCreatePic(@ScriptDir & "/Images/Image1.jpg", 0, 15, 200, 200)

But still no go, I just get a blank GUI.

Edited April 26, 2011 by Damein

[water 1,883]

According to the help file only BMP, JPG and GIF are supported.

PNG can be used with GDI+. See example 3 in the help file for GUICtrlCreatePic.

BTW: Some error checking will show you if the function does what you want it to do. If $CurrentImage = 0 then there was a problem.

Edited April 26, 2011 by water

[Jayson 0]

This does trick with .png images (from help file) :

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#Include <WinAPI.au3>

Opt('MustDeclareVars', 1)

Global $hGUI, $hImage, $hGraphic, $hImage1

$hGUI = GUICreate("Show PNG", 250, 250)

_GDIPlus_StartUp()
$hImage   = _GDIPlus_ImageLoadFromFile(@ScriptDir & "/Images/Image1.png")
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)

GUIRegisterMsg($WM_PAINT, "MY_WM_PAINT")
GUISetState()

do
until GUIGetMsg() = $GUI_EVENT_CLOSE

; Clean up resources
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_ImageDispose($hImage)
_GDIPlus_ShutDown()

; Draw PNG image
Func MY_WM_PAINT($hWnd, $Msg, $wParam, $lParam)
    _WinAPI_RedrawWindow($hGUI, 0, 0, $RDW_UPDATENOW)
    _GDIPlus_GraphicsDrawImage($hGraphic, $hImage, 0, 0)
    _WinAPI_RedrawWindow($hGUI, 0, 0, $RDW_VALIDATE)
    Return $GUI_RUNDEFMSG
EndFunc

Edited April 26, 2011 by Jayson

[Damein 18]

Thanks Jayson, worked great