FileCountLines incorect count

[guinness]

Very clever regular exp<b></b>ressi&#111;n Melba23. When I saw it last night for some reason I glazed over it, but today decided to to revisit this thread.

#include <Constants.au3>

Local $aEOL[3] = [@CRLF, @CR, @LF], _
        $sReturn = ''
For $i = 1 To 20
    $sReturn &= 'Random__' & $i & $aEOL[Random(0, 2, 1)]
Next
Local $sBeforeText = $sReturn
ConvertEOLToText($sBeforeText)
MsgBox($MB_SYSTEMMODAL, 'Before', $sBeforeText & @CRLF)

; By Melba23, convert @CR & @LF to @CRLF. Using lookarounds, very clever!
$sReturn = StringRegExpReplace($sReturn, '((?<!\x0d)\x0a|\x0d(?!\x0a))', @CRLF)

Local $sAfterText = $sReturn
ConvertEOLToText($sAfterText)
MsgBox($MB_SYSTEMMODAL, 'After', $sAfterText & @CRLF)

; Convert the EOL characters to the macro string representation.
Func ConvertEOLToText(ByRef $sText)
    ; \x0a = @LF & \x0d = @CR & \x0d\x0a = @CRLF
    $sText = StringRegExpReplace($sText, '\x0d(?!\x0a)', '@CR' & @CR)
    $sText = StringRegExpReplace($sText, '(?<!\x0d)\x0a', '@LF' & @LF)
    $sText = StringRegExpReplace($sText, '\x0d\x0a', '@CRLF' & @CRLF)
EndFunc   ;==>ConvertEOLToText

SciTE has an option to convert EOLs to what ever the preferred choice is. Navigate to Options >> Convert Line End Characters. The preferred choice can be changed by selecting the menu item above. I have it set to @CRLF (like most probably.)

And for those who like rn and not the Hex values.

#include <Constants.au3>

Local $aEOL[3] = [@CRLF, @CR, @LF], _
        $sReturn = ''
For $i = 1 To 20
    $sReturn &= 'Random__' & $i & $aEOL[Random(0, 2, 1)]
Next
Local $sBeforeText = $sReturn
ConvertEOLToText($sBeforeText)
MsgBox($MB_SYSTEMMODAL, 'Before', $sBeforeText & @CRLF)

; By Melba23, convert @CR & @LF to @CRLF. Using lookarounds, very clever!
$sReturn = StringRegExpReplace($sReturn, '((?<!\r)\n|\r(?!\n))', @CRLF)

Local $sAfterText = $sReturn
ConvertEOLToText($sAfterText)
MsgBox($MB_SYSTEMMODAL, 'After', $sAfterText & @CRLF)

; Convert the EOL characters to the macro string representation.
Func ConvertEOLToText(ByRef $sText)
    ; \n = @LF & \r = @CR & \r\n = @CRLF
    $sText = StringRegExpReplace($sText, '\r(?!\n)', '@CR' & @CR)
    $sText = StringRegExpReplace($sText, '(?<!\r)\n', '@LF' & @LF)
    $sText = StringRegExpReplace($sText, '\r\n', '@CRLF' & @CRLF)
EndFunc   ;==>ConvertEOLToText

Edited April 8, 2013 by guinness

[HeavenlyDemon]

verry nice....i am going to test this out....thanks

[guinness]

My code was just to demonstrate that it works. No credit should be given to me.