Sign in to follow this  
Followers 0
Maffe811

Splash screen uses bmp, i

8 posts in this topic

#1 ·  Posted (edited)

So this is my grooveshark splash screen wich uses the attatched bmp file as splash screen.

I need the attatched png file to be used, but i cant figure out how.

If i just change the extention (wich i though i could after reading the help file) it disapears.

Png file:[LNK]

Bmp file: [LINK]

#include-once
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <SendMessage.au3>
;~ #NoTrayIcon

;Available functions:
;_GUI_Image()       Will create the image.
;_GUI_Image_Show()  Will show the image.
;_GUI_Image_Hide()  Will hide the image.

;Variables
Global Const $SC_DRAGMOVE = 0xF012
Global $ParentGui, $ImgGUI, $Percent = 35, $SplashSize = (@DesktopHeight/100*$Percent)

Func _GUI_Image()
    ;Creating GUI
    $ParentGui = GUICreate("", 100,100, 100, 100)
    $ImgGUI = GUICreate("", $SplashSize, $SplashSize, -1, -1, $WS_POPUP, Bitor($WS_EX_TOPMOST,$WS_EX_LAYERED),$ParentGui)
    GUICtrlCreatePic(@ScriptDir & "\Groovesharksplash.bmp", 0, 0, $SplashSize, $SplashSize)
;~  GUICtrlCreatePic($FilePath, 0, 0, $SplashSize, $SplashSize)
    GUICtrlSetState(-1, $GUI_DISABLE);Hide the GUI and so only the image is showed

EndFunc ;==>_GUI_Image

Func _GUI_Image_Show()
    Opt("TrayIconHide", 1)
    GUISetState(@SW_SHOW,$ImgGUI);Show GUI, but the gui is disabled, therefore its the image.
EndFunc ;==> _GUI_Image_Show

Func _GUI_Image_Hide()
    Opt("TrayIconHide", 0)
    GUISetState(@SW_HIDE,$ImgGUI);Hides the GUI
EndFunc;==> _GUI_Image


_GUI_Image()
_GUI_Image_Show()
Sleep(4000)
_GUI_Image_Hide()
Exit
Edited by Maffe811

[font="helvetica, arial, sans-serif"]Hobby graphics artist, using gimp.Automating pc stuff, using AutoIt.Listening to music, using Grooveshark.[/font]Scripts:[spoiler]Simple ScreenshotSaves you alot of trouble when taking a screenshot!Don't remember what happened with this, but aperantly the exe is all i got.If you don't want to run it, simply don't._IsRun UDFIt figures out if the script has ben ran before based on the info in a ini file.If you don't want to use exactly what i wrote, you can use it as inspiration.[/spoiler]

Share this post


Link to post
Share on other sites



#2 ·  Posted (edited)

You can use png file with GDI+. In picture control can be used just bitmap and jpg.

EDIT: Maybe this example GDI+ can help you

#include <GDIPlus.au3>

Global $GUI, $W = 300, $H = 300, $GRAPHIC, $IMAGE, $SPLASH_VISIBLE = True

HotKeySet("{ESC}","Quit")       ; Press ESC to quit
HotKeySet("{F1}","ToggleState") ; Press F1 to show/hide the splash

$GUI = GUICreate("Splash Screen",300,300,Default,Default,0x80000000)
SplashScreen($GUI,@ScriptDir & "\groovesharksplash.png")
SplashScreen_Show($GUI)

GUIRegisterMsg(0xF, "MY_PAINT")
GUIRegisterMsg(0x85, "MY_PAINT")

While True
    Sleep(10)
WEnd

Func SplashScreen($GUI,$PATH)
    _GDIPlus_Startup()
    $GRAPHIC = _GDIPlus_GraphicsCreateFromHWND($GUI)
    $IMAGE = _GDIPlus_ImageLoadFromFile($PATH)
EndFunc

Func SplashScreen_Show($GUI)
    GUISetState(@SW_SHOW,$GUI)
    _GDIPlus_GraphicsDrawImageRect($GRAPHIC,$IMAGE,0,0,$W,$H)
EndFunc

Func SplashScreen_Hide($GUI)
    GUISetState(@SW_HIDE,$GUI)
EndFunc

Func ToggleState()
    $SPLASH_VISIBLE = Not $SPLASH_VISIBLE
    If $SPLASH_VISIBLE Then
        SplashScreen_Show($GUI)
    Else
        SplashScreen_Hide($GUI)
    EndIf
EndFunc

Func MY_PAINT($hWnd, $msg, $wParam, $lParam)
    _GDIPlus_GraphicsDrawImageRect($GRAPHIC,$IMAGE,0,0,$W,$H)
    Return ''
EndFunc

Func Quit()
    _GDIPlus_ImageDispose($IMAGE)
    _GDIPlus_GraphicsDispose($GRAPHIC)
    _GDIPlus_Shutdown()
    Exit
EndFunc
Edited by Andreik

When the words fail... music speaks

Share this post


Link to post
Share on other sites

#3 ·  Posted (edited)

Have a look here >>

And as Andreik said there are plenty of Examples by UEZ, Yashied & Zedna discussing the topic of adding a PNG image to a GUIControl.

Edited by guinness

_AdapterConnections()_AlwaysRun()_AppMon()_AppMonEx()_BinaryBin()_CheckMsgBox()_CmdLineRaw()_ContextMenu()_ConvertLHWebColor()/_ConvertSHWebColor()_DesktopDimensions()_DisplayPassword()_DotNet_Load()/_DotNet_Unload()_Fibonacci()_FileCompare()_FileCompareContents()_FileNameByHandle()_FilePrefix/SRE()_FindInFile()_GetBackgroundColor()/_SetBackgroundColor()_GetConrolID()_GetCtrlClass()_GetDirectoryFormat()_GetDriveMediaType()_GetFilename()/_GetFilenameExt()_GetHardwareID()_GetIP()_GetIP_Country()_GetOSLanguage()_GetSavedSource()_GetStringSize()_GetSystemPaths()_GetURLImage()_GIFImage()_GoogleWeather()_GUICtrlCreateGroup()_GUICtrlListBox_CreateArray()_GUICtrlListView_CreateArray()_GUICtrlListView_SaveCSV()_GUICtrlListView_SaveHTML()_GUICtrlListView_SaveTxt()_GUICtrlListView_SaveXML()_GUICtrlMenu_Recent()_GUICtrlMenu_SetItemImage()_GUICtrlTreeView_CreateArray()_GUIDisable()_GUIImageList_SetIconFromHandle()_GUIRegisterMsg()_GUISetIcon()_Icon_Clear()/_Icon_Set()_IdleTime()_InetGet()_InetGetGUI()_InetGetProgress()_IPDetails()_IsFileOlder()_IsGUID()_IsHex()_IsPalindrome()_IsRegKey()_IsStringRegExp()_IsSystemDrive()_IsUPX()_IsValidType()_IsWebColor()_Language()_Log()_MicrosoftInternetConnectivity()_MSDNDataType()_PathFull/GetRelative/Split()_PathSplitEx()_PrintFromArray()_ProgressSetMarquee()_ReDim()_RockPaperScissors()/_RockPaperScissorsLizardSpock()_ScrollingCredits_SelfDelete()_SelfRename()_SelfUpdate()_SendTo()_ShellAll()_ShellFile()_ShellFolder()_SingletonHWID()_SingletonPID()_Startup()_StringCompact()_StringIsValid()_StringRegExpMetaCharacters()_StringReplaceWholeWord()_StringStripChars()_Temperature()_TrialPeriod()_UKToUSDate()/_USToUKDate()_WinAPI_Create_CTL_CODE()_WinAPI_CreateGUID()_WMIDateStringToDate()/_DateToWMIDateString()Au3 script parsingAutoIt SearchAutoIt3 PortableAutoIt3WrapperToPragmaAutoItWinGetTitle()/AutoItWinSetTitle()CodingDirToHTML5FileInstallrFileReadLastChars()GeoIP databaseGUI - Only Close ButtonGUI ExamplesGUICtrlDeleteImage()GUICtrlGetBkColor()GUICtrlGetStyle()GUIEventsGUIGetBkColor()Int_Parse() & Int_TryParse()IsISBN()LockFile()Mapping CtrlIDsOOP in AutoItParseHeadersToSciTE()PasswordValidPasteBinPosts Per DayPreExpandProtect GlobalsQueue()Resource UpdateResourcesExSciTE JumpSettings INISHELLHOOKShunting-YardSignature CreatorStack()Stopwatch()StringAddLF()/StringStripLF()StringEOLToCRLF()VSCROLLWM_COPYDATAMore Examples...

Updated: 04/09/2015

Share this post


Link to post
Share on other sites

#4 ·  Posted (edited)

You can use png file with GDI+. In picture control can be used just bitmap and jpg.

EDIT: Maybe this example GDI+ can help you

....

Im gonna see if i can make the gui transparent, but if not then ill rather use what i got.

This is how it looks:

Posted Image

Have a look here >>

And as Andreik said there are plenty of Examples by UEZ, Yashied & Zedna discussing the topic of adding a PNG image to a GUIControl.

Ill take a look and search around tomorrow! Edited by Maffe811

[font="helvetica, arial, sans-serif"]Hobby graphics artist, using gimp.Automating pc stuff, using AutoIt.Listening to music, using Grooveshark.[/font]Scripts:[spoiler]Simple ScreenshotSaves you alot of trouble when taking a screenshot!Don't remember what happened with this, but aperantly the exe is all i got.If you don't want to run it, simply don't._IsRun UDFIt figures out if the script has ben ran before based on the info in a ini file.If you don't want to use exactly what i wrote, you can use it as inspiration.[/spoiler]

Share this post


Link to post
Share on other sites

#5 ·  Posted (edited)

This gives you an idea of how to make a GUI transparent. Using _WinAPI_SetLayeredWindowAttributes() with the Style $WS_EX_LAYERED & matching the background colour too.

Edited by guinness

_AdapterConnections()_AlwaysRun()_AppMon()_AppMonEx()_BinaryBin()_CheckMsgBox()_CmdLineRaw()_ContextMenu()_ConvertLHWebColor()/_ConvertSHWebColor()_DesktopDimensions()_DisplayPassword()_DotNet_Load()/_DotNet_Unload()_Fibonacci()_FileCompare()_FileCompareContents()_FileNameByHandle()_FilePrefix/SRE()_FindInFile()_GetBackgroundColor()/_SetBackgroundColor()_GetConrolID()_GetCtrlClass()_GetDirectoryFormat()_GetDriveMediaType()_GetFilename()/_GetFilenameExt()_GetHardwareID()_GetIP()_GetIP_Country()_GetOSLanguage()_GetSavedSource()_GetStringSize()_GetSystemPaths()_GetURLImage()_GIFImage()_GoogleWeather()_GUICtrlCreateGroup()_GUICtrlListBox_CreateArray()_GUICtrlListView_CreateArray()_GUICtrlListView_SaveCSV()_GUICtrlListView_SaveHTML()_GUICtrlListView_SaveTxt()_GUICtrlListView_SaveXML()_GUICtrlMenu_Recent()_GUICtrlMenu_SetItemImage()_GUICtrlTreeView_CreateArray()_GUIDisable()_GUIImageList_SetIconFromHandle()_GUIRegisterMsg()_GUISetIcon()_Icon_Clear()/_Icon_Set()_IdleTime()_InetGet()_InetGetGUI()_InetGetProgress()_IPDetails()_IsFileOlder()_IsGUID()_IsHex()_IsPalindrome()_IsRegKey()_IsStringRegExp()_IsSystemDrive()_IsUPX()_IsValidType()_IsWebColor()_Language()_Log()_MicrosoftInternetConnectivity()_MSDNDataType()_PathFull/GetRelative/Split()_PathSplitEx()_PrintFromArray()_ProgressSetMarquee()_ReDim()_RockPaperScissors()/_RockPaperScissorsLizardSpock()_ScrollingCredits_SelfDelete()_SelfRename()_SelfUpdate()_SendTo()_ShellAll()_ShellFile()_ShellFolder()_SingletonHWID()_SingletonPID()_Startup()_StringCompact()_StringIsValid()_StringRegExpMetaCharacters()_StringReplaceWholeWord()_StringStripChars()_Temperature()_TrialPeriod()_UKToUSDate()/_USToUKDate()_WinAPI_Create_CTL_CODE()_WinAPI_CreateGUID()_WMIDateStringToDate()/_DateToWMIDateString()Au3 script parsingAutoIt SearchAutoIt3 PortableAutoIt3WrapperToPragmaAutoItWinGetTitle()/AutoItWinSetTitle()CodingDirToHTML5FileInstallrFileReadLastChars()GeoIP databaseGUI - Only Close ButtonGUI ExamplesGUICtrlDeleteImage()GUICtrlGetBkColor()GUICtrlGetStyle()GUIEventsGUIGetBkColor()Int_Parse() & Int_TryParse()IsISBN()LockFile()Mapping CtrlIDsOOP in AutoItParseHeadersToSciTE()PasswordValidPasteBinPosts Per DayPreExpandProtect GlobalsQueue()Resource UpdateResourcesExSciTE JumpSettings INISHELLHOOKShunting-YardSignature CreatorStack()Stopwatch()StringAddLF()/StringStripLF()StringEOLToCRLF()VSCROLLWM_COPYDATAMore Examples...

Updated: 04/09/2015

Share this post


Link to post
Share on other sites

I edited Andreik's code and added_WinAPI_SetLayeredWindowAttributes() and $WS_EX_LAYERED as suggested by Guinness.

The problem is that it has rough edges. Not as rough as the bmp, but if im gonna swap my code i rather swap it for the thing i want instead of something im gonna change later anyhow.

Im gonna search for examplesby UEZ, Yashied & Zedna!

#include <GDIPlus.au3>
#Include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $GUI, $W = 600, $H = 600, $GRAPHIC, $IMAGE, $SPLASH_VISIBLE = True

HotKeySet("{ESC}","Quit")       ; Press ESC to quit
HotKeySet("{F1}","ToggleState") ; Press F1 to show/hide the splash

$GUI = GUICreate("Splash Screen",$W,$H,Default,Default,0x80000000,$WS_EX_LAYERED)
SplashScreen($GUI,@DesktopDir & "\groovesharksplashbig.png")
SplashScreen_Show($GUI)
_WinAPI_SetLayeredWindowAttributes($GUI, 0xf0f0f0)


GUIRegisterMsg(0xF, "MY_PAINT")
GUIRegisterMsg(0x85, "MY_PAINT")

While True
    Sleep(10)
WEnd

Func SplashScreen($GUI,$PATH)
    _GDIPlus_Startup()
    $GRAPHIC = _GDIPlus_GraphicsCreateFromHWND($GUI)
    $IMAGE = _GDIPlus_ImageLoadFromFile($PATH)
EndFunc

Func SplashScreen_Show($GUI)
    GUISetState(@SW_SHOW,$GUI)
    _GDIPlus_GraphicsDrawImageRect($GRAPHIC,$IMAGE,0,0,$W,$H)
EndFunc

Func SplashScreen_Hide($GUI)
    GUISetState(@SW_HIDE,$GUI)
EndFunc

Func ToggleState()
    $SPLASH_VISIBLE = Not $SPLASH_VISIBLE
    If $SPLASH_VISIBLE Then
        SplashScreen_Show($GUI)
    Else
        SplashScreen_Hide($GUI)
    EndIf
EndFunc

Func MY_PAINT($hWnd, $msg, $wParam, $lParam)
    _GDIPlus_GraphicsDrawImageRect($GRAPHIC,$IMAGE,0,0,$W,$H)
    Return ''
EndFunc

Func Quit()
    _GDIPlus_ImageDispose($IMAGE)
    _GDIPlus_GraphicsDispose($GRAPHIC)
    _GDIPlus_Shutdown()
    Exit
EndFunc

[font="helvetica, arial, sans-serif"]Hobby graphics artist, using gimp.Automating pc stuff, using AutoIt.Listening to music, using Grooveshark.[/font]Scripts:[spoiler]Simple ScreenshotSaves you alot of trouble when taking a screenshot!Don't remember what happened with this, but aperantly the exe is all i got.If you don't want to run it, simply don't._IsRun UDFIt figures out if the script has ben ran before based on the info in a ini file.If you don't want to use exactly what i wrote, you can use it as inspiration.[/spoiler]

Share this post


Link to post
Share on other sites

#7 ·  Posted (edited)

This work for me, but i dont know how to make the semi transparency work... it apears like solid..

#include <GDIPlus.au3>
#Include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $GUI, $W = 600, $H = 600, $GRAPHIC, $IMAGE, $SPLASH_VISIBLE = True

HotKeySet("{ESC}","Quit")       ; Press ESC to quit
HotKeySet("{F1}","ToggleState") ; Press F1 to show/hide the splash

$GUI = GUICreate("Splash Screen",$W,$H,-1,-1,$WS_POPUP,$WS_EX_LAYERED)
GuisetBkColor(0xf0f0f0, $GUI)
_WinAPI_SetLayeredWindowAttributes($GUI, 0xf0f0f0,255,0x03) ; I dont know why but this go before...
                                                            ; ...Splashing the image
SplashScreen($GUI,@Scriptdir & "\groovesharksplash.png")
SplashScreen_Show($GUI)



GUIRegisterMsg(0xF, "MY_PAINT")
GUIRegisterMsg(0x85, "MY_PAINT")

While True
    Sleep(10)
WEnd

Func SplashScreen($GUI,$PATH)
    _GDIPlus_Startup()
    $IMAGE = _GDIPlus_ImageLoadFromFile($PATH)
    $GRAPHIC = _GDIPlus_GraphicsCreateFromHWND($GUI)
EndFunc

Func SplashScreen_Show($GUI)
    GUISetState(@SW_SHOW,$GUI)
    _GDIPlus_GraphicsDrawImagerect($GRAPHIC,$IMAGE,0,0,$W,$H)
EndFunc

Func SplashScreen_Hide($GUI)
    GUISetState(@SW_HIDE,$GUI)
EndFunc

Func ToggleState()
    $SPLASH_VISIBLE = Not $SPLASH_VISIBLE
    If $SPLASH_VISIBLE Then
        SplashScreen_Show($GUI)
    Else
        SplashScreen_Hide($GUI)
    EndIf
EndFunc

Func MY_PAINT($hWnd, $msg, $wParam, $lParam)
    _GDIPlus_GraphicsDrawImageRect($GRAPHIC,$IMAGE,0,0,$W,$H)
    Return ''
EndFunc

Func Quit()
    _GDIPlus_ImageDispose($IMAGE)
    _GDIPlus_GraphicsDispose($GRAPHIC)
    _GDIPlus_Shutdown()
    Exit
EndFunc

EDIT: I Change @Desktopdir ---> @Scriptdir

Edited by monoscout999

Share this post


Link to post
Share on other sites

#8 ·  Posted (edited)

Or this >>

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

_Splash()

Func _Splash()
    Local $hGUI

    $hGUI = GUICreate("", 300, 300, -1, -1, -1, BitOR($WS_EX_LAYERED, $WS_EX_TOPMOST))
    GUISetState(@SW_SHOW, $hGUI)

    _GDIPlus_Startup()
    _SetBitmap($hGUI, @ScriptDir & "\Splash.png", 255) ; <<<<< Change the Image name.

    GUIRegisterMsg($WM_NCHITTEST, "WM_NCHITTEST")

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                _GDIPlus_Shutdown()
                Exit

        EndSwitch
    WEnd
EndFunc   ;==>_Main

Func _SetBitmap($hGUI, $sImageFile, $iOpacity)
    Local $hBitmap, $hGetDC, $hImage, $hMemDC, $hPreviousImage, $pBlend, $pSize, $pSource, $tBlend, $tSize, $tSource

    $hImage = _GDIPlus_ImageLoadFromFile($sImageFile)
    $hGetDC = _WinAPI_GetDC(0)
    $hMemDC = _WinAPI_CreateCompatibleDC($hGetDC)
    $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
    $hPreviousImage = _WinAPI_SelectObject($hMemDC, $hBitmap)
    $tSize = DllStructCreate($tagSIZE)
    $pSize = DllStructGetPtr($tSize)
    DllStructSetData($tSize, "X", _GDIPlus_ImageGetWidth($hImage))
    DllStructSetData($tSize, "Y", _GDIPlus_ImageGetHeight($hImage))
    $tSource = DllStructCreate($tagPOINT)
    $pSource = DllStructGetPtr($tSource)
    $tBlend = DllStructCreate($tagBLENDFUNCTION)
    $pBlend = DllStructGetPtr($tBlend)
    DllStructSetData($tBlend, "Alpha", $iOpacity)
    DllStructSetData($tBlend, "Format", 1)
    _WinAPI_UpdateLayeredWindow($hGUI, $hGetDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, $ULW_ALPHA)
    _WinAPI_ReleaseDC(0, $hGetDC)
    _WinAPI_SelectObject($hMemDC, $hPreviousImage)
    _WinAPI_DeleteObject($hBitmap)
    _WinAPI_DeleteDC($hMemDC)
EndFunc   ;==>_SetBitmap

Func WM_NCHITTEST($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam, $ilParam
    Return $HTCAPTION
EndFunc   ;==>WM_NCHITTEST

I used _SetBitmap & WM_NCHITTEST so the image file can be moved around the Screen. I hope this is what you're looking for and you can see similar code in the link I provided above.

Edited by guinness

_AdapterConnections()_AlwaysRun()_AppMon()_AppMonEx()_BinaryBin()_CheckMsgBox()_CmdLineRaw()_ContextMenu()_ConvertLHWebColor()/_ConvertSHWebColor()_DesktopDimensions()_DisplayPassword()_DotNet_Load()/_DotNet_Unload()_Fibonacci()_FileCompare()_FileCompareContents()_FileNameByHandle()_FilePrefix/SRE()_FindInFile()_GetBackgroundColor()/_SetBackgroundColor()_GetConrolID()_GetCtrlClass()_GetDirectoryFormat()_GetDriveMediaType()_GetFilename()/_GetFilenameExt()_GetHardwareID()_GetIP()_GetIP_Country()_GetOSLanguage()_GetSavedSource()_GetStringSize()_GetSystemPaths()_GetURLImage()_GIFImage()_GoogleWeather()_GUICtrlCreateGroup()_GUICtrlListBox_CreateArray()_GUICtrlListView_CreateArray()_GUICtrlListView_SaveCSV()_GUICtrlListView_SaveHTML()_GUICtrlListView_SaveTxt()_GUICtrlListView_SaveXML()_GUICtrlMenu_Recent()_GUICtrlMenu_SetItemImage()_GUICtrlTreeView_CreateArray()_GUIDisable()_GUIImageList_SetIconFromHandle()_GUIRegisterMsg()_GUISetIcon()_Icon_Clear()/_Icon_Set()_IdleTime()_InetGet()_InetGetGUI()_InetGetProgress()_IPDetails()_IsFileOlder()_IsGUID()_IsHex()_IsPalindrome()_IsRegKey()_IsStringRegExp()_IsSystemDrive()_IsUPX()_IsValidType()_IsWebColor()_Language()_Log()_MicrosoftInternetConnectivity()_MSDNDataType()_PathFull/GetRelative/Split()_PathSplitEx()_PrintFromArray()_ProgressSetMarquee()_ReDim()_RockPaperScissors()/_RockPaperScissorsLizardSpock()_ScrollingCredits_SelfDelete()_SelfRename()_SelfUpdate()_SendTo()_ShellAll()_ShellFile()_ShellFolder()_SingletonHWID()_SingletonPID()_Startup()_StringCompact()_StringIsValid()_StringRegExpMetaCharacters()_StringReplaceWholeWord()_StringStripChars()_Temperature()_TrialPeriod()_UKToUSDate()/_USToUKDate()_WinAPI_Create_CTL_CODE()_WinAPI_CreateGUID()_WMIDateStringToDate()/_DateToWMIDateString()Au3 script parsingAutoIt SearchAutoIt3 PortableAutoIt3WrapperToPragmaAutoItWinGetTitle()/AutoItWinSetTitle()CodingDirToHTML5FileInstallrFileReadLastChars()GeoIP databaseGUI - Only Close ButtonGUI ExamplesGUICtrlDeleteImage()GUICtrlGetBkColor()GUICtrlGetStyle()GUIEventsGUIGetBkColor()Int_Parse() & Int_TryParse()IsISBN()LockFile()Mapping CtrlIDsOOP in AutoItParseHeadersToSciTE()PasswordValidPasteBinPosts Per DayPreExpandProtect GlobalsQueue()Resource UpdateResourcesExSciTE JumpSettings INISHELLHOOKShunting-YardSignature CreatorStack()Stopwatch()StringAddLF()/StringStripLF()StringEOLToCRLF()VSCROLLWM_COPYDATAMore Examples...

Updated: 04/09/2015

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0