I need to read the random passwords from https://www.random.org/passwords/?num=1&len=8&format=html&rnd=new

[Cyborg5000]

Cant get Autoit to read the random passwords from https://www.random.org/passwords/?num=1&len=8&format=html&rnd=new

Can some one help?

Tried using all IE functions/examples

Edited April 2, 2015 by Cyborg5000

[water]

What have you tried so far?

[Cyborg5000]

_IEFormGetObjByName

_IEPropertyGet

_IEBodyReadText

_IEFormElementGetValue

[Melba23]

Cyborg5000,

This works for me:

#include <Array.au3>
#include <IE.au3>

Local $oIE = _IECreate("https://www.random.org/passwords/?num=1&len=8&format=html&rnd=new")
; Read page content
$sText = _IEDocReadHTML($oIE)
; Extract the password
$aExtract = StringRegExp($sText, '(?U)"data">(?:\v*)<li>(.*)</li>', 3)
; And here it is
_ArrayDisplay($aExtract, "", Default, 8)

SRE decode:

(?U)     - Look for smallest match (Ungreedy)
"data">  - Look for this string
(?:\v*)  - followed by any number of vertical white space characters (to cover CR/LF/CRLF etc) in a non-capturing group
<li>     - followed by this tag
(.*)     - Capture everything
</li>    - until this tag

M23

[Exit]

#include <String.au3>
MsgBox(262144, "Your Password is",_StringBetween(BinaryToString(InetRead("https://www.random.org/passwords/?num=1&len=8&format=html&rnd=new", 1)), '<ul class="data">' & @LF & '<li>', '</li>')[0],0)

Edit: Melba23 was quicker and better

Edited April 2, 2015 by Exit

[Kyan]

ConsoleWrite(_RandomPassword()&@LF)
Exit

Func _RandomPassword($__PWlength = 8)
    Local $__pwd = ''
    For $x = 1 To $__PWlength
        While 1
            $_rnd = Random(65,122,1)
            If $_rnd < 91 Or $_rnd > 96 Then ExitLoop
        WEnd
        $__pwd &= Chr($_rnd)
    Next
    Return $__pwd
EndFunc 

Cyborg5000, wouldn't be easier if you gen them? If they are random, why bother getting them from that site?

 

[jguinch]

Also with InetRead :

Local $sText = BinaryToString(InetRead("https://www.random.org/passwords/?num=1&len=8&format=html&rnd=new"))
$aRet = StringRegExp($sText, '<li>([[:alnum:]]{8})</li>', 1)
If IsArray($aRet) Then MsgBox(0, "", $aRet[0])

But it should be simplier to generate the password directly with AutoIt, like Kyan suggests.

Edit :

ConsoleWrite(_Password() )

Func _Password($iLen = 8, $iFlagSpecialChars = 0)
    Local $sStandardChars = "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789", $sPassword
    Local $sSpecialChars = "$@^`,|%;.~()/\{}:?[]=-+_#!"
    
    Local $sChars = $sStandardChars
    If $iFlagSpecialChars Then $sChars &= $sSpecialChars
    
    For $i = 1 To $iLen
        $sPassword &= StringMid($sChars, Random(1, StringLen($sChars), 1), 1)
    Next
    Return $sPassword
EndFunc

Edited April 2, 2015 by jguinch

[Cyborg5000]

On 4/2/2015 at 3:50 PM, Exit said:

#include <String.au3>
MsgBox(262144, "Your Password is",_StringBetween(BinaryToString(InetRead("https://www.random.org/passwords/?num=1&len=8&format=html&rnd=new", 1)), '<ul class="data">' & @LF & '<li>', '</li>')[0],0)

Edit: Melba23 was quicker and better

Thanks this worked for me.....

Edited November 28, 2018 by Cyborg5000

[JohnOne]

What a wonderful free advertisement for random.org.

[Cyborg5000]

ConsoleWrite(_RandomPassword()&@LF)
Exit

Func _RandomPassword($__PWlength = 8)
    Local $__pwd = ''
    For $x = 1 To $__PWlength
        While 1
            $_rnd = Random(65,122,1)
            If $_rnd < 91 Or $_rnd > 96 Then ExitLoop
        WEnd
        $__pwd &= Chr($_rnd)
    Next
    Return $__pwd
EndFunc 

Cyborg5000, wouldn't be easier if you gen them? If they are random, why bother getting them from that site?

 

This too is a good option Kyan, thanks