[Solved] Run function on Mouse Hover

IanN1990 · January 2, 2012

I am trying to make a function but struggling to put it all together.

I need a function that detects when my mouse is over a "application or window" and sets it ontop and once the mouse leaves that application it sets it back to zero. Any ideas?

Edited April 14, 2012 by IanN1990

guinness · January 2, 2012

A couple of ways you could do this...

1. Using MouseGetPos & WinGetPos to monitor when the mouse is in the same position as where the window is situated.

2. Use WinGetHandle to find the hWnd of the window and _WinAPI_WindowFromPoint() (see Help file for a working example.)

If you want a working example let me know, but I honestly believe this is an easy task for you.

Edited January 2, 2012 by guinness

IanN1990 · January 2, 2012

#include <WinAPI.au3>
Global $Struct = DllStructCreate($tagPoint)
Opt('MustDeclareVars', 1)
While  True
sleep(100)
Local $hWnd, $hLast, $trans, $old, $new, $title
DllStructSetData($Struct, "x", MouseGetPos(0))
    DllStructSetData($Struct, "y", MouseGetPos(1))
    $hWnd = _WinAPI_WindowFromPoint($Struct)
    do
        $hLast = $hWnd
        $hWnd = _WinAPI_GetParent($hLast)
    Until $hWnd = 0

    $hWnd = $hLast
if $hwnd = $old Then
Else
WinSetOnTop($old, "", 0)
$old = $hWnd
WinSetOnTop($old, "", 1)
EndIf
WEnd

Missed out a few things but still seams to work fine

Edited January 3, 2012 by IanN1990

goldenix · January 3, 2012

Answer
thanks for suggesting the API guinness

Can you post a working example please? the one u posted doesnt work.

Melba23 · January 3, 2012

goldenix,

The example works for me. Are you running x64 and have not yet updated to v3.3.8.0?

If you are it is probably a struct problem and you need to do something like this:

If @AutoItX64 Then
    Local $tPoint = DllStructCreate("int X;int Y")
    DllStructSetData ( $tPoint, "X", MouseGetPos(0))
    DllStructSetData ( $tPoint, "Y", MouseGetPos(1))
    Local $tPoint64 = DllStructCreate("int64", DllStructGetPtr($tPoint))
    Local $aHwnd = DllCall("user32.dll", "hwnd", "WindowFromPoint", "int64", DllStructGetData($tPoint64, 1))
Else
    Local $aHwnd = DllCall("user32.dll", "hwnd", "WindowFromPoint", "uint", MouseGetPos(0), "uint", MouseGetPos(1))
EndIf

Or better still update and let AutoIt do all the work.

M23

guinness · January 3, 2012

I couldn't get IanN1990's example to work either because the structure for WindowFromPoint isn't created and neither is the window he is meant to be monitoring. But no worries, last night I was updating the Help file and using Notepad quite a bit so here is a short demonstration of the idea I proposed in post #2.

Without the Windows API:

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#include <WinAPI.au3>

Run("notepad.exe") ; We're using Notepad for the purposes of this example.

_Main()

Func _Main()
    Local $aArray, $hWnd = WinWait("[CLASS:Notepad]", "", 10), $iIsHover = 0, $iIsHovered = 0 ; I'm using the handle returned by WinWait to give time for Notepad to load.

    While 1
        Sleep(100)

        $aArray = WinGetPos($hWnd) ; Get the position of the window we're monitoring using the handle returned by WinGetHandle.
        If @error Then
            ExitLoop
        EndIf

        If WinActive($hWnd) = 0 Then ; Check if the window is currently active, if not then continue the loop and don't check the mouse position.
            ContinueLoop
        EndIf

        $iIsHover = _MouseInBounds($aArray[0], $aArray[1], $aArray[2], $aArray[3]) ; Check if the mouse in in between the Notepad window.
        If $iIsHover And $iIsHovered = 0 Then ; If the mouse isn't over the window from the last time we check it then do this ...
            $iIsHovered = 1
            WinSetOnTop($hWnd, "", 1) ; Set the window "ontop" state as 1.
            ConsoleWrite("OnTop >> " & $hWnd & @LF) ; For debugging only.
        ElseIf $iIsHover = 0 And $iIsHovered = 1 Then ; If the mouse isn't over the window anymore but it was in the last check then do this ...
            $iIsHovered = 0
            WinSetOnTop($hWnd, "", 0) ; Set the window "ontop" state as 0.
            ConsoleWrite("NOT OnTop >> " & $hWnd & @LF) ; For debugging only.
        EndIf

    WEnd
EndFunc   ;==>_Main

Func _MouseInBounds($iLeft = 0, $iTop = 0, $iWidth = 50, $iHeight = 50) ; By guinness 2012. Check if the mouse is in between a certain window.
    Local $aMouseGetPos = MouseGetPos()
    If @error Then
        Return SetError(@error, 0, 0)
    EndIf
    Return ($aMouseGetPos[0] >= $iLeft And $aMouseGetPos[0] <= $iLeft + $iWidth) And ($aMouseGetPos[1] >= $iTop And $aMouseGetPos[1] <= $iTop + $iHeight)
EndFunc   ;==>_MouseInBounds

Note: I added comments, I hope goldenix appreciates that

Edited January 3, 2012 by guinness

IanN1990 · January 3, 2012

I dont understand it -_^ the code i wrote was working and now it doesnt. Time to go find the bug

guinness · January 3, 2012

Perhaps when you copied the code you didn't copy it all. Anyway I provided a working example in post #6.

IanN1990 · January 3, 2012

Your code seams alot more reliable then what i wrote but the structure of the code would only support listed apps, whereas i need it to detect any application.

**Basically i have a GUI which dims the screen, and i was going to make it so if my mouse hovers over-something it Un-dims it "By setting it on top which is above the GUI"

guinness · January 3, 2012

OK, I thought you knew the window title/classname.

IanN1990 · January 4, 2012

is there any way we could edit ur example into working for any application ? As my code seams to be very unreliable

guinness · January 4, 2012

You could've done something like this too, again without the Windows API call.

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

HotKeySet("{ESC}", "_Exit")

Global $hWnd = -1, $hWndPrevious = -1

_Main()

Func _Main()
    While 1
        Sleep(100)

        $hWnd = WinGetHandle("[ACTIVE]")
        If @error Then
            ContinueLoop
        EndIf

        If $hWnd = $hWndPrevious Then
            ContinueLoop
        EndIf

        If $hWndPrevious <> -1 Then
            WinSetOnTop($hWndPrevious, "", 0) ; Set the window "ontop" state as 0.
        EndIf
        WinSetOnTop($hWnd, "", 1) ; Set the window "ontop" state as 1.
        $hWndPrevious = $hWnd
    WEnd
EndFunc   ;==>_Main

Func _Exit()
    WinSetOnTop($hWndPrevious, "", 0)
    WinSetOnTop($hWnd, "", 0)
    Exit
EndFunc   ;==>_Exit

IanN1990 · January 4, 2012

Very nice thanks for ur help

guinness · January 4, 2012

You're welcome.

UEZ · January 4, 2012

Here another mixed up version:

;coded by UEZ build 2012-01-05
#AutoIt3Wrapper_UseX64=n
;~ #AutoIt3Wrapper_Compile_both=y
#AutoIt3Wrapper_Run_Obfuscator=y
#Obfuscator_Parameters=/sf /sv /om /cs=0 /cn=0
#AutoIt3Wrapper_UseUpx=n
#AutoIt3Wrapper_Run_After=del /f /q "%scriptdir%%scriptfile%_Obfuscated.au3"
#AutoIt3Wrapper_Run_After=upx.exe --best --lzma "%out%"

#include <Constants.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>

Global $aHwnd, $mem, $topmost, $hWin, $hWinAncestor, $hWnd, $end = False
Global $tPoint = DllStructCreate("int X;int Y")
;~ Global $tPoint64 = DllStructCreate("int64", DllStructGetPtr($tPoint))
Global $delta_t = 1000
Global $oD = ObjCreate('Scripting.Dictionary')

GetAllVisibleWindow()

HotKeySet("{ESC}", "_SetExit")

Global $timer = TimerInit()
Do
    DllStructSetData ($tPoint, "X", MouseGetPos(0))
    DllStructSetData ($tPoint, "Y", MouseGetPos(1))
;~  If @AutoItX64 Then
;~      $aHwnd = DllCall("user32.dll", "hwnd", "WindowFromPoint", "int64", DllStructGetData($tPoint64, 1))
;~      $hWin = _WinAPI_WindowFromPoint($tPoint64)
;~  Else
        $aHwnd = DllCall("user32.dll", "hwnd", "WindowFromPoint", "uint", MouseGetPos(0), "uint", MouseGetPos(1))
        $hWin = _WinAPI_WindowFromPoint($tPoint)
;~  EndIf
    $hWinAncestor = _WinAPI_GetAncestor($hWin, 2)
    $hWnd = HWnd($hWinAncestor)
    If TimerDiff($timer) > $delta_t Then
        If $mem <> $hWnd Then
            GetAllVisibleWindow()
            WinActivate($hWnd, "")
            $mem = $hWnd
            $timer = TimerInit()
        EndIf
    EndIf
    If $end Then _Exit()
Until 0 * Sleep(25)

Func _Exit()
    Local $j, $hWnd
    Local $aKey = $oD.Keys ;hwnd
    Local $aItems = $oD.Items ;style
    For $j = 0 To UBound($aKey) - 1
        If $aItems[$j] Then
            $hWnd = HWnd($aKey[$j])
            WinActivate($hWnd, "")
            WinSetOnTop($hWnd, "", 1)
        EndIf
    Next
    $oD.RemoveAll
    $oD = 0
    Exit
EndFunc

Func _SetExit()
    $end = True
EndFunc

Func Add($key, $value)
    If $oD.Exists($key) Then Return 0
    $oD.Add($key, $value)
    Return 1
EndFunc

Func GetAllVisibleWindow()
    Local $aWin = WinList()
    Local $iStyle, $iEx_Style
    Local $i, $aWinPos

    For $i = 1 To $aWin[0][0]
        $iEx_Style = BitAND(_WinAPI_GetWindowLong($aWin[$i][1], $GWL_EXSTYLE), $WS_EX_TOOLWINDOW)
        $iStyle = BitAND(WinGetState($aWin[$i][1]), 2)
        If $iEx_Style <> -1 And Not $iEx_Style And $iStyle Then
            $aWinPos = WinGetPos($aWin[$i][1])
            If $aWinPos[2] > 1 And $aWinPos[3] > 1 Then
                Add(Int($aWin[$i][1]), BitAND(_WinAPI_GetWindowLong($aWin[$i][1], $GWL_EXSTYLE), $WS_EX_TOPMOST))
                WinSetOnTop($aWin[$i][1], "", 0)
            EndIf
        EndIf
    Next
EndFunc

Br,

UEZ

Edited January 6, 2012 by UEZ

Sign In

[Solved] Run function on Mouse Hover

Recommended Posts

IanN1990

guinness

IanN1990

goldenix

Melba23

guinness

IanN1990

guinness

IanN1990

guinness

IanN1990

guinness

IanN1990

guinness

UEZ

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members

Browse

AutoIt Resources

Release

Beta