_SingletonPID() - Enforce only one instance of the program running. Use AutoIt's hidden window.

[guinness]

This is slightly different to how _Singleton() (Misc.au3) works by Valik, because firstly this function uses the hidden window of an AutoIt executable and secondly it returns the PID of the main executable, not the handle to the object used for synchronization. It should also be noted that $iFlag parameter 2 doesn't exist in this function and if no program exists already _SingletonPID() returns 0. Any suggestions are welcome. Thanks.

Function:

expandcollapse popup

#include <StringConstants.au3>

; #FUNCTION# ====================================================================================================================
; Name ..........: _SingletonPID
; Description ...: Enforce a design paradigm where only one instance of the script may be running.
; Syntax ........: _SingletonPID($sOccurenceName[, $iFlag = 0])
; Parameters ....: $sOccurenceName      - String to identify the occurrence of the script.
;                  $iFlag               - [optional] Optional parameters (see below). Default is 0.
;                       0 - Exit the script with the exit code -1 if another instance already exists.
;                       1 - Return the PID of the initial executable.
; Return values .: Success - 0 (no additional instances exist).
;                  Failure - The PID of the initial instance.
; Author ........: guinness with initial ideas by Valik for _Singleton() & KaFu for _EnforceSingleInstance().
; Example .......: Yes
; ===============================================================================================================================
Func _SingletonPID($sOccurenceName, $iFlag = 0)
    Local $hAutoItWnd = WinGetHandle($sOccurenceName)
    If @error Then
        Local Const $sUniqName = @AutoItPID & '__' & $sOccurenceName & '__' & @AutoItPID
        AutoItWinSetTitle($sUniqName)
        $hAutoItWnd = WinGetHandle($sUniqName)
        AutoItWinSetTitle($sOccurenceName)

        ; Append the current AutoIt PID placeholder to the edit control
        Local Const $hControl = ControlGetHandle($hAutoItWnd, '', 'Edit1')
        ControlSetText($hAutoItWnd, '', $hControl, ControlGetText($hAutoItWnd, '', $hControl) & @CRLF & _
                '|AUTOIT_SINGLETON_PID:' & @AutoItPID & @CRLF)

        Return 0
    EndIf

    If $iFlag = Default Or $iFlag = 0 Then
        Exit -1
    EndIf

    ; Get the edit control text and append a default AutoIt PID placeholder, in case it doesn't exist
    Local Const $sCtrlText = ControlGetText($hAutoItWnd, '', ControlGetHandle($hAutoItWnd, '', 'Edit1')) & @CRLF & _
                '|AUTOIT_SINGLETON_PID:0' & @CRLF

    ; Get the first match and parse as an integer
    Return Int(StringRegExp($sCtrlText, _
                '\|AUTOIT_SINGLETON_PID:(\d+)\R', $STR_REGEXPARRAYMATCH)[0])
EndFunc   ;==>_SingletonPID

Example 1:

#include <MsgBoxConstants.au3>

Example()

Func Example()
    If @Compiled Then
        Local $iSingleton = _SingletonPID('myUniqueName', 1)
        If Not $iSingleton Then
            MsgBox($MB_SYSTEMMODAL, 'PID: ' & @AutoItPID, 'This is the first instance of the program running: ' & $iSingleton)
        Else
            MsgBox($MB_SYSTEMMODAL, 'PID: ' & @AutoItPID, 'There is another instance running. This PID is: ' & $iSingleton)
        EndIf
    Else
        MsgBox($MB_SYSTEMMODAL, 'PID: ' & @AutoItPID, 'Please compile the code and run the executable twice to see the two different messages.')
    EndIf
EndFunc   ;==>Example

Example 2:

#include <MsgBoxConstants.au3>

Example()

Func Example()
    If @Compiled Then
        Local $iSingleton = _SingletonPID('myUniqueName', 1)
        If Not $iSingleton Then
            MsgBox($MB_SYSTEMMODAL, 'PID: ' & @AutoItPID, 'This is the first instance of the program running: ' & $iSingleton)
        Else
            MsgBox($MB_SYSTEMMODAL, 'PID: ' & @AutoItPID, 'There is another instance running. This PID is: ' & $iSingleton)

            ; Wait for the process to close.
            ProcessWaitClose($iSingleton, 5)

            ; Reset _SingletonPID() to the current process since the previous one was closed.
            $iSingleton = _SingletonPID('myUniqueName', 1)
            MsgBox($MB_SYSTEMMODAL, 'PID: ' & @AutoItPID, 'This is now the first instance of the program running: ' & $iSingleton)
        EndIf
    Else
        MsgBox($MB_SYSTEMMODAL, 'PID: ' & @AutoItPID, 'Please compile the code and run the executable twice to see the two different messages.')
    EndIf
EndFunc   ;==>Example

Edited April 22, 2018 by guinness

[qvex21]

Great. I am just writing my first script in a productive environment and already needed a way to prevent multiple instances of the script, but not by preventing further intances from executing but by killing the older instances. So your 2 weeks old function just comes just at the right time for me.

dim $iScriptIsRunnig = _SingletonPID( "HWS-start-stop.exe", 1)
If $iScriptIsRunnig Then ProcessClose( $iScriptIsRunnig)

Thanks a lot.

[guinness]

Great, didn't think anyone would use it. One point to make with your code is don't use Dim, try to use Global (if necessary) or Local scope.

[qvex21]

Great, didn't think anyone would use it.

And i didn't think that my problem would be solved so quickly.

One point to make with your code is don't use Dim, try to use Global (if necessary) or Local scope.

Thanks for the hint.

[qvex21]

Local $iScriptIsRunnig = _SingletonPID( "HWS-start-stop.exe", 1)
If $iScriptIsRunnig Then ProcessWaitClose( $iScriptIsRunnig)
; some code

MMh... When i execute my compiled script, it runs (ok). When i execute it again while the first instance is still running, it kills the older instance and runs (ok). Now only the new instance is running (looked up that in process explorer). But when i execute it again the third time, it doesn't kill the other instance any more.

Edited May 14, 2012 by qvex21

[guinness]

There is no bug, everything is working correctly, basically you need to reset _SingletonPID to the new process e.g.

Local $iSingleton = _SingletonPID('RandomName', 1)

If $iSingleton = 0 Then
    MsgBox(4096, '', 'This is the first instance of the program running: ' & $iSingleton)
Else
    MsgBox(4096, '', 'There is another instance running. This PID is: ' & $iSingleton)

    ; Wait for the process to close.
    ProcessWaitClose($iSingleton, 5)

    ; Reset _SingletonPID to current process since the previous one was closed.
    $iSingleton = _SingletonPID('RandomName', 1)
    MsgBox(4096, '', 'This is now the first instance of the program running: ' & $iSingleton)
EndIf

[qvex21]

There is no bug, everything is working correctly, basically you need to reset _SingletonPID to the new process e.g.

I thought that, when only the second instance is running and i start the third, the first line of my code should do the reset. Maybe i unterstand that later, i am just a beginner. Anyway, meanwhile i solved my problem this way:

$aProcList = ProcessList ( "HWS-start-stop.exe" )
For $i = 1 To $aProcList[0][0]
    If $aProcList[$i][1] <> @AutoItPID Then ProcessClose($aProcList[$i][1])
Next

Edited May 15, 2012 by qvex21

[guinness]

I'm not following, what I provided you works.

Edit: Ah, I think you misunderstood the purpose of this function from what you posted.

Edited May 15, 2012 by guinness

[guinness]

Updated the function syntax and added a second example on how to close the PID and reset to the current process.

[guinness]

Updated the example by replacing 4096 with the $MB_SYSTEMMODAL constant variable.

[robertcollier4]

A Simpler way of doing Example #2 without needing the full function. Closes all previous instances of a script so as to have only the most recently launched version of the script running:

Global Const $_AUTOIT_WIN_TITLE = "My Singleton Identifier"

While WinExists($_AUTOIT_WIN_TITLE)
    WinClose($_AUTOIT_WIN_TITLE)
WEnd

AutoItWinSetTitle($_AUTOIT_WIN_TITLE)

Edited June 7, 2013 by robertcollier4

[guinness]

You missed the point of the function.

[robertcollier4]

Example #2 had the problem for me that it did not remove the tray icon of the previous AutoIt script instance from the taskbar. I have to move my mouse over the system tray for the tray icon to then get removed. So it seems that to use WinClose is better because it notifies Windows of the close so it can update/remove its system tray icon. Also, ProcessWaitClose for some reason is buggy for me and sometimes does not work but instead returns 0 to indicate it timed out.

So if you are having problems with ProcessClose / ProcessWaitClose, try using WinClose instead.

[guinness]

It's not the UDF at fault. Could you provide details of your system and AutoIt version.

[robertcollier4]

It's not the UDF at fault. Could you provide details of your system and AutoIt version.

The UDF is good. However I am just commenting on Example #2 where you specifically want the design paradigm of closing previous instances - the use of ProcessClose / ProcessWaitClose should be replaced with WinClose since WinClose will update the system tray and remove the tray icon without manually having to move your mouse over it. I am using WinXP x86 AutoIt 3394 Beta.

 

So, you could replace:

ProcessWaitClose($iSingleton, 5)

With:

While WinExists('myUniqueName')
    WinClose('myUniqueName')
WEnd

Edited June 7, 2013 by robertcollier4

[guinness]

OK, but this is an example and nothing to do with the UDF.

[guinness]

I have updated the function and example. Enjoy!

[guinness]

The help file example modified.

; #include <Misc.au3>
#include <MsgBoxConstants.au3>

If _Singleton("test", 1) Then
    MsgBox($MB_SYSTEMMODAL, "Warning", "An occurrence of test is already running")
    Exit
EndIf
MsgBox($MB_SYSTEMMODAL, "OK", "the first occurrence of test is running")

[kylejustknows]

thanks!  one problem solved!

 

robertcollier4, the system tray icon stuck is an windows system problem. there is a UDF to refresh that. BTW there is a func to find the windows title using the process PID. Please search a bit.

[kylejustknows]

the Old _Singleton Func have a parameter which can make it "System Global". Means it detects the same process running under different users. (admin, user, guest, system etc)

Sometimes that switch is kind of important when ppl using autoit for service control and so.