DllStructCreate & DllStructGet/SetData - element name or index (code of practice)

[guinness]

I was just curious as to what was the preferred approach when using DllStructCreate and then later using DllStructGetData/DllStructSetData etc... Is it more customary to declare an element name in DllStructCreate to later use in DllStructGetData/DllStructSetData or opt for using just the element index instead?

It might be a straightforward answer of "both are fine" but I'm wanting to improve my understanding of the language as well as the best practices for creating good code.

Example: This is an example of the API function GetVersionExW

expandcollapse popup

#include <Array.au3>

#cs
    Note: You must have the latest beta as these examples are using struct* instead of DllStructGetPtr.
#ce

Local $aArray = _WindowsOSVersion_1() ; Using DllStructCreate with the Element name.
_ArrayDisplay($aArray)

$aArray = _WindowsOSVersion_2() ; Using DllStructCreate with the Element index number.
_ArrayDisplay($aArray)

Func _WindowsOSVersion_1() ; Using DllStructCreate with the Element name.
    Local $aVersion[4] = [-1, -1, -1, -1]
    Local $tagOSVERSIONINFO = DllStructCreate('dword dwOSVersionInfoSize;dword dwMajorVersion;dword dwMinorVersion;dword dwBuildNumber;dword dwPlatformId;wchar szCSDVersion[128]')
    DllStructSetData($tagOSVERSIONINFO, 'dwOSVersionInfoSize', DllStructGetSize($tagOSVERSIONINFO))

    Local $aReturn = DllCall('kernel32.dll', 'int', 'GetVersionExW', 'struct*', $tagOSVERSIONINFO)
    If @error Or Not $aReturn[0] Then
        Return SetError(1, 0, $aReturn)
    EndIf

    $aVersion[0] = DllStructGetData($tagOSVERSIONINFO, 'dwMajorVersion')
    $aVersion[1] = DllStructGetData($tagOSVERSIONINFO, 'dwMinorVersion')
    $aVersion[2] = DllStructGetData($tagOSVERSIONINFO, 'dwBuildNumber')
    $aVersion[3] = DllStructGetData($tagOSVERSIONINFO, 'szCSDVersion')
    Return $aVersion
EndFunc   ;==>_WindowsOSVersion_1

Func _WindowsOSVersion_2() ; Using DllStructCreate with the Element index number.
    Local $aVersion[4] = [-1, -1, -1, -1]
    Local $tagOSVERSIONINFO = DllStructCreate('dword;dword;dword;dword;dword;wchar[128]')
    DllStructSetData($tagOSVERSIONINFO, 1, DllStructGetSize($tagOSVERSIONINFO))

    Local $aReturn = DllCall('kernel32.dll', 'int', 'GetVersionExW', 'struct*', $tagOSVERSIONINFO)
    If @error Or Not $aReturn[0] Then
        Return SetError(1, 0, $aVersion)
    EndIf

    $aVersion[0] = DllStructGetData($tagOSVERSIONINFO, 2)
    $aVersion[1] = DllStructGetData($tagOSVERSIONINFO, 3)
    $aVersion[2] = DllStructGetData($tagOSVERSIONINFO, 4)
    $aVersion[3] = DllStructGetData($tagOSVERSIONINFO, 6)
    Return $aVersion
EndFunc   ;==>_WindowsOSVersion_2

Edited November 28, 2011 by guinness

[Shaggi]

Use elements names for clarity, else just for indexes. An element name takes O(n) strcmp whilst indexes are direct access (i assume)

Edited November 29, 2011 by Shaggi

[guinness]

OK, I thought as much. Thanks shaggi.

[KaFu]

Using the type 'struct*' (latest Beta required) + fetching the data via the element index and not the name seems the be the fastest way ...

expandcollapse popup

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Version=Beta
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <Array.au3>
#cs
 Note: You must have the latest beta as these examples are using struct* instead of DllStructGetPtr.
#ce
#cs
Local $aArray = _WindowsOSVersion_1() ; Using DllStructCreate with the Element name.
_ArrayDisplay($aArray)
$aArray = _WindowsOSVersion_2() ; Using DllStructCreate with the Element index number.
_ArrayDisplay($aArray)
#ce
$timer = TimerInit()
For $i = 0 To 10000
 _WindowsOSVersion_1()
Next
ConsoleWrite(TimerDiff($timer) & @CRLF)
$timer = TimerInit()
For $i = 0 To 10000
 _WindowsOSVersion_2()
Next
ConsoleWrite(TimerDiff($timer) & @CRLF)
$timer = TimerInit()
For $i = 0 To 10000
 _WindowsOSVersion_3()
Next
ConsoleWrite(TimerDiff($timer) & @CRLF)
$timer = TimerInit()
For $i = 0 To 10000
 _WindowsOSVersion_4()
Next
ConsoleWrite(TimerDiff($timer) & @CRLF)

Func _WindowsOSVersion_1() ; Using DllStructCreate with the Element name.
 Local $aVersion[4] = [-1, -1, -1, -1]
 Local $tagOSVERSIONINFO = DllStructCreate('dword dwOSVersionInfoSize;dword dwMajorVersion;dword dwMinorVersion;dword dwBuildNumber;dword dwPlatformId;wchar szCSDVersion[128]')
 DllStructSetData($tagOSVERSIONINFO, 'dwOSVersionInfoSize', DllStructGetSize($tagOSVERSIONINFO))
 Local $aReturn = DllCall('kernel32.dll', 'int', 'GetVersionExW', 'struct*', $tagOSVERSIONINFO)
 If @error Or Not $aReturn[0] Then
  Return SetError(1, 0, $aReturn)
 EndIf
 $aVersion[0] = DllStructGetData($tagOSVERSIONINFO, 'dwMajorVersion')
 $aVersion[1] = DllStructGetData($tagOSVERSIONINFO, 'dwMinorVersion')
 $aVersion[2] = DllStructGetData($tagOSVERSIONINFO, 'dwBuildNumber')
 $aVersion[3] = DllStructGetData($tagOSVERSIONINFO, 'szCSDVersion')
 Return $aVersion
EndFunc   ;==>_WindowsOSVersion_1
Func _WindowsOSVersion_2() ; Using DllStructCreate with the Element index number.
 Local $aVersion[4] = [-1, -1, -1, -1]
 Local $tagOSVERSIONINFO = DllStructCreate('dword;dword;dword;dword;dword;wchar[128]')
 DllStructSetData($tagOSVERSIONINFO, 1, DllStructGetSize($tagOSVERSIONINFO))
 Local $aReturn = DllCall('kernel32.dll', 'int', 'GetVersionExW', 'struct*', $tagOSVERSIONINFO)
 If @error Or Not $aReturn[0] Then
  Return SetError(1, 0, $aVersion)
 EndIf
 $aVersion[0] = DllStructGetData($tagOSVERSIONINFO, 2)
 $aVersion[1] = DllStructGetData($tagOSVERSIONINFO, 3)
 $aVersion[2] = DllStructGetData($tagOSVERSIONINFO, 4)
 $aVersion[3] = DllStructGetData($tagOSVERSIONINFO, 6)
 Return $aVersion
EndFunc   ;==>_WindowsOSVersion_2
Func _WindowsOSVersion_3() ; Using DllStructCreate with the Element name.
 Local $aVersion[4] = [-1, -1, -1, -1]
 Local $tagOSVERSIONINFO = DllStructCreate('dword dwOSVersionInfoSize;dword dwMajorVersion;dword dwMinorVersion;dword dwBuildNumber;dword dwPlatformId;wchar szCSDVersion[128]')
 DllStructSetData($tagOSVERSIONINFO, 'dwOSVersionInfoSize', DllStructGetSize($tagOSVERSIONINFO))
 Local $aReturn = DllCall('kernel32.dll', 'int', 'GetVersionExW', 'ptr', DllStructGetPtr($tagOSVERSIONINFO))
 If @error Or Not $aReturn[0] Then
  Return SetError(1, 0, $aReturn)
 EndIf
 $aVersion[0] = DllStructGetData($tagOSVERSIONINFO, 'dwMajorVersion')
 $aVersion[1] = DllStructGetData($tagOSVERSIONINFO, 'dwMinorVersion')
 $aVersion[2] = DllStructGetData($tagOSVERSIONINFO, 'dwBuildNumber')
 $aVersion[3] = DllStructGetData($tagOSVERSIONINFO, 'szCSDVersion')
 Return $aVersion
EndFunc   ;==>_WindowsOSVersion_1
Func _WindowsOSVersion_4() ; Using DllStructCreate with the Element index number.
 Local $aVersion[4] = [-1, -1, -1, -1]
 Local $tagOSVERSIONINFO = DllStructCreate('dword;dword;dword;dword;dword;wchar[128]')
 DllStructSetData($tagOSVERSIONINFO, 1, DllStructGetSize($tagOSVERSIONINFO))
 Local $aReturn = DllCall('kernel32.dll', 'int', 'GetVersionExW', 'ptr', DllStructGetPtr($tagOSVERSIONINFO))
 If @error Or Not $aReturn[0] Then
  Return SetError(1, 0, $aVersion)
 EndIf
 $aVersion[0] = DllStructGetData($tagOSVERSIONINFO, 2)
 $aVersion[1] = DllStructGetData($tagOSVERSIONINFO, 3)
 $aVersion[2] = DllStructGetData($tagOSVERSIONINFO, 4)
 $aVersion[3] = DllStructGetData($tagOSVERSIONINFO, 6)
 Return $aVersion
EndFunc   ;==>_WindowsOSVersion_2

[guinness]

Thanks KaFu, I got the same result, example 2 was quicker of the 4.