Mouseclick

[Merrik]

Hi,

I was wondering if anyone knows how to click on a text box and then text in the box disappears on the click.

I was thinking of using something like this, but could use some help.

MouseClick ( "textbox")
Send("{CLEAR}")

Edited June 24, 2011 by Merrik

[monoscout999]

I m a little confused :S You ask for something and you write another.

What i understand from what you are requesting is a function to clear a textbox when you click on it

but you write

Send("{CTRLDOWN}")
MouseClick("left",Random(0,1024,1),Random(0,700,1),1,1)
Send("{CTRLUP}")

why do you want the mouse click anywhere on the screen while you holding the CTRL key???

sorry, i don`t understand the request

Edited June 23, 2011 by monoscout999

[Merrik]

Sorry for poor explaination. I have a textbox that I enter info into and when the button is click I want the info in the textbox to remain after clicking the button, but I was hoping that the text would clear when you click your mouse on the text box.

[JohnOne]

You should always do a quick search on these things, its forum 101.

#include <GUIConstants.au3>

$Clear = 0

$Form1 = GUICreate("Form1", 242, 99)
$Input1 = GUICtrlCreateInput("Enter ID", 40, 24, 121, 21)
$btn1 = GUICtrlCreateButton ("Catches initial focus", 40, 70)

GUICtrlSetState ($btn1, $GUI_Focus)

GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch

    If _IsFocused ($Form1, $Input1) And $Clear = 0 Then
        GUICtrlSetData ($Input1, "")
        $Clear = 1
    ElseIf $Clear = 1  And Not _IsFocused ($Form1, $Input1) Then
        $Clear = 0
    EndIf

WEnd


Func _IsFocused($hWnd, $nCID)
    Return ControlGetHandle($hWnd, '', $nCID) = ControlGetHandle($hWnd, '', ControlGetFocus($hWnd))
EndFunc   ;==>_IsFocused

[guinness]

Or another Example using WM_COMMAND >>

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $Global_ControlID, $Global_PreviousText

_Main()

Func _Main()
    Local $hGUI, $iButton
    $hGUI = GUICreate("", 640, 480)
    GUICtrlCreateInput("Client Name", 432, 176, 153, 21)
    GUICtrlCreateInput("Username", 432, 256, 153, 21)
    GUICtrlCreateInput("Pass", 432, 296, 153, 21)
    $iButton = GUICtrlCreateButton("Exit", 432, 420, 30, 30)
    GUISetState()
    ControlFocus($hGUI, "", $iButton)

    GUIRegisterMsg($WM_COMMAND, 'WM_CHECK')

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $iButton
                Exit

        EndSwitch
    WEnd
EndFunc   ;==>_Main

Func WM_CHECK($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $ilParam
    Local $iCode
    $iCode = _WinAPI_HiWord($iwParam)
    Switch $iCode
        Case $EN_SETFOCUS
            $Global_ControlID = _WinAPI_LoWord($iwParam)
            $Global_PreviousText = GUICtrlRead($Global_ControlID)
            GUICtrlSetData($Global_ControlID, "")

        Case $EN_KILLFOCUS
            If GUICtrlRead($Global_ControlID) = "" Then
                GUICtrlSetData($Global_ControlID, $Global_PreviousText)
            EndIf
    EndSwitch
    Return "GUI_RUNDEFMSG"
EndFunc   ;==>WM_CHECK