Preprocessor for AutoIt created using AutoIt.

[guinness]

So I'm thinking about creating a preprocessor for AutoIt and was wondering on whether you had any ideas?

Thanks.

Quick idea:

#include <Array.au3>
#include <Constants.au3>

#define MSGOK = 4096
#define MATCHSTRING = "This is some simple string" & @CRLF
#define PI = 3.14159

Local $sScriptFileData = 'MsgBox(#MSGOK, "", "")' & @CRLF & @CRLF & 'StringInStr("Some string example",#MATCHSTRING, "#PI") ; #PI shouldn''t be expanded in strings.'
Local Const $aMacros = PreProcessorMacros(@ScriptFullPath)
;~ _ArrayDisplay($aMacros)
For $i = 1 To $aMacros[0][0]
    $sScriptFileData = StringRegExpReplace($sScriptFileData, '#\b' & $aMacros[$i][0] & '\b', $aMacros[$i][1])
Next
MsgBox($MB_SYSTEMMODAL, '', $sScriptFileData)

Func PreProcessorMacros($sFilePath)
    Local $aMacros = StringRegExp('#define macrocount = 0' & @CRLF & FileRead($sFilePath), '(?im:^#define\h+)(\w+)(?:\h+=\h+)([^\r\n]+)', 3)
    $aMacros[0] = UBound($aMacros) - 1
    Local $aReturn[($aMacros[0] / 2) + 1][2] = [[0]]
    For $i = 2 To $aMacros[0] Step 2
        $aReturn[0][0] += 1
        $aReturn[$aReturn[0][0]][0] = $aMacros[$i]
        $aReturn[$aReturn[0][0]][1] = $aMacros[$i + 1]
    Next
    Return SetError($aReturn[0][0] = 0, 0, $aReturn)
EndFunc   ;==>PreProcessorMacros

Edited February 26, 2013 by guinness

[guinness]

This only applies to the example above.

$sScriptFileData = StringRegExpReplace($sScriptFileData, '(?<=\(|,)#\b' & $aMacros[$i][0] & '\b', $aMacros[$i][1])

[lorenkinzel]

"#define"

I couldn't find this in the help file.

Do I need to look harder, or is there another place to look?

[guinness]

It doesn't exist in AutoIt, this is why I had the idea of creating a C-like preprocessor.

Source: https://en.wikipedia.org/wiki/C_preprocessor

[lorenkinzel]

√ That explains my not finding it.

[guinness]

OK.

After sleeping on it I realised that it's something I should do for personal use and not the community. Sorry.

[LarsJ]

guinness, Take a look at this one http://www.autoitscript.com/forum/index.php?showtopic=133808.

[guinness]

Thanks LarsJ, I looked at this 3 months ago but I will probably just use a different pre-processor.

[guinness]

OK, my initial idea is back on, though the concept has changed a little.

[guinness]

I will be posting the application tomorrow (after testing) but this gives you an idea of what it can do at the moment.

Before:

#include <Constants.au3>

Example()

Func Example()
    Local Const $MB_SYSTEMMODAL = 4096
    Local Const $sVar = 'SomeVar', $iConsty = 1000, $sConstyVar = 'SomeConst', $iControlID = ConsoleWrite('This won''t be expanded.')
    Local Enum $eVar_1 = 1, $eVar_2, $eVar_3, $eVar_4
    #forceref $eVar_1, $eVar_2, $eVar_3

    MsgBox($MB_SYSTEMMODAL, $sVar, 'Enum Var_4: ' & $eVar_4 & @TAB & @TAB)

    MsgBox($MB_SYSTEMMODAL, 'Enum Var_2: ' & $eVar_2, $sConstyVar & @TAB & @TAB)
EndFunc   ;==>Example

 

After:

#include <Constants.au3>

Example()

Func Example()
    Local Const $iControlID = ConsoleWrite('This won''t be expanded.')
    MsgBox(4096, 'SomeVar', 'Enum Var_4: ' & 4 & @TAB & @TAB)
    MsgBox(4096, 'Enum Var_2: ' & 2, 'SomeConst' & @TAB & @TAB)
EndFunc   ;==>Example

An example of why I use Enum:

#include <Constants.au3>

Example()

Func Example()
    Local Enum $eAPI_FilePath, $eAPI_FileDate, $eAPI_FileData, $eAPI_Max
    Local $aAPI[$eAPI_Max]

    $aAPI[$eAPI_FilePath] = @ScriptFullPath

    ; It's easier to understand that this item is hold the file path date
    ; string, instead of using $aAPI[1]. Also if I decided to change what index
    ; holds what, then I only have to change the order of the Enum declaration.
    $aAPI[$eAPI_FileDate] = FileGetTime($aAPI[$eAPI_FilePath], Default, 1)

    MsgBox($MB_SYSTEMMODAL, '', $aAPI[$eAPI_FilePath] & @CRLF & _
            $aAPI[$eAPI_FileDate])
EndFunc   ;==>Example