GUICtrlCreateListView to Array

[Jaboowaki]

Is there a way to read the whole list in ListView to an array?

[Melba23]

Jaboowaki,

My GUIListViewEx UDF will do that - although you do have to use the UDF function to alter the listview contents. Look in my sig.

And I believe guinness has produced a number of UDFs to extract data from ListViews.

M23

[BrewManNH]

How are you building the ListView's contents? You could build an array as you're building your listview.

[AdmiralAlkex]

_GUICtrlListView_GetItemTextArray()? Or just loop through the items and create the array yourself?

[BrewManNH]

_GUICtrlListView_GetItemTextArray()?

Unfortunately, that only gets one "row" of a listview to put into an array, not what the OP was looking for I'd guess.

[AdmiralAlkex]

Unfortunately, that only gets one "row" of a listview to put into an array, not what the OP was looking for I'd guess.

Oh right.

@Jaboowaki

Just write your own code then. Would have taken less time than waiting for answers on the forum.

Edited August 11, 2011 by AdmiralAlkex

[Jaboowaki]

Awesome thank you for the help and creating a very useful UDF. I'm creating the Array as I create the LV.

Edited August 11, 2011 by Jaboowaki

[taietel]

Here's an example from a program I'm working on ($hLV is the handle to the listview):

Func _Array2Csv($hLV, $sFile = "")
 Local $hFile, $aTxt, $iItems
 If $sFile = "" Then $sFile = @ScriptDir & "\ExportLV_" & @HOUR & "-" & @MIN & "-" & @SEC & ".csv"
 $hFile = FileOpen($sFile, 18)
 If $hFile = -1 Then
  MsgBox(48, "Error", "File could not be opened")
  Return
 EndIf
 $iItems = _GUICtrlListView_GetItemCount($hLV)
 For $i = 0 To $iItems - 1
  $aTxt &= _GUICtrlListView_GetItemTextString($hLV, $i) & @CRLF
 Next
 FileWrite($hFile, $aTxt)
 FileClose($hFile)
 MsgBox(64, "Export Listview", "Done")
EndFunc   ;==>_Box_Array2Csv

[EDIT] I've copied the wrong function. Here's the one I wanted to post:

Func _Box_LV2Array($hLV)
 Local $iRows, $iCols
 $iRows = _GUICtrlListView_GetItemCount($hLV)
 $iCols = _GUICtrlListView_GetColumnCount($hLV)
 Local $aArray[$iRows][$iCols]
 For $i = 0 To $iRows - 1
  Local $aItem = _GUICtrlListView_GetItemTextArray($hLV, $i)
  For $j = 1 To $aItem[0]
   $aArray[$i][$j - 1] = $aItem[$j]
  Next
 Next
 _ArrayDisplay($aArray) ;for testing
 ;Return $aArray ;uncomment this to return the array
EndFunc   ;==>_Box_LV2Array

Edited August 11, 2011 by taietel

[guinness]

And I believe guinness has produced a number of UDFs to extract data from ListViews.

I have indeed, check in my signature.

will create an Array and you need to pass the handle of the ListView not the ControlID.

Edited August 11, 2011 by guinness

[Scriptonize]

This is my little function doing exactly the same thing.

My listview item has to columns, each of the columns will be added to the array.

Have fun with it.

Remark: $h_lstvwWrkCodes is a handle to the listview control.

Func LstViewItems2Array()
    #cs -------------------------------------------------------------------------------
    |   Function fills the array with the current content of listview items
    #ce -------------------------------------------------------------------------------
    Local $int_ListItems, $int_i,  $arr_lstViewItems[1][2]

    $int_ListItems = _GUICtrlListView_GetItemCount($h_lstvwWrkCodes)
    Redim $arr_lstViewItems[$int_ListItems+1][2]

    $arr_lstViewItems[0][0] = $int_ListItems
    $arr_lstViewItems[0][1] = "[0][0] indicates the number of items found in the listview."

    For $int_i = 1 to $int_ListItems
        $arr_lstViewItems[$int_i][0] = _GUICtrlListView_GetItemText($h_lstvwWrkCodes,$int_i - 1,0)
        $arr_lstViewItems[$int_i][1] = _GUICtrlListView_GetItemText($h_lstvwWrkCodes,$int_i - 1,1)
    Next

    _ArrayDisplay($arr_lstViewItems,"$arr_lstViewItems")

EndFunc

[guinness]

@Scriptonize - this Function won't work correctly if I have more than 2 columns in the array, also why don't you pass the ListView handle to the Function instead of using a Global variable e.g. >>

LstViewItems2Array($hListView)

[Scriptonize]

this Function won't work correctly if I have more than 2 columns in the array

In case you have three columns, you need to adjust the code.

It then would become something like this:

Func LstViewItems2Array()
    #cs -------------------------------------------------------------------------------
    |   Function fills the array with the current content of listview items
    #ce -------------------------------------------------------------------------------
    Local $int_ListItems, $int_i,  $arr_lstViewItems[1][3]

    $int_ListItems = _GUICtrlListView_GetItemCount($h_lstvwWrkCodes)
    Redim $arr_lstViewItems[$int_ListItems+1][3]

    $arr_lstViewItems[0][0] = $int_ListItems
    $arr_lstViewItems[0][1] = "[0][0] indicates the number of items found in the listview."

    For $int_i = 1 to $int_ListItems
        $arr_lstViewItems[$int_i][0] = _GUICtrlListView_GetItemText($h_lstvwWrkCodes,$int_i - 1,0)
        $arr_lstViewItems[$int_i][1] = _GUICtrlListView_GetItemText($h_lstvwWrkCodes,$int_i - 1,1)
        $arr_lstViewItems[$int_i][2] = _GUICtrlListView_GetItemText($h_lstvwWrkCodes,$int_i - 1,2)
    Next

    _ArrayDisplay($arr_lstViewItems,"$arr_lstViewItems")

EndFunc

also why don't you pass the ListView handle to the Function instead of using a Global variable

That is a neater way to do it.

It can be made more sophisticated in many ways, but I wanted to give a very simple example.

[guinness]

In case you have three columns, you need to adjust the code.

OK, for someone starting out this might not be apparent. Personally I find it easy just to count the number of columns and use a couple of loops, without the fuss Edited August 11, 2011 by guinness