BASE64 decoding images

[mrPuh]

Hi!

In XML-file (attach) xd:inline parameter contains BASE64 encoded images.

I decoding images and save to jpg-file with this function:

Func _Encoding_Base64Decode($sData)
    Local $struct = DllStructCreate("int")

    $a_Call = DllCall("Crypt32.dll", "int", "CryptStringToBinary", _
            "str", $sData, _
            "int", 0, _
            "int", 1, _
            "ptr", 0, _
            "ptr", DllStructGetPtr($struct, 1), _
            "ptr", 0, _
            "ptr", 0)

    If @error Or Not $a_Call[0] Then
        Return SetError(1, 0, "") ; error calculating the length of the buffer needed
    EndIf

    Local $a = DllStructCreate("byte[" & DllStructGetData($struct, 1) & "]")

    $a_Call = DllCall("Crypt32.dll", "int", "CryptStringToBinary", _
            "str", $sData, _
            "int", 0, _
            "int", 1, _
            "ptr", DllStructGetPtr($a), _
            "ptr", DllStructGetPtr($struct, 1), _
            "ptr", 0, _
            "ptr", 0)

    If @error Or Not $a_Call[0] Then
        Return SetError(2, 0, "") ; error decoding
    EndIf

    Return BinaryToString(DllStructGetData($a, 1))
EndFunc

But last image decoded only small part and image incorrect.

In output data I see that image is gif and not jpg.

Help me please decode this images.

I need decode many images.

Sorry for my English)

xml.rar

[careca]

Come on, do we have to do everything to test this?

Add code to open and read the file and whatnot.

You get help faster if the script you post is reproducible out-of-the-box.

[Danyfirex]

Hello Try this:

expandcollapse popup

#include <String.au3>
#include <Array.au3>
Local $sData = FileRead("xml.xml")
Local $aData = _StringBetween($sData, 'xd:inline="', '"')
_ArrayDisplay($aData)

Local $sImageName = ""
Local $hFile = 0
For $i = 0 To UBound($aData) - 1
    $sImageName = "Image-" & $i + 1 & "." & _Base64ImageType($aData[$i])
    $hFile=FileOpen($sImageName, 18)
    FileWrite($hFile, _Encoding_Base64Decode($aData[$i]))
    FileClose($hFile)
Next


Func _Base64ImageType($sBase64Image)
    Local $sType = ""
    Local $sChar = StringMid($sBase64Image, 1, 1)
    Switch $sChar
        Case "/"
            $sType = "jpg"
        Case "R"
            $sType = "gif"
        Case "i"
            $sType = "png"
        Case Else
    EndSwitch
    Return $sType
EndFunc   ;==>_Base64ImageType

Func _Encoding_Base64Decode($sData)
    Local $struct = DllStructCreate("int")

    $a_Call = DllCall("Crypt32.dll", "int", "CryptStringToBinary", _
            "str", $sData, _
            "int", 0, _
            "int", 1, _
            "ptr", 0, _
            "ptr", DllStructGetPtr($struct, 1), _
            "ptr", 0, _
            "ptr", 0)

    If @error Or Not $a_Call[0] Then
        Return SetError(1, 0, "") ; error calculating the length of the buffer needed
    EndIf

    Local $a = DllStructCreate("byte[" & DllStructGetData($struct, 1) & "]")

    $a_Call = DllCall("Crypt32.dll", "int", "CryptStringToBinary", _
            "str", $sData, _
            "int", 0, _
            "int", 1, _
            "ptr", DllStructGetPtr($a), _
            "ptr", DllStructGetPtr($struct, 1), _
            "ptr", 0, _
            "ptr", 0)

    If @error Or Not $a_Call[0] Then
        Return SetError(2, 0, "") ; error decoding
    EndIf

    Return BinaryToString(DllStructGetData($a, 1))
EndFunc   ;==>_Encoding_Base64Decode

Saludos

[mrPuh]

  On 7/22/2018 at 6:05 PM, Danyfirex said:

Hello Try this:

Expand  

Hello Danyfirex!

Thank you for you answer!

But last image incorrect (

Screenshot in attachment.

[mrPuh]

I found that if there is a (;) character in the string then images is corrupted after decoding.

But how I can solve this...

[Deye]

 insert this to skip that one line ..

For $i = 0 To UBound($aData) - 1
    If StringInStr($aData[$i] ,';') Then ContinueLoop

 

[careca]

Not only that, but there's a pattern of 
 so maybe it's more than just the ;

Edited July 23, 2018 by careca

[jchd]

It's the escape sequence for linefeed (0x0A). Replace "
" before base64-decode.

Edited July 23, 2018 by jchd

[mrPuh]

  On 7/23/2018 at 11:42 AM, jchd said:

It's the escape sequence for linefeed (0x0A). Replace "
" before base64-decode.

Expand  

jchd thank you very much!

I replace this symbol and problem is solved.