Function Equivalent of Execute()

[noellarkin]

Local $a = 1
Local $v = Execute("$a+1") ; $v is set to 2

I've been wondering if there's something similar to Execute that would work with function names, something like:

Func _IncrementNumber($thisnumber)
    Return $thisnumber + 1
EndFunc

Local $Number = 10
Local $IncrementedNumber = ExecuteFunction("_IncrementNumber", $Number) ; $IncrementedNumber becomes 11

I haven't found anything similar to "ExecuteFunction" in the docs.

[water]

Execute takes any valid statement and executes it.

Func _IncrementNumber($thisnumber)
    Return $thisnumber + 1
EndFunc

Local $iNumber = 10
Local $iIncrementedNumber = Execute("_IncrementNumber(" & $iNumber & ")")
ConsoleWrite($iIncrementedNumber & @CRLF)

 

Edited January 16, 2023 by water

[water]

Even this works:

Func _IncrementNumber($thisnumber)
    Return $thisnumber + 1
EndFunc

Local $iNumber = 10
AutoItSetOption("ExpandVarStrings", 1)
Local $iIncrementedNumber = Execute("_IncrementNumber($iNumber)")
ConsoleWrite($iIncrementedNumber & @CRLF)

 

[noellarkin]

And here I was writing long Switch/Case combinations :P something like this:

Switch $Function
    Case "Function1"
        $ReturnValue = Function1()
    Case "Function2"
        $ReturnValue = Function2()
    Case "Function3"
        $ReturnValue = Function3()
EndSwitch

lol

 

3 minutes ago, water said:

Local $iIncrementedNumber = Execute("_IncrementNumber($iNumber)")

Wow, I love this Thank you, this is perfect!

[water]

This is made possible by

AutoItSetOption("ExpandVarStrings", 1)

[genius257]

Hi @noellarkin.
If it's just calling a function by name as string with parameters, you can also use the Call function.

[noellarkin]

Thanks @water and @genius257, both the Execute() and Call() functions work for my use case

[jchd]

Also note that functions are first-class citizens in AutoIt.

ConsoleWrite(VarGetType(ConsoleWrite) & @LF)
ConsoleWrite(VarGetType(_MyFunc) & @LF)
Local $v = _MyFunc
ConsoleWrite($v() & @LF)

Func _MyFunc()
    Return("Done")
EndFunc

This way keeps you away from calling a badly formed function name, like Call("MyFunc")

[genius257]

18 hours ago, water said:

Even this works:

Func _IncrementNumber($thisnumber)
    Return $thisnumber + 1
EndFunc

Local $iNumber = 10
AutoItSetOption("ExpandVarStrings", 1)
Local $iIncrementedNumber = Execute("_IncrementNumber($iNumber)")
ConsoleWrite($iIncrementedNumber & @CRLF)

 

 

18 hours ago, water said:

This is made possible by

AutoItSetOption("ExpandVarStrings", 1)

Hi @water.

The use of ExpandVarStrings seems to be redundant

Your example works event if "ExpandVarStrings" is omitted.

example code to show why:

AutoItSetOption("ExpandVarStrings", 1)
global $iNumber = 123;
ConsoleWrite("_IncrementNumber($iNumber)"&@CRLF)
ConsoleWrite("_IncrementNumber($iNumber$)"&@CRLF)

To be clear, your example works perfectly fine, just wanted to clarify that ExpandVarStrings had nothing to do with it

[water]

My example

ConsoleWrite("_IncrementNumber($iNumber)"&@CRLF)

is wrong as it misses the trailing $.
ExpandVarStrings does exactly what it is supposed to do (tested using AutoIt 3.3.16.0):

AutoItSetOption("ExpandVarStrings", 0)
ConsoleWrite("_IncrementNumber($iNumber$)" & @CRLF)

returns "_IncrementNumber($iNumber$)" and

AutoItSetOption("ExpandVarStrings", 1)
ConsoleWrite("_IncrementNumber($iNumber$)" & @CRLF)

returns "_IncrementNumber(123)".

[noellarkin]

Func _IncrementNumber($thisnumber)
    Return $thisnumber + 1
EndFunc

Local $iNumber = 10
Local $iIncrementedNumber = Execute("_IncrementNumber(" & $iNumber & ")")
ConsoleWrite($iIncrementedNumber & @CRLF)

$iIncrementedNumber = Execute("_IncrementNumber($iNumber)")
ConsoleWrite($iIncrementedNumber & @CRLF)

Both of these returned 11 for me without setting "ExpandVarStrings".

[OJBakker]

@noellarkin

Yes both  return 11 but that is not a failure of "ExpandVarStrings" but a feature of the Execute function.

You are not using the $var$-syntax for "ExpandVarString" in your example.

If you use the "ExpandVarString"-syntax you will see the difference.

See the expanded example program below.

expandcollapse popup

Local $iNumber = 10
Local $iIncrementedNumber = Execute("_IncrementNumber(" & $iNumber & ")")
MyCheckForError()
If Not @error Then ConsoleWrite("A " & $iIncrementedNumber & @CRLF)

AutoItSetOption("ExpandVarStrings", 0)

$iIncrementedNumber = Execute("_IncrementNumber($iNumber$)")
MyCheckForError()
If Not @error Then ConsoleWrite("B " & $iIncrementedNumber & @CRLF)

AutoItSetOption("ExpandVarStrings", 1)

$iIncrementedNumber = Execute("_IncrementNumber($iNumber$)")
MyCheckForError()
If Not @error Then ConsoleWrite("C " & $iIncrementedNumber & @CRLF)

Func _IncrementNumber($thisnumber)
    Return $thisnumber + 1
EndFunc

Func MyCheckForError($iError = @error, $iExtended = @extended)
    If $ierror Then
        If opt("ExpandVarStrings") = 0 Then
            SetError($ierror, $iextended)
            ConsoleWrite("Execute failed!" & @CRLF)
            ConsoleWrite("error: " & @error & " extended: " & @extended & @CRLF)
            ConsoleWrite("ierror: " & $ierror & " iextended: " & $iextended & @CRLF)
        EndIf
        If opt("ExpandVarStrings") = 1 Then
            SetError($ierror, $iextended)
            ConsoleWrite("Execute failed!@CRLF@")
            ConsoleWrite("error: @error@ extended: @extended@" & @CRLF)
            ConsoleWrite("ierror: $ierror$ extended: @extended@" & @CRLF)
        EndIf
    EndIf
    Return SetError($ierror, $iextended)
EndFunc