Jump to content
Sign in to follow this  
GMK

[solved] _GUICtrlListView_DeleteAllItems

Recommended Posts

GMK

I don't understand why _GUICtrlListView_DeleteAllItems is not clearing all items from the ListView. Any ideas?

#NoTrayIcon

#region ;***** Includes *****
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <WinHttp.au3>
#include <StaticConstants.au3>
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#endregion ;***** Includes *****

#region ;***** GUI *****
Global $ZIPCodeGUI = GUICreate("ZIP Code Lookup", 448, 339, -1, -1)
Global $lblTitle = GUICtrlCreateLabel("ZIP Code Lookup", 137, 5, 206, 33, BitOR($SS_CENTER, $SS_CENTERIMAGE))
GUICtrlSetFont(-1, 18, 800, 0, "MS Sans Serif")
Global $lblRequired = GUICtrlCreateLabel("* Required Field", 50, 55, 79, 17, 0)
Global $lblAddr = GUICtrlCreateLabel("* Street Address", 49, 78, 80, 17, $SS_RIGHT)
Global $inpAddr = GUICtrlCreateInput("", 131, 75, 284, 21, $GUI_SS_DEFAULT_INPUT)
GUICtrlSetLimit(-1, 50)
Global $lblApt = GUICtrlCreateLabel("Apt / Suite / Other", 36, 102, 92, 17, $SS_RIGHT)
Global $inpApt = GUICtrlCreateInput("", 131, 100, 84, 21, $GUI_SS_DEFAULT_INPUT)
Global $lblCity = GUICtrlCreateLabel("* City", 100, 127, 28, 17, $SS_RIGHT)
Global $inpCity = GUICtrlCreateInput("", 131, 125, 284, 21, $GUI_SS_DEFAULT_INPUT)
GUICtrlSetLimit(-1, 50)
Global $lblState = GUICtrlCreateLabel("* State", 92, 152, 36, 17, $SS_RIGHT)
Global $cboState = GUICtrlCreateCombo("", 131, 150, 42, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "AL|AK|AS|AZ|AR|CA|CO|CT|DE|DC|FM|FL|GA|GU|HI|ID|IL|IN|IA|KS|KY|LA|ME|MH|MD|MA|MI|MN|MS|MO|MT|NE|NV|NH|NJ|NM|NY|NC|ND|MP|OH|OK|OR|PW|PA|PR|RI|SC|SD|TN|TX|UT|VT|VI|VA|WA|WV|WI|WY|AE|AA|AE|AP")
Global $lblZip5 = GUICtrlCreateLabel("ZIP Code", 79, 177, 49, 17, $SS_RIGHT)
Global $inpZIP5 = GUICtrlCreateInput("", 131, 175, 79, 21, $GUI_SS_DEFAULT_INPUT)
GUICtrlSetLimit(-1, 10)
Global $btnSubmit = GUICtrlCreateButton("Submit", 131, 202, 70, 17, $BS_NOTIFY)
Global $lvResults = GUICtrlCreateListView("Address 1|Address 2|City, State|ZIP Code", 5, 232, 460, 121, $GUI_SS_DEFAULT_LISTVIEW)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 104)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 104)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 2, 104)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 3, 104)
Global $btnClear = GUICtrlCreateButton("Clear Results", 216, 202, 75, 17)
GUISetState(@SW_SHOW)

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $btnSubmit
Search()
Case $btnClear
Clear()
EndSwitch
WEnd
#endregion ;***** GUI *****

#region ;**** Functions *****
Func Search()
SplashTextOn("ZIP Code Lookup", "SEARCHING...", 300, 200)
Local $sServer = "tools.usps.com" ; Address
Local $sPage = "/go/ZipLookupResultsAction!input.action" ; Page
$sAddr = StringLower(StringReplace(GUICtrlRead($inpAddr), " ", "+")) ;Get Address 1 string
$sApt = StringLower(StringReplace(GUICtrlRead($inpApt), " ", "+")) ;Get Apt string
$sCity = StringLower(StringReplace(GUICtrlRead($inpCity), " ", "+")) ;Get City string
$sState = StringUpper(GUICtrlRead($cboState)) ;Get State string
$sZIP5 = GUICtrlRead($inpZIP5) ;Get ZIP Code string
Local $sRequest = "resultMode=0&companyName=&address1=" & $sAddr & "&address2=" & $sApt & "&city=" & $sCity & "&state=" & $sState & "&urbanCode=&postalCode=&zip=" & $sZIP5 ; Request
Local $hOpen = _WinHttpOpen() ; Initialize and get session handle
Local $hConnect = _WinHttpConnect($hOpen, $sServer, $INTERNET_DEFAULT_HTTPS_PORT) ; Get connection handle
Local $sData = _WinHttpSimpleSSLRequest($hConnect, "POST", $sPage, Default, $sRequest)
_WinHttpCloseHandle($hConnect)
_WinHttpCloseHandle($hOpen)
$sData = StringStripWS($sData, 7)
Local $aTable = ""
Local $aSRE = StringRegExp($sData, '<p class="std-address">(.*?)</p>', 3)
If UBound($aSRE) > 1 Then
For $iRow = 1 To UBound($aSRE) - 1
If Not IsArray($aTable) Then Local $aTable[UBound($aSRE) - 1][4]
$aTable[$iRow - 1][0] = StringRegExpReplace($aSRE[$iRow], '.*<span class="address1 range">(.*?)</span>.*', '$1')
If StringRegExp($aSRE[$iRow], '<span class="address2 range">(.*?)</span>.*') Then $aTable[$iRow - 1][1] = StringRegExpReplace($aSRE[$iRow], '.*<span class="address2 range">(.*?)</span>.*', '$1')
$aTable[$iRow - 1][2] = StringRegExpReplace($aSRE[$iRow], '.*<span class="city range">(.*?)</span> <span class="state range">(.*?)</span>.*', '$1 $2')
$aTable[$iRow - 1][3] = StringRegExpReplace($aSRE[$iRow], '.*<span class="zip" style="">(.*?)</span><span class="hyphen">&#45;</span><span class="zip4">(.*?)</span>.*', '$1-$2')
Next
EndIf
SplashOff()
_GUICtrlListView_AddArray($lvResults, $aTable)
_GUICtrlListView_SetColumnWidth($lvResults, 0, $LVSCW_AUTOSIZE)
_GUICtrlListView_SetColumnWidth($lvResults, 1, $LVSCW_AUTOSIZE)
_GUICtrlListView_SetColumnWidth($lvResults, 2, $LVSCW_AUTOSIZE)
_GUICtrlListView_SetColumnWidth($lvResults, 3, $LVSCW_AUTOSIZE)
EndFunc ;==>Search

Func Clear()
_GUICtrlListView_DeleteAllItems($lvResults)
EndFunc ;==>Clear
#endregion ;**** Functions *****

Edit:

_GUICtrlListView_DeleteAllItems(GUICtrlGetHandle($lvResults))
Edited by GMK

Share this post


Link to post
Share on other sites
Melba23

GMK,

You are creating the ListView using the native function while adding the items using a UDF function. Mixing the two when in this manner always ends in tears. :(

Either create the ListView using the UDF function (_GUICtrlListView_Create) - or add the items using the native function (GUICtrlCreateListViewItem) - and you will find that you can delete the items. ;)

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites
Melba23

GMK,

If you look inside the UDF you can see why you need the handle. When you use the handle, the function sends the $LVM_DELETEALLITEMS message to the ListView - when you use the ControlID, it assumes you have created the items with the native function and deletes the items using GUICtrlDelete to free up space in the array AutoIt maintains internally. As you had not created the items with the native function that did not work. ;)

As I mentioned, mixing native and UDF functions to create a ListView (nearly!) always ends in tears - best to stick to one or the other method. :)

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites
GMK

Ah, ok. Thanks for clearing that up!

Edit: Just to point out--the help file for _GUICtrlListView_DeleteAllItems (Example 2) mixes native with UDF and that's how I found my mistake.

Edited by GMK

Share this post


Link to post
Share on other sites
guinness

The function should retrieve the handle if using a native function and the controlid is passed. I will check the UDF later on today.


UDF List:

 
_AdapterConnections()_AlwaysRun()_AppMon()_AppMonEx()_ArrayFilter/_ArrayReduce_BinaryBin()_CheckMsgBox()_CmdLineRaw()_ContextMenu()_ConvertLHWebColor()/_ConvertSHWebColor()_DesktopDimensions()_DisplayPassword()_DotNet_Load()/_DotNet_Unload()_Fibonacci()_FileCompare()_FileCompareContents()_FileNameByHandle()_FilePrefix/SRE()_FindInFile()_GetBackgroundColor()/_SetBackgroundColor()_GetConrolID()_GetCtrlClass()_GetDirectoryFormat()_GetDriveMediaType()_GetFilename()/_GetFilenameExt()_GetHardwareID()_GetIP()_GetIP_Country()_GetOSLanguage()_GetSavedSource()_GetStringSize()_GetSystemPaths()_GetURLImage()_GIFImage()_GoogleWeather()_GUICtrlCreateGroup()_GUICtrlListBox_CreateArray()_GUICtrlListView_CreateArray()_GUICtrlListView_SaveCSV()_GUICtrlListView_SaveHTML()_GUICtrlListView_SaveTxt()_GUICtrlListView_SaveXML()_GUICtrlMenu_Recent()_GUICtrlMenu_SetItemImage()_GUICtrlTreeView_CreateArray()_GUIDisable()_GUIImageList_SetIconFromHandle()_GUIRegisterMsg()_GUISetIcon()_Icon_Clear()/_Icon_Set()_IdleTime()_InetGet()_InetGetGUI()_InetGetProgress()_IPDetails()_IsFileOlder()_IsGUID()_IsHex()_IsPalindrome()_IsRegKey()_IsStringRegExp()_IsSystemDrive()_IsUPX()_IsValidType()_IsWebColor()_Language()_Log()_MicrosoftInternetConnectivity()_MSDNDataType()_PathFull/GetRelative/Split()_PathSplitEx()_PrintFromArray()_ProgressSetMarquee()_ReDim()_RockPaperScissors()/_RockPaperScissorsLizardSpock()_ScrollingCredits_SelfDelete()_SelfRename()_SelfUpdate()_SendTo()_ShellAll()_ShellFile()_ShellFolder()_SingletonHWID()_SingletonPID()_Startup()_StringCompact()_StringIsValid()_StringRegExpMetaCharacters()_StringReplaceWholeWord()_StringStripChars()_Temperature()_TrialPeriod()_UKToUSDate()/_USToUKDate()_WinAPI_Create_CTL_CODE()_WinAPI_CreateGUID()_WMIDateStringToDate()/_DateToWMIDateString()Au3 script parsingAutoIt SearchAutoIt3 PortableAutoIt3WrapperToPragmaAutoItWinGetTitle()/AutoItWinSetTitle()CodingDirToHTML5FileInstallrFileReadLastChars()GeoIP databaseGUI - Only Close ButtonGUI ExamplesGUICtrlDeleteImage()GUICtrlGetBkColor()GUICtrlGetStyle()GUIEventsGUIGetBkColor()Int_Parse() & Int_TryParse()IsISBN()LockFile()Mapping CtrlIDsOOP in AutoItParseHeadersToSciTE()PasswordValidPasteBinPosts Per DayPreExpandProtect GlobalsQueue()Resource UpdateResourcesExSciTE JumpSettings INISHELLHOOKShunting-YardSignature CreatorStack()Stopwatch()StringAddLF()/StringStripLF()StringEOLToCRLF()VSCROLLWM_COPYDATAMore Examples...

Updated: 22/04/2018

Share this post


Link to post
Share on other sites
Melba23

guinness,

This is the function:

Func _GUICtrlListView_DeleteAllItems($hWnd)
    If $Debug_LV Then __UDF_ValidateClassName($hWnd, $__LISTVIEWCONSTANT_ClassName)

    If _GUICtrlListView_GetItemCount($hWnd) == 0 Then Return True
    If IsHWnd($hWnd) Then
        Return _SendMessage($hWnd, $LVM_DELETEALLITEMS) <> 0
    Else
        Local $ctrlID
        For $index = _GUICtrlListView_GetItemCount($hWnd) - 1 To 0 Step -1
            $ctrlID = _GUICtrlListView_GetItemParam($hWnd, $index)
            If $ctrlID Then GUICtrlDelete($ctrlID)
        Next
        If _GUICtrlListView_GetItemCount($hWnd) == 0 Then Return True
    EndIf
    Return False
EndFunc   ;==>_GUICtrlListView_DeleteAllItems

As you can see, it assumes that the items are created in the same manner as the ListView itself. :(

Perhaps it could be rewritten as shown in this example to make sure that it covers the native ListView with UDF items as well:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>

$hGUI = GUICreate("Test", 500, 500)
GUISetBkColor(0xC4C4C4)

$cLV_1 = GUICtrlCreateListView("Col 1|Col 2|Col 3|Col 4", 10, 10, 400, 150)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 100)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 100)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 2, 100)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 3, 100)
For $i = 0 To 3
    GUICtrlCreateListViewItem("Item " & $i & "1|Item " & $i & "2|Item " & $i & "3|Item " & $i & "4", $cLV_1)
Next

$cLV_2 = GUICtrlCreateListView("Col 1|Col 2|Col 3|Col 4", 10, 170, 400, 150)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 0, 100)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 1, 100)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 2, 100)
GUICtrlSendMsg(-1, $LVM_SETCOLUMNWIDTH, 3, 100)
Local $aTable[4][4] = [[1, 2, 3, 4],[2, 3, 4, 5],[3, 4, 5, 6],[4, 5, 6, 7]]
_GUICtrlListView_AddArray($cLV_2, $aTable)

$hLV_3 = _GUICtrlListView_Create($hGUI, "", 10, 330, 400, 150)
_GUICtrlListView_SetExtendedListViewStyle($hLV_3, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
_GUICtrlListView_InsertColumn($hLV_3, 0, "Col 1", 100)
_GUICtrlListView_InsertColumn($hLV_3, 1, "Col 2", 100)
_GUICtrlListView_InsertColumn($hLV_3, 2, "Col 3", 100)
_GUICtrlListView_InsertColumn($hLV_3, 3, "Col 4", 100)
Local $aTable[4][4] = [[1, 2, 3, 4],[2, 3, 4, 5],[3, 4, 5, 6],[4, 5, 6, 7]]
_GUICtrlListView_AddArray($hLV_3, $aTable)

$cButton_1 = GUICtrlCreateButton("Delete All 1", 420, 70, 80, 30)
$cButton_2 = GUICtrlCreateButton("Delete All 2", 420, 230, 80, 30)
$cButton_3 = GUICtrlCreateButton("Delete All 3", 420, 390, 80, 30)

GUISetState()


While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton_1
            _New_GUICtrlListView_DeleteAllItems($cLV_1)
        Case $cButton_2
            _New_GUICtrlListView_DeleteAllItems($cLV_2)
        Case $cButton_3
            _New_GUICtrlListView_DeleteAllItems($hLV_3)
    EndSwitch

WEnd

Func _New_GUICtrlListView_DeleteAllItems($hWnd)
    If $Debug_LV Then __UDF_ValidateClassName($hWnd, $__LISTVIEWCONSTANT_ClassName)

    If _GUICtrlListView_GetItemCount($hWnd) == 0 Then Return True
    ; If a ControlID is passed
    If Not IsHWnd($hWnd) Then
        Local $ctrlID
        ; Delete and remove the items from AutoIt internal array if cretaed with native function
        For $index = _GUICtrlListView_GetItemCount($hWnd) - 1 To 0 Step -1
            $ctrlID = _GUICtrlListView_GetItemParam($hWnd, $index)
            If $ctrlID Then GUICtrlDelete($ctrlID)
        Next
        ; If all removed then they were created with native function so return
        If _GUICtrlListView_GetItemCount($hWnd) = 0 Then Return True
        ; Must have been created with UDF function so convert ControlID to handle
        $hWnd = GUICtrlGetHandle($hWnd)
    EndIf
    ; And remove UDF created items - which also works for UDF ListViews
    Return _SendMessage($hWnd, $LVM_DELETEALLITEMS) <> 0
    Return False
EndFunc   ;==>_GUICtrlListView_DeleteAllItems

Happy to discuss further via PM if you would like. :)

M23


Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind._______My UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Share this post


Link to post
Share on other sites
guinness

Happy to discuss further via PM if you would like. :)

I will PM you this afternoon. I see the problem.

UDF List:

 
_AdapterConnections()_AlwaysRun()_AppMon()_AppMonEx()_ArrayFilter/_ArrayReduce_BinaryBin()_CheckMsgBox()_CmdLineRaw()_ContextMenu()_ConvertLHWebColor()/_ConvertSHWebColor()_DesktopDimensions()_DisplayPassword()_DotNet_Load()/_DotNet_Unload()_Fibonacci()_FileCompare()_FileCompareContents()_FileNameByHandle()_FilePrefix/SRE()_FindInFile()_GetBackgroundColor()/_SetBackgroundColor()_GetConrolID()_GetCtrlClass()_GetDirectoryFormat()_GetDriveMediaType()_GetFilename()/_GetFilenameExt()_GetHardwareID()_GetIP()_GetIP_Country()_GetOSLanguage()_GetSavedSource()_GetStringSize()_GetSystemPaths()_GetURLImage()_GIFImage()_GoogleWeather()_GUICtrlCreateGroup()_GUICtrlListBox_CreateArray()_GUICtrlListView_CreateArray()_GUICtrlListView_SaveCSV()_GUICtrlListView_SaveHTML()_GUICtrlListView_SaveTxt()_GUICtrlListView_SaveXML()_GUICtrlMenu_Recent()_GUICtrlMenu_SetItemImage()_GUICtrlTreeView_CreateArray()_GUIDisable()_GUIImageList_SetIconFromHandle()_GUIRegisterMsg()_GUISetIcon()_Icon_Clear()/_Icon_Set()_IdleTime()_InetGet()_InetGetGUI()_InetGetProgress()_IPDetails()_IsFileOlder()_IsGUID()_IsHex()_IsPalindrome()_IsRegKey()_IsStringRegExp()_IsSystemDrive()_IsUPX()_IsValidType()_IsWebColor()_Language()_Log()_MicrosoftInternetConnectivity()_MSDNDataType()_PathFull/GetRelative/Split()_PathSplitEx()_PrintFromArray()_ProgressSetMarquee()_ReDim()_RockPaperScissors()/_RockPaperScissorsLizardSpock()_ScrollingCredits_SelfDelete()_SelfRename()_SelfUpdate()_SendTo()_ShellAll()_ShellFile()_ShellFolder()_SingletonHWID()_SingletonPID()_Startup()_StringCompact()_StringIsValid()_StringRegExpMetaCharacters()_StringReplaceWholeWord()_StringStripChars()_Temperature()_TrialPeriod()_UKToUSDate()/_USToUKDate()_WinAPI_Create_CTL_CODE()_WinAPI_CreateGUID()_WMIDateStringToDate()/_DateToWMIDateString()Au3 script parsingAutoIt SearchAutoIt3 PortableAutoIt3WrapperToPragmaAutoItWinGetTitle()/AutoItWinSetTitle()CodingDirToHTML5FileInstallrFileReadLastChars()GeoIP databaseGUI - Only Close ButtonGUI ExamplesGUICtrlDeleteImage()GUICtrlGetBkColor()GUICtrlGetStyle()GUIEventsGUIGetBkColor()Int_Parse() & Int_TryParse()IsISBN()LockFile()Mapping CtrlIDsOOP in AutoItParseHeadersToSciTE()PasswordValidPasteBinPosts Per DayPreExpandProtect GlobalsQueue()Resource UpdateResourcesExSciTE JumpSettings INISHELLHOOKShunting-YardSignature CreatorStack()Stopwatch()StringAddLF()/StringStripLF()StringEOLToCRLF()VSCROLLWM_COPYDATAMore Examples...

Updated: 22/04/2018

Share this post


Link to post
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
Sign in to follow this  

  • Similar Content

    • nacerbaaziz
      By nacerbaaziz
      Hello my friends
      I have an inquiry and I hope to find the answer here
      I want to create a graphical user interface
      but I want to hide the system menu
      I mean the window menu
      Is this possible?
      If is possible please give me how to do that
      Thanks in advance
    • helmar
      By helmar
      I was playing around with simple GUI creation.  I tend to like parameter driven coding (in prior life (years ago) as Clipper/FoxPro/dBase coder).  Just wanted to see what I could do with a GUI.
      #Region options, includes Opt('MustDeclareVars', 1) Opt("GUIOnEventMode", 1) ; Change to OnEvent mode #include <GUIConstantsEx.au3> #EndRegion options, includes Global Const $nCols = 2, $nRows = 6, $nSpacer = 10, $nBtnWidth = 150, $nBtnHeight = 30 Global $xName = 0, $xID = 0 Global $nGUIWidth = ($nCols * $nBtnWidth) + (($nCols + 1) * $nSpacer) Global $nGUIHeight = ($nRows * $nBtnHeight) + (($nRows + 1) * $nSpacer) Global $hMainGUI = GUICreate("Calculated GUI", $nGUIWidth, $nGUIHeight, -1, -1) For $xRows = 1 to $nRows ;in this arrangement, tabbing is left to right, then next row For $xCols = 1 to $nCols ;reverse the order of this line with the prior line for top to bottom tabbing, then next col $xName += 1 $xID += 1 Global $Dummy = GUICtrlCreateButton("Button" & $xName, _ ($nBtnWidth * ($xCols - 1)) + (($xCols - 1) * $nSpacer) + $nSpacer, _ ($nBtnHeight* ($xRows - 1)) + (($xRows - 1) * $nSpacer) + $nSpacer, _ $nBtnWidth, _ $nBtnHeight) GUICtrlSetOnEvent($xID+2, "Handler") Next Next GUISetOnEvent($GUI_EVENT_CLOSE, "CloseApp") GUISetState(@SW_SHOW) While 1 Sleep(10) WEnd Func CloseApp() Exit EndFunc Func Handler() MsgBox(0,0,"Button " & @GUI_CtrlId - 2) EndFunc  
    • XinYoung
      By XinYoung
      For fun, I'm building an app that opens a webpage and refreshes it every 30 seconds.
      But once the script performs _IEAction($oIE, "refresh"), the GUI closes.
      Any help is appreciated.
       

      #include <ButtonConstants.au3>
      #include <EditConstants.au3>
      #include <GUIConstantsEx.au3>
      #include <StaticConstants.au3>
      #include <WindowsConstants.au3>
      #include <WinAPIFiles.au3>
      #include <Array.au3>
      #include <File.au3>
      #include <Excel.au3>
      #include <DateTimeConstants.au3>
      #include <MsgBoxConstants.au3>
      #include <WinAPIShellEx.au3>
      #include <MsgBoxConstants.au3>
      #include <Date.au3>
      #include <ComboConstants.au3>
      #include <guimenu.au3>
      #include <IE.au3>
      HotKeySet("{F4}", "_Exit")
      ;Open the file(s) in the selected folder
      $extension = ".txt"
      $app2openWith = @SystemDir & "\notepad.exe"
      Func Begin()
          Global $loopTrick = 0
          #Region ### START Koda GUI section ### Form=c:\users\mchu\downloads\autoit\my code\form1.kxf
          Global $UI = GUICreate("Hit Em Up!", 256, 113, -1, -1)
          GUISetBkColor(0x000000)
          $menu = _GUICtrlMenu_GetSystemMenu($UI)
          _GUICtrlMenu_EnableMenuItem($menu, $SC_CLOSE, 1, False)
          Global $url = GUICtrlCreateInput("https://www.youtube.com/watch?v=dQw4w9WgXcQ", 81, 8, 160, 21)
          $Label1 = GUICtrlCreateLabel("Target:", 16, 8, 55, 17)
          GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
          GUICtrlSetColor(-1, 0x00FF00)
          Global $StartBut = GUICtrlCreateButton("Start", 16, 40, 67, 25)
          GUICtrlSetFont(-1, 13, 800, 0, "MS Sans Serif")
          GUICtrlSetBkColor(-1, 0x008000)
          $Label2 = GUICtrlCreateLabel("(Press F4 to Exit)", 96, 40, 8000, 17)
          GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
          GUICtrlSetColor(-1, 0x00FF00)
          GUISetState(@SW_SHOW)
          #EndRegion ### END Koda GUI section ###
          While 1
              $UIfunc = GUIGetMsg()
              Select
                  Case $UIfunc = $GUI_EVENT_CLOSE
                      _Exit()
                  Case $UIfunc = $StartBut
                      If GUICtrlRead($url) = "" Then
                          MsgBox(48, "Um...", "Give me a target you idiot.")
                      Else
                          GUICtrlSetState($url, $GUI_DISABLE)
                          GUICtrlSetState($StartBut, $GUI_DISABLE)
                          Start()
                      EndIf
              EndSelect
          WEnd
      EndFunc   ;==>Begin
      Func Start()
          If $loopTrick = 0 Then
              Global $oIE = _IECreate(GUICtrlRead($url))
              _IELoadWait($oIE)
              Again()
          ElseIf $loopTrick = 1 Then
              Sleep(3000)
              _IEAction($oIE, "refresh")
              Sleep(3000)
              Start()
          EndIf
      EndFunc   ;==>Start
      Func Again()
          $loopTrick = 1
          Start()
      EndFunc   ;==>Again
      Func _Exit()
          Exit
      EndFunc   ;==>_Exit
    • Skysnake
      By Skysnake
      I am tracking this topic by @LarsJ.  It is very advanced and overkill for what I am currently trying to do.
       
      Problem is this.
      Listview contains columns, one of which is right aligned and gets populated by float values, such as 123.99.  Some do not have decimals ie 124.00 and on sort gets truncated to 124.  Its obviously still the same value, but the display has reset.
      ; line below is for list VIEW ;..................................0.........1......2............ $cListView = GUICtrlCreateListView("CUSTOMER|AMOUNT|DESCRIPTION", 8, 152, 764, 279) GUICtrlSetBkColor($cListView, $GUI_BKCOLOR_LV_ALTERNATE) ; alternate between the listview background color and the listview item background color GUICtrlSetBkColor($cListView, $LVStdClr) ; Set the background color for the listview _GUICtrlListView_SetColumnWidth($cListView, 0, 120) ; -- the client name _GUICtrlListView_SetColumnWidth($cListView, 1, 90) ;-- the amount _GUICtrlListView_JustifyColumn($cListView, 1, 1) ; 1 - Text is right aligned _GUICtrlListView_SetColumnWidth($cListView, 2, 200) ; the description What I am looking for is something native and simple like a 
          _GUICtrlListView_SetColumnFormat($cListView, 1, "%.2f") ;  1 - column is stringformatted to "%.2f"
      So that after each sort it will appear as it was in the original rendering.
      Is there something like this? I have not been able to find a simple solution.

      Thanks.
      Skysnake
    • kcvinu
      By kcvinu
      Hi all,
      I have a button created with _GUICtrlButton_Create function. I know that this function returns a handle of button instead of an ID. So i have obtain control ID by calling _WinAPI_GetDlgCtrlID function. After that i have tried the GUICtrlSetBkColor function. But it didnt worked. Any suggestions will be appreciated. Thanks in advance. 
      Note : - The window which carries this button is not created with native gui create function. Instead, it is created with CreateWindowEx api function.
×

Important Information

We have placed cookies on your device to help make this website better. You can adjust your cookie settings, otherwise we'll assume you're okay to continue.