GUICtrlSetImage() forces Pic control to resize

[mikell 646]

Hello

GUICtrlSetImage() forces a pic control created with GUICtrlCreatePic() to resize, and I can't find why.

I searched evrywhere on the forum and the only solution I could find to work was to delete and recreate the pic control... it works but makes my image flicker

The strangest thing is that I made this script and compiled it in 2009 and this old exe works nice, while the .au3 I used to compile it actually doesn't work....

Help please !

Edit :

If I put no style or exstyle for the border of my Pic, then no problem.

it occurs only if I use $SS_SUNKEN, $WS_EX_DLGMODALFRAME, $WS_EX_CLIENTEDGE, etc

Is there a way to solve this ?

Edited June 13, 2011 by mikell

[KaFu 185]

Works fine for me. Did you declare the width and height of the control explicitly?

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$s_AU_Path = StringTrimRight(@AutoItExe, StringLen(@AutoItExe) - StringInStr(@AutoItExe, "\", 2, -1)) & "\Examples\GUI"

GUICreate("My GUI picture", 350, 300, -1, -1, $WS_SIZEBOX + $WS_SYSMENU) ; will create a dialog box that when displayed is centered

GUISetBkColor(0xE0FFFF)
$n = GUICtrlCreatePic($s_AU_Path & "\mslogo.jpg", 50, 50, 255, 40)
GUISetState()

Sleep(2000)
GUICtrlSetImage($n, $s_AU_Path & "\msoobe.jpg")

Sleep(2000)
GUICtrlSetImage($n, $s_AU_Path & "\logo4.gif")


; Run the GUI until the dialog is closed
While 1
    $msg = GUIGetMsg()

    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd

GUIDelete()

[mikell 646]

Yes I did

The problem occurs when I give a border style to the pic

On your script with this line, you can see the pic grow

$n = GUICtrlCreatePic($s_AU_Path & "\mslogo.jpg", 50, 50, 255, 40, $SS_SUNKEN)

[rover 42]

Yes I did

The problem occurs when I give a border style to the pic

On your script with this line, you can see the pic grow

$n = GUICtrlCreatePic($s_AU_Path & "\mslogo.jpg", 50, 50, 255, 40, $SS_SUNKEN)

use the SS_CENTERIMAGE style

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>

$s_AU_Path = StringTrimRight(@AutoItExe, StringLen(@AutoItExe) - StringInStr(@AutoItExe, "\", 2, -1)) & "\Examples\GUI"

GUICreate("My GUI picture", 350, 300, -1, -1, $WS_SIZEBOX + $WS_SYSMENU)
GUISetBkColor(0xE0FFFF)

;draw black border around pic control to highlight
;the image size/placement issue without the SS_CENTERIMAGE style
GUICtrlCreateLabel("", 48, 48, 258, 43, $SS_BLACKFRAME)
GuiCtrlSetState(-1,$GUI_DISABLE)

$n = GUICtrlCreatePic($s_AU_Path & "\mslogo.jpg", 50, 50, 255, 40, BitOR($SS_CENTERIMAGE, $SS_SUNKEN), $WS_EX_CLIENTEDGE)
GUISetState()

Sleep(2000)
GUICtrlSetImage($n, $s_AU_Path & "\msoobe.jpg")

Sleep(2000)
GUICtrlSetImage($n, $s_AU_Path & "\logo4.gif")


; Run the GUI until the dialog is closed
While 1
    $msg = GUIGetMsg()

    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd

GUIDelete()

[mikell 646]

Thanks a lot !

This $SS_CENTERIMAGE feature is not very explicite when reading the helpfile ...

Edit: though I still don't understand why my 2009 script didn't get this trouble

Edited June 16, 2011 by mikell

[guinness 1,458]

It's to be expected as AutoIt has been updated quite a bit since 2009

Edited June 16, 2011 by guinness

[mikell 646]

I know this a bit

But I wonder what precisely in the update(s) caused the trouble

Curiosity only For educational purpose

Edited June 16, 2011 by mikell