Listening To Multiple Child Process

[Funtime60]

I have a Parent Script that starts multiple, concurrent child processes. I cannot figure out how to apply the technique for using StdoutRead in the examples in a way that listens to them all simultaneously.

For reference, there can be any even number of, or single, child processes and there is an 1D array, $PIDS, that stores the PIDS of all the child processes and they should be outputting to another 1D array $sOutput.

Thank you for your time. Please just point me in the right direction. I'm sorry if I missed another topic that covers this.

Edited February 13, 2019 by Funtime60
Edit 2: Forgot to add a reason for Edit 1: Grammar

[caramen]

Hi,

How to Ask Help

Edited February 13, 2019 by caramen

[Funtime60]

Could you please be more complete in what you think I missed? I cannot think of anything other than what I tried, which I will add when my laptop can reach the site. I'd like to help anyone who wants to try and assist me with my problem. Thank you.

Edited February 13, 2019 by Funtime60
Edit 1: wanted to mention that this is from my phone

[Nine]

Both StdoutRead and StdinWrite require the PID of the child as the first parameter.  So you just have to poll (read) each of the PIDs to see if the childs have sent you something.  Since StdoutRead is a non-blocking function, there is no issue opting for this strategy.  If you need more detailed help, I would suggest you post a small snippet of both your parent and child in order for us to better understand your problem.

[Funtime60]

I realize that I should have posted code now, which I will do now that it seems my school has unblocked autoitscript.com on the WiFi. Child must be compiled in same directory currently. It must also be named Child1TMP.exe currently. My problem seems to be that my parent keeps trying to pull data even after the children have stopped outputting.

expandcollapse popup

;Snippet of the Parent
Local $x = 100
Local $y = 100
Local $x2 = 100 + $x
Local $y2 = 100 + $y
Local $ChildCount = 4
Local $PIDS[$ChildCount]
Local $PIDSMask = $PIDS
Local $PCount = 0
For $ix = 0 To (2)-1
    For $iy = 0 To (2)-1
        $PIDS[$PCount] = Example($x*$PCount, $y, $x2, $y2)
        $PCount += 1
    Next
Next
For $MCount = 0 To UBound($PIDSMask)-1
    $PIDSMask[$MCount] = 0
Next

Local $sOutput[$ChildCount]
While 1
    For $RCheck = 0 To UBound($PIDS)-1
        If $PIDSMask[$RCheck] =0 Then
            $sOutput[$RCheck] &= StdoutRead($PIDS[$RCheck])
            ConsoleWrite($RCheck&@TAB&StdoutRead($PIDS[$RCheck])&@CRLF) ;Debug
        EndIf
        If @error Then
            $PIDSMask[$RCheck] += 1
            ExitLoop
        EndIf
    Next
WEnd

Func Example($fsx,$fsy,$fdx,$fdy)
    Local $iPID = Run(@ScriptDir&"\Child1TMP.exe", @ScriptDir, @SW_HIDE, 3)

    StdinWrite($iPID, $fsx & @CRLF & $fsy & @CRLF & $fdx & @CRLF & $fdy & @CRLF)

    StdinWrite($iPID)

    Return($iPID)
EndFunc

;Snippet of the Child
Local $sOutput = ""
While True
    $sOutput &= ConsoleRead()
    If @error Then ExitLoop
    Sleep(25)
WEnd

TestWrite($sOutput)

Func TestWrite($input)
    Local $Stuff = StringSplit($input, @CRLF, 1)
    For $x = $Stuff[1] To $Stuff[3]+$Stuff[1]
        For $y = $Stuff[2] To $Stuff[4]+$Stuff[2]
            ConsoleWrite($x&","&$y&@CRLF) ;Output
        Next
    Next
EndFunc

Thank you

[BrewManNH]

Your @error should be after the StdOutRead, and not after the EndIf, it will never get an error message that way, the ConsoleWrite resets the error value before you try to read it.

[Nine]

Like Brew said the @error is misplaced but I also think your dual loop is not working properly.  It should a 3 levels loops.  If you read help file carefully it says : 

StdoutRead() does not block, it will return immediately. In order to get all data, it must be called in a loop.

So in your snippet, you will exitloop before going thru all your childs.  I don't believe this is want you want.  I think you want to exitloop when you reach EOF.

[Funtime60]

I've done something a bit dumb. I've asked you all for help, but now I've gone and changed how my code is intended to function. The only part I think that still applies is this:

4 hours ago, Nine said:

StdoutRead() does not block, it will return immediately. In order to get all data, it must be called in a loop.

I say this because even after looking at the help file, I still have no idea what it means by it "does not block". Am I correct in assuming that this means that the StdoutRead()  won't be able to pull anything after the process closes?

I'll post an updated snippet when I finish the changes.

Edited February 13, 2019 by Funtime60

[Nine]

33 minutes ago, Funtime60 said:

Am I correct in assuming that this means that the StdoutRead()  won't be able to pull anything after the process closes?

No, it means that using the function, it  will not stop the script at that function.  It will continue returning a value that says something it has nothing to read.  Unlike for example a msgbox () which ofc is totally different, it will block the script till the user respond to the message...

Edit : for everyone who will read this.  When you look at the help file and you do not understand a sentence, you should know that you are missing something important.  All single words in this help file are truly essential. Read carefully multiple times the help subject, try the examples, modify the examples at the places you are unsure of the meaning.  This is the best recommandation I can give...

Edited February 13, 2019 by Nine

[Gianni]

Hi @Funtime60, at first glance on your listing I see 2 inaccuracies quite macroscopic .

1. One is that you try to read twice the same data from the StdOut straem buffer. Once you read  the I/O stream from your process, that stream buffer is emptyed, so next read will get data only if new data is present, otherwyse you get an empty string (and not an @error). Of course the first stdoutread, stores the read data in the  $sOutput[$RCheck] variable, so you have to use that variable to 'see' and manage data read.
2. two, as already pointed out by BrewManNH and Nine, the  @error macro is misplaced. In short the use of the @error macro to check if a process has finished, it should be placed right after the StdOutread statement, so if the @error is set to true it means that the Pid you are trying to read doesn't exists anymore, tht is, it has finished and closed himself. (you can still read data from the stdoutread buffer even if in some cases I got issues in that way). Another maybe more kind way to check if a process has finished is to use the ProcessExist() function.

Here your script a little modified (quick and dirty) should do what you expect (at least I hope...)
P.S. maybe you can also be interested to this link where there is a ready made way to run and manage many external process.

expandcollapse popup

;Snippet of the Parent
Local $x = 100
Local $y = 100
Local $x2 = 100 + $x
Local $y2 = 100 + $y
Local $ChildCount = 4
Local $PIDS[$ChildCount]
Local $PIDSMask = $PIDS
Local $PCount = 0
For $ix = 0 To(2) - 1
    For $iy = 0 To(2) - 1
        $PIDS[$PCount] = Example($x * $PCount, $y, $x2, $y2)
        $PCount += 1
    Next
Next
For $MCount = 0 To UBound($PIDSMask) - 1
    $PIDSMask[$MCount] = 0
Next

Local $sOutput[$ChildCount], $TasksDone = 0
; While 1
Do
    $TasksDone = 0
    For $RCheck = 0 To UBound($PIDS) - 1

        ; If $PIDSMask[$RCheck] =0 Then
        $CheckData = StdoutRead($PIDS[$RCheck]) ; check presence of new data on the $PID's stream
        If $CheckData <> "" Then ; if we got something then keep it
            $sOutput[$RCheck] &= $CheckData ; stack task's stdout
            ; ConsoleWrite($RCheck&@TAB&StdoutRead($PIDS[$RCheck])&@CRLF) ; StdOut already read!!, you con't read twice same data
            ConsoleWrite($RCheck & @TAB & $sOutput[$RCheck] & @CRLF) ;Debug ; print already got data to console
        EndIf
        ; EndIf
        ; If @error Then
        If Not ProcessExists($PIDS[$RCheck]) Then
            $TasksDone += 1
            ; $PIDSMask[$RCheck] += 1
            ; ExitLoop
        EndIf
    Next
Until $TasksDone = UBound($PIDS)
; WEnd

Func Example($fsx, $fsy, $fdx, $fdy)
    Local $iPID = Run(@ScriptDir & "\Child1TMP.exe", @ScriptDir, @SW_HIDE, 3)

    StdinWrite($iPID, $fsx & @CRLF & $fsy & @CRLF & $fdx & @CRLF & $fdy & @CRLF)

    StdinWrite($iPID)

    Return($iPID)
EndFunc   ;==>Example

#cs
    ;Snippet of the Child
    Local $sOutput = ""
    While True
    $sOutput &= ConsoleRead()
    If @error Then ExitLoop
    Sleep(25)
    WEnd
    
    TestWrite($sOutput)
    
    Func TestWrite($input)
    Local $Stuff = StringSplit($input, @CRLF, 1)
    For $x = $Stuff[1] To $Stuff[3] + $Stuff[1]
    For $y = $Stuff[2] To $Stuff[4] + $Stuff[2]
    ConsoleWrite($x & "," & $y & @CRLF) ;Output
    Next
    Next
    EndFunc   ;==>TestWrite
#ce

 

[Funtime60]

Chimp definitely solved it for me. I'm sorry if I missed someone else's solution. Thanks everyone for helping me understand the issue.