How to change keyboard layout?

[GodlessSinner]

How to change keyboard layout without sending hotkeys?

(Once I had done it, but forgot how...)

[Yashied]

Func _WinAPI_GetKeyboardLayout($hWnd)

    Local $Ret = DllCall('user32.dll', 'long', 'GetWindowThreadProcessId', 'hwnd', $hWnd, 'ptr', 0)

    If (@error) Or ($Ret[0] = 0) Then
        Return SetError(1, 0, 0)
    EndIf
    $Ret = DllCall('user32.dll', 'long', 'GetKeyboardLayout', 'long', $Ret[0])
    If (@error) Or ($Ret[0] = 0) Then
        Return SetError(1, 0, 0)
    EndIf
    Return '0000' & Hex($Ret[0], 4)
EndFunc   ;==>_WinAPI_GetKeyboardLayout

Func _WinAPI_SetKeyboardLayout($sLayout, $hWnd)

    If Not WinExists($hWnd) Then
        Return SetError(1, 0, 0)
    EndIf

    Local $Ret = DllCall('user32.dll', 'long', 'LoadKeyboardLayout', 'str', StringFormat('%08s', StringStripWS($sLayout, 8)), 'int', 0)

    If (@error) Or ($Ret[0] = 0) Then[url="http://msdn.microsoft.com/en-us/library/dd318693(VS.85).aspx"]http://msdn.microsoft.com/en-us/library/dd318693(VS.85).aspx[/url]
        Return SetError(1, 0, 0)
    EndIf
    DllCall('user32.dll', 'ptr', 'SendMessage', 'hwnd', $hWnd, 'int', 0x0050, 'int', 1, 'int', $Ret[0])
    Return SetError(0, 0, 1)
EndFunc   ;==>_WinAPI_SetKeyboardLayout

$sLayout = ...

'00000407' - Germany

'00000409' - United States

'0000040C' - France

'00000410' - Italian

'00000419' - Russian

See http://msdn.microsoft.com/en-us/library/dd318693(VS.85).aspx for more information.

Edited July 17, 2009 by Yashied

[MrCreatoR]

Search for _SetKeyboardLayout on the forum, this question has been asked before.