Sign in to follow this  
Followers 0
Andreik

Hot key control

4 posts in this topic

#1 ·  Posted (edited)

This UDF contains functions that assist with hot key control management. A hot key control is a window that enables the user to enter a combination of keystrokes to be used as a hot key. A hot key is a key combination that the user can press to perform an action quickly.key combination that the user can press to perform an action quickly.

jz9u6r.png

I tried to keep the syntax close to AutoIt UDFs standards to be more easy to work.

GUIHotkey.au3

#include <Array.au3>
#include <WinAPI.au3>
#include <WinAPIMisc.au3>

; #INDEX# =======================================================================================================================
; Title .........: Hotkey
; AutoIt Version : 3.3.12.0
; Language ......: English
; Description ...: Functions that assist with Hotkey control management.
;                  A hot key control is a window that enables the user to enter a combination of keystrokes to be used as a
;                  hot key. A hot key is a key combination that the user can press to perform an action quickly.
; ===============================================================================================================================

; #CONSTANTS# ===================================================================================================================
Global Const $tagINITCOMMONCONTROLSEX  = 'STRUCT;DWORD dwSize;DWORD dwICC;ENDSTRUCT;'

Global Const $ICC_HOTKEY_CLASS  = 0x00000040
Global Const $sClassName        = 'msctls_hotkey32'

Global Const $HKM_SETHOTKEY     = 0x0400 + 1
Global Const $HKM_GETHOTKEY     = 0x0400 + 2
Global Const $HKM_SETRULES      = 0x0400 + 3

Global Const $HKCOMB_NONE       = 0x1   ; Unmodified keys
Global Const $HKCOMB_S          = 0x2   ; SHIFT
Global Const $HKCOMB_C          = 0x4   ; CTRL
Global Const $HKCOMB_A          = 0x8   ; ALT
Global Const $HKCOMB_SC         = 0x10  ; SHIFT + CTRL
Global Const $HKCOMB_SA         = 0x20  ; SHIFT + ALT
Global Const $HKCOMB_CA         = 0x40  ; CTRL + ALT
Global Const $HKCOMB_SCA        = 0x80  ; SHIFT + CTRL + ALT

Global Const $HOTKEYF_SHIFT     = 0x01
Global Const $HOTKEYF_CONTROL   = 0x02
Global Const $HOTKEYF_ALT       = 0x04
Global Const $HOTKEYF_EXT       = 0x80
; ===============================================================================================================================

; #CURRENT# =====================================================================================================================
; _GUICtrlHotkey_Create
; _GUICtrlHotkey_Get
; _GUICtrlHotkey_Set
; _GUICtrlHotkey_SetRules
; _GUICtrlHotkey_Destroy
; _GetHotkey_ModifiersList
; ===============================================================================================================================

; #INTERNAL_USE_ONLY# ===========================================================================================================
; __char
; __vkCode
; ===============================================================================================================================

; #FUNCTION# ====================================================================================================================
; Name...........: _GUICtrlHotkey_Create
; Description ...: Creates a hot key control
; Syntax.........: _GUICtrlHotkey_Create ( $hParent, $iX, $iY, $iW, $iH )
; Parameters ....: $hParent     - Handle to the parent window
;                  $iX          - The initial horizontal position of the control
;                  $iY          - The initial vertical position of the control
;                  $iW          - The width, in device units, of the control
;                  $iH          - The height, in device units, of the control
; Return values .: Success      - Handle to the new hot key control
;                  Failure      - Null
; Author ........: Andreica Ionut (Andreik)
; Modified.......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _GUICtrlHotkey_Create($hParent,$iX,$iY,$iW,$iH)
    If Not HWnd($hParent) Then $hParent = WinGetHandle($hParent)
    Local $tINITCOMMONCONTROLSEX = DllStructCreate($tagINITCOMMONCONTROLSEX)
    DllStructSetData($tINITCOMMONCONTROLSEX,'dwSize',DllStructGetSize($tINITCOMMONCONTROLSEX))
    DllStructSetData($tINITCOMMONCONTROLSEX,'dwICC',$ICC_HOTKEY_CLASS)
    Local $aResult = DllCall('comctl32','BOOL','InitCommonControlsEx','ptr',DllStructGetPtr($tINITCOMMONCONTROLSEX))
    If $aResult[0] Then
        Local $hCtrl = _WinAPI_CreateWindowEx(0,$sClassName,'',BitOR(0x40000000,0x10000000),$iX,$iY,$iW,$iH,$hParent)
        If IsHWnd($hCtrl) Then Return $hCtrl
    EndIf
    Return Null
EndFunc

; #FUNCTION# ====================================================================================================================
; Name...........: _GUICtrlHotkey_Get
; Description ...: Gets the virtual key code and modifier flags of a hot key from a hot key control
; Syntax.........: _GUICtrlHotkey_Get ( $hCtrl [, $bFormat] )
; Parameters ....: $hCtrl       - Handle to the hot key control
;                  $bFormat     - If False return virtual key code of the hot key (default)
;                               - If True return char of the hotkey
; Return values .: Success      - Virtual key code or char according to $bFormat parameter
; Author ........: Andreica Ionut (Andreik)
; Modified.......:
; Remarks .......: @extended contains the combination of hot key modifiers
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _GUICtrlHotkey_Get($hCtrl,$bFormat=False)
    Local $LoWord = _WinAPI_LoWord(_SendMessage($hCtrl,$HKM_GETHOTKEY))
    Return SetExtended(_WinAPI_HiByte($LoWord),($bFormat)?(__char(_WinAPI_LoByte($LoWord))):(_WinAPI_LoByte($LoWord)))
EndFunc

; #FUNCTION# ====================================================================================================================
; Name...........: _GUICtrlHotkey_Set
; Description ...: Sets the hot key combination for a hot key control
; Syntax.........: _GUICtrlHotkey_Set ( $hCtrl, $Modifiers, $Key [, $bFormat] )
; Parameters ....: $hCtrl       - Handle to the hot key control
;                  $Modifiers   - the key modifier that indicates the keys that define a hot key combination
;                  $Key         - the virtual key code or char of the hot key according to $bFormat parameter
;                  $bFormat     - If False the key is given as virtual key code (default)
;                               - If True the key is given as char
; Return values .: Success      - None
; Author ........: Andreica Ionut (Andreik)
; Modified.......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _GUICtrlHotkey_Set($hCtrl,$Modifiers,$Key,$bFormat=False)
    _SendMessage($hCtrl,$HKM_SETHOTKEY,_WinAPI_MakeLong(_WinAPI_MakeWord($Modifiers,(($bFormat)?(__vkCode($Key)):($Key))),0))
EndFunc

; #FUNCTION# ====================================================================================================================
; Name...........: _GUICtrlHotkey_SetRules
; Description ...: Defines the invalid combinations and the default modifier combination for a hot key control
; Syntax.........: _GUICtrlHotkey_SetRules ( $hCtrl, $HKCOMB, $HKCOMB_Def )
; Parameters ....: $hCtrl       - Handle to the hot key control
;                  $HKCOMB      - flags that specify invalid key combinations
;                  $HKCOMB_Def  - flags that specify the key combination to use when the user enters an invalid combination
; Return values .: Success      - None
; Author ........: Andreica Ionut (Andreik)
; Modified.......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _GUICtrlHotkey_SetRules($hCtrl,$HKCOMB,$HKCOMB_Def)
    _SendMessage($hCtrl,$HKM_SETRULES,$HKCOMB,_WinAPI_MakeLong($HKCOMB_Def,0))
EndFunc

; #FUNCTION# ====================================================================================================================
; Name...........: _GUICtrlHotkey_Destroy
; Description ...: Destroy a hot key control
; Syntax.........: _GUICtrlHotkey_Destroy ( $hCtrl )
; Parameters ....: $hCtrl       - Handle to the hot key control
; Return values .: Success      - True
;                  Failure      - False
; Author ........: Andreica Ionut (Andreik)
; Modified.......:
; Remarks .......:
; Related .......:
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _GUICtrlHotkey_Destroy($hCtrl)
    Return _WinAPI_DestroyWindow($hCtrl)
EndFunc

; #FUNCTION# ====================================================================================================================
; Name...........: _GetHotkey_ModifiersList
; Description ...: Return an array of modifiers from variable that contains a combination of modifiers
; Syntax.........: _GetHotkey_ModifiersList ( $Modifiers )
; Parameters ....: $Modifiers   - a combination of modifiers
; Return values .: Success      - An array (0 indexed) that contains a list of modifiers as text. First index indicates the
;                                 number of modifiers.
; Author ........: Andreica Ionut (Andreik)
; Modified.......:
; Remarks .......:
; Related .......: _GUICtrlHotkey_Get
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func _GetHotkey_ModifiersList($Modifiers)
    Local $aResult[1] = [0]
    If BitAND($Modifiers,$HOTKEYF_SHIFT)=$HOTKEYF_SHIFT Then _ArrayAdd($aResult,'SHIFT')
    If BitAND($Modifiers,$HOTKEYF_CONTROL)=$HOTKEYF_CONTROL Then _ArrayAdd($aResult,'CTRL')
    If BitAND($Modifiers,$HOTKEYF_ALT)=$HOTKEYF_ALT Then _ArrayAdd($aResult,'ALT')
    If BitAND($Modifiers,$HOTKEYF_EXT)=$HOTKEYF_EXT Then _ArrayAdd($aResult,'EXT')
    $aResult[0] = UBound($aResult)-1
    Return $aResult
EndFunc

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name...........: __char
; Description ...: Convert virtual key code to char
; Syntax.........: __char ( $vkCode )
; Parameters ....: $vkCode      - virtual key code
; Return values .: Success      - char or acronym of virtual key code
; Author ........: Andreica Ionut (Andreik)
; Modified.......:
; Remarks .......:
; Related .......: __vkCode
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func __char($vkCode)
    Switch $vkCode
        Case 0
            Return '[NUL]'
        Case 1
            Return '[SOH]'
        Case 2
            Return '[STX]'
        Case 3
            Return '[ETX]'
        Case 4
            Return '[EOT]'
        Case 5
            Return '[ENQ]'
        Case 6
            Return '[ACK]'
        Case 7
            Return '[BEL]'
        Case 8
            Return '[BS]'
        Case 9
            Return '[HT]'
        Case 10
            Return '[LF]'
        Case 11
            Return '[VT]'
        Case 12
            Return '[FF]'
        Case 13
            Return '[CR]'
        Case 14
            Return '[SO]'
        Case 15
            Return '[SI]'
        Case 16
            Return '[DLE]'
        Case 17
            Return '[DC1]'
        Case 18
            Return '[DC2]'
        Case 19
            Return '[DC3]'
        Case 20
            Return '[DC4]'
        Case 21
            Return '[NAK]'
        Case 22
            Return '[SYN]'
        Case 23
            Return '[ETB]'
        Case 24
            Return '[CAN]'
        Case 25
            Return '[EM]'
        Case 26
            Return '[SUB]'
        Case 27
            Return '[ESC]'
        Case 28
            Return '[FS]'
        Case 29
            Return '[GS]'
        Case 30
            Return '[RS]'
        Case 31
            Return '[US]'
        Case 32
            Return '[SPACE]'
        Case 127
            Return '[DEL]'
        Case Else
            Return Chr($vkCode)
    EndSwitch
EndFunc

; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name...........: __vkCode
; Description ...: Convert char to virtual key code
; Syntax.........: __vkCode ( $Char )
; Parameters ....: $Char        - char or acronym
; Return values .: Success      - virtual key code of char or acronym
; Author ........: Andreica Ionut (Andreik)
; Modified.......:
; Remarks .......:
; Related .......: __char
; Link ..........:
; Example .......:
; ===============================================================================================================================
Func __vkCode($Char)
    Switch $Char
        Case '[NUL]'
            Return 0
        Case '[SOH]'
            Return 1
        Case '[STX]'
            Return 2
        Case '[ETX]'
            Return 3
        Case '[EOT]'
            Return 4
        Case '[ENQ]'
            Return 5
        Case '[ACK]'
            Return 6
        Case '[BEL]'
            Return 7
        Case '[BS]'
            Return 8
        Case '[HT]'
            Return 9
        Case '[LF]'
            Return 10
        Case '[VT]'
            Return 11
        Case '[FF]'
            Return 12
        Case '[CR]'
            Return 13
        Case '[SO]'
            Return 14
        Case '[SI]'
            Return 15
        Case '[DLE]'
            Return 16
        Case '[DC1]'
            Return 17
        Case '[DC2]'
            Return 18
        Case '[DC3]'
            Return 19
        Case '[DC4]'
            Return 20
        Case '[NAK]'
            Return 21
        Case '[SYN]'
            Return 22
        Case '[ETB]'
            Return 23
        Case '[CAN]'
            Return 24
        Case '[EM]'
            Return 25
        Case '[SUB]'
            Return 26
        Case '[ESC]'
            Return 27
        Case '[FS]'
            Return 28
        Case '[GS]'
            Return 29
        Case '[RS]'
            Return 30
        Case '[US]'
            Return 31
        Case '[SPACE]'
            Return 32
        Case '[DEL]'
            Return 127
        Case Else
            Return Asc($Char)
    EndSwitch
EndFunc

 

Example.au3

#include <GUIHotkey.au3>
#include <GuiListBox.au3>

Global $hMain, $hCtrl, $InvalidList, $DefList

$hMain = GUICreate('Hotkey control example',400,390)
GUICtrlCreateLabel('Invalid hotkey combinations',10,10,380,20,0x201)
$AddInvalid = GUICtrlCreateButton('Add',10,40,90,45)
$DelInvalid = GUICtrlCreateButton('Delete',10,90,90,45)
$InvalidList = GUICtrlCreateList('',110,40,280,100,0x00200000)
GUICtrlCreateLabel('Default when invalid hotkey detected',10,150,380,20,0x201)
$AddDef = GUICtrlCreateButton('Add',10,180,90,45)
$DelDef = GUICtrlCreateButton('Delete',10,230,90,45)
$DefList = GUICtrlCreateList('',110,180,280,100,0x00200000)
$hCtrl = _GUICtrlHotkey_Create($hMain,10,290,380,20)
GUICtrlCreateLabel('Current hotkey',10,320,100,20,0x201)
$CurrentHotkey = GUICtrlCreateLabel('',110,320,280,20,0x1201)
$Read = GUICtrlCreateButton('Read current hotkey',110,350,280,30)
ControlFocus($hMain,'',$hCtrl)
GUISetState(@SW_SHOW,$hMain)

_GUICtrlHotkey_Set($hCtrl,$HOTKEYF_CONTROL,'A',True)    ; When application start set default hotkey CTRL+A

While True
    Switch GUIGetMsg()
        Case $Read
            Read($CurrentHotkey)
        Case $AddInvalid
            Add($InvalidList,'Unmodified keys|SHIFT|CTRL|ALT|SHIFT + CTRL|SHIFT + ALT|CTRL + ALT|SHIFT + CTRL + ALT')
        Case $DelInvalid
            Del($InvalidList)
        Case $AddDef
            Add($DefList,'SHIFT|CTRL|ALT|EXT')
        Case $DelDef
            Del($DefList)
        Case -3 ;$GUI_EVENT_CLOSE
            _GUICtrlHotkey_Destroy($hCtrl)
            Exit
    EndSwitch
    Sleep(10)
WEnd

Func Add($List,$Flags)
    Local $Flag
    Local $hGUI = GUICreate('Add invalid hotkey',250,100)
    Local $InvalidFlags = GUICtrlCreateCombo('',10,10,230,20,0x03)
    Local $hAdd = GUICtrlCreateButton('Add',50,50,150,30)
    GUICtrlSetData($InvalidFlags,$Flags)
    GUISetState(@SW_SHOW,$hGUI)
    While True
        Switch GUIGetMsg()
            Case $hAdd
                $Flag = GUICtrlRead($InvalidFlags)
                If $Flag Then
                    ControlCommand($hMain,'',$List,'AddString',$Flag)
                    ExitLoop
                EndIf
            Case -3
                ExitLoop
        EndSwitch
        Sleep(10)
    WEnd
    GUIDelete($hGUI)
    SetRules()
EndFunc

Func Del($List)
    _GUICtrlListBox_DeleteString($List,_GUICtrlListBox_GetCurSel($List))
    SetRules()
EndFunc

Func SetRules()
    Local $InvalidFlags, $DefaultFlags
    For $Index = 0 To _GUICtrlListBox_GetCount($InvalidList)-1
        $InvalidFlags = BitOR($InvalidFlags,FlagValue(_GUICtrlListBox_GetText($InvalidList,$Index),0))
    Next
    For $Index = 0 To _GUICtrlListBox_GetCount($DefList)-1
        $DefaultFlags = BitOR($DefaultFlags,FlagValue(_GUICtrlListBox_GetText($DefList,$Index),1))
    Next
    _GUICtrlHotkey_SetRules($hCtrl,$InvalidFlags,$DefaultFlags)
EndFunc

Func Read($CurrentHotkey)
    Local $Hotkey = ''
    Local $Key = _GUICtrlHotkey_Get($hCtrl,True)
    Local $Mod = @extended
    Local $ModList = _GetHotkey_ModifiersList($Mod)
    For $Index = 1 To $ModList[0]
        If $ModList[$Index] <> 'EXT' Then $Hotkey &= $ModList[$Index] & ' + '
    Next
    GUICtrlSetData($CurrentHotkey,$Hotkey & $Key)
EndFunc

Func FlagValue($Flag,$Param)
    Switch $Flag
        Case 'Unmodified keys'
            Return $HKCOMB_NONE
        Case 'SHIFT'
            Switch $Param
                Case 0
                    Return $HKCOMB_S
                Case 1
                    Return $HOTKEYF_SHIFT
            EndSwitch
        Case 'CTRL'
            Switch $Param
                Case 0
                    Return $HKCOMB_C
                Case 1
                    Return $HOTKEYF_CONTROL
            EndSwitch
        Case 'ALT'
            Switch $Param
                Case 0
                    Return $HKCOMB_A
                Case 1
                    Return $HOTKEYF_ALT
            EndSwitch
        Case 'SHIFT + CTRL'
            Return $HKCOMB_SC
        Case 'SHIFT + ALT'
            Return $HKCOMB_SA
        Case 'CTRL + ALT'
            Return $HKCOMB_CA
        Case 'SHIFT + CTRL + ALT'
            Return $HKCOMB_SCA
        Case 'EXT'
            Return $HOTKEYF_EXT
    EndSwitch
EndFunc

 

GUIHotkey.zip

Edited by Andreik

When the words fail... music speaks

Share this post


Link to post
Share on other sites



Great, but too many return points. For example consider something like this for the create function...

If $aResult[0] Then
    Local $hCtrl = _WinAPI_CreateWindowEx(0,$sClassName,'',BitOR(0x40000000,0x10000000),$iX,$iY,$iW,$iH,$hParent)
    If IsHWnd($hCtrl) Then Return $hCtrl
 ; Success
EndIf

Return Null ; Failure

 


_AdapterConnections()_AlwaysRun()_AppMon()_AppMonEx()_BinaryBin()_CheckMsgBox()_CmdLineRaw()_ContextMenu()_ConvertLHWebColor()/_ConvertSHWebColor()_DesktopDimensions()_DisplayPassword()_DotNet_Load()/_DotNet_Unload()_Fibonacci()_FileCompare()_FileCompareContents()_FileNameByHandle()_FilePrefix/SRE()_FindInFile()_GetBackgroundColor()/_SetBackgroundColor()_GetConrolID()_GetCtrlClass()_GetDirectoryFormat()_GetDriveMediaType()_GetFilename()/_GetFilenameExt()_GetHardwareID()_GetIP()_GetIP_Country()_GetOSLanguage()_GetSavedSource()_GetStringSize()_GetSystemPaths()_GetURLImage()_GIFImage()_GoogleWeather()_GUICtrlCreateGroup()_GUICtrlListBox_CreateArray()_GUICtrlListView_CreateArray()_GUICtrlListView_SaveCSV()_GUICtrlListView_SaveHTML()_GUICtrlListView_SaveTxt()_GUICtrlListView_SaveXML()_GUICtrlMenu_Recent()_GUICtrlMenu_SetItemImage()_GUICtrlTreeView_CreateArray()_GUIDisable()_GUIImageList_SetIconFromHandle()_GUIRegisterMsg()_GUISetIcon()_Icon_Clear()/_Icon_Set()_IdleTime()_InetGet()_InetGetGUI()_InetGetProgress()_IPDetails()_IsFileOlder()_IsGUID()_IsHex()_IsPalindrome()_IsRegKey()_IsStringRegExp()_IsSystemDrive()_IsUPX()_IsValidType()_IsWebColor()_Language()_Log()_MicrosoftInternetConnectivity()_MSDNDataType()_PathFull/GetRelative/Split()_PathSplitEx()_PrintFromArray()_ProgressSetMarquee()_ReDim()_RockPaperScissors()/_RockPaperScissorsLizardSpock()_ScrollingCredits_SelfDelete()_SelfRename()_SelfUpdate()_SendTo()_ShellAll()_ShellFile()_ShellFolder()_SingletonHWID()_SingletonPID()_Startup()_StringCompact()_StringIsValid()_StringRegExpMetaCharacters()_StringReplaceWholeWord()_StringStripChars()_Temperature()_TrialPeriod()_UKToUSDate()/_USToUKDate()_WinAPI_Create_CTL_CODE()_WinAPI_CreateGUID()_WMIDateStringToDate()/_DateToWMIDateString()Au3 script parsingAutoIt SearchAutoIt3 PortableAutoIt3WrapperToPragmaAutoItWinGetTitle()/AutoItWinSetTitle()CodingDirToHTML5FileInstallrFileReadLastChars()GeoIP databaseGUI - Only Close ButtonGUI ExamplesGUICtrlDeleteImage()GUICtrlGetBkColor()GUICtrlGetStyle()GUIEventsGUIGetBkColor()Int_Parse() & Int_TryParse()IsISBN()LockFile()Mapping CtrlIDsOOP in AutoItParseHeadersToSciTE()PasswordValidPasteBinPosts Per DayPreExpandProtect GlobalsQueue()Resource UpdateResourcesExSciTE JumpSettings INISHELLHOOKShunting-YardSignature CreatorStack()Stopwatch()StringAddLF()/StringStripLF()StringEOLToCRLF()VSCROLLWM_COPYDATAMore Examples...

Updated: 04/09/2015

Share this post


Link to post
Share on other sites

I don't think that will be more optimized as speed but indeed this might look better for reading. Thanks for tip. Edited first post.


When the words fail... music speaks

Share this post


Link to post
Share on other sites

I wasn't talking about speed, just readability. I also wonder if it would be better to have __char() as an array with the $vkcode acting as the index to return the string value? That might be quicker, especially if you cache the array,


_AdapterConnections()_AlwaysRun()_AppMon()_AppMonEx()_BinaryBin()_CheckMsgBox()_CmdLineRaw()_ContextMenu()_ConvertLHWebColor()/_ConvertSHWebColor()_DesktopDimensions()_DisplayPassword()_DotNet_Load()/_DotNet_Unload()_Fibonacci()_FileCompare()_FileCompareContents()_FileNameByHandle()_FilePrefix/SRE()_FindInFile()_GetBackgroundColor()/_SetBackgroundColor()_GetConrolID()_GetCtrlClass()_GetDirectoryFormat()_GetDriveMediaType()_GetFilename()/_GetFilenameExt()_GetHardwareID()_GetIP()_GetIP_Country()_GetOSLanguage()_GetSavedSource()_GetStringSize()_GetSystemPaths()_GetURLImage()_GIFImage()_GoogleWeather()_GUICtrlCreateGroup()_GUICtrlListBox_CreateArray()_GUICtrlListView_CreateArray()_GUICtrlListView_SaveCSV()_GUICtrlListView_SaveHTML()_GUICtrlListView_SaveTxt()_GUICtrlListView_SaveXML()_GUICtrlMenu_Recent()_GUICtrlMenu_SetItemImage()_GUICtrlTreeView_CreateArray()_GUIDisable()_GUIImageList_SetIconFromHandle()_GUIRegisterMsg()_GUISetIcon()_Icon_Clear()/_Icon_Set()_IdleTime()_InetGet()_InetGetGUI()_InetGetProgress()_IPDetails()_IsFileOlder()_IsGUID()_IsHex()_IsPalindrome()_IsRegKey()_IsStringRegExp()_IsSystemDrive()_IsUPX()_IsValidType()_IsWebColor()_Language()_Log()_MicrosoftInternetConnectivity()_MSDNDataType()_PathFull/GetRelative/Split()_PathSplitEx()_PrintFromArray()_ProgressSetMarquee()_ReDim()_RockPaperScissors()/_RockPaperScissorsLizardSpock()_ScrollingCredits_SelfDelete()_SelfRename()_SelfUpdate()_SendTo()_ShellAll()_ShellFile()_ShellFolder()_SingletonHWID()_SingletonPID()_Startup()_StringCompact()_StringIsValid()_StringRegExpMetaCharacters()_StringReplaceWholeWord()_StringStripChars()_Temperature()_TrialPeriod()_UKToUSDate()/_USToUKDate()_WinAPI_Create_CTL_CODE()_WinAPI_CreateGUID()_WMIDateStringToDate()/_DateToWMIDateString()Au3 script parsingAutoIt SearchAutoIt3 PortableAutoIt3WrapperToPragmaAutoItWinGetTitle()/AutoItWinSetTitle()CodingDirToHTML5FileInstallrFileReadLastChars()GeoIP databaseGUI - Only Close ButtonGUI ExamplesGUICtrlDeleteImage()GUICtrlGetBkColor()GUICtrlGetStyle()GUIEventsGUIGetBkColor()Int_Parse() & Int_TryParse()IsISBN()LockFile()Mapping CtrlIDsOOP in AutoItParseHeadersToSciTE()PasswordValidPasteBinPosts Per DayPreExpandProtect GlobalsQueue()Resource UpdateResourcesExSciTE JumpSettings INISHELLHOOKShunting-YardSignature CreatorStack()Stopwatch()StringAddLF()/StringStripLF()StringEOLToCRLF()VSCROLLWM_COPYDATAMore Examples...

Updated: 04/09/2015

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!


Register a new account

Sign in

Already have an account? Sign in here.


Sign In Now
Sign in to follow this  
Followers 0