[SOLVED] Change Z-ordering of controls

[jmon 11]

Hello,

I am trying to change the z-ordering of controls in my GUI using GUICtrlSetState. How come this example don't work? (I want $LABEL1 to be above $LABEL2)

#include <GUIConstantsEx.au3>

$GUI = GUICreate("Test", 800, 600)
GUISetState()

$LABEL1 = GUICtrlCreateLabel("under", 20, 20, 500, 300)
GUICtrlSetBkColor(-1, 0xFF0000)
$LABEL2 = GUICtrlCreateLabel("above", 40, 60, 500, 300)
GUICtrlSetBkColor(-1, 0x00FF00)

GUICtrlSetState($LABEL1, $GUI_ONTOP)

Do
Sleep(50)
Until GUIGetMsg() = -3
Exit

Is there another method to change the z ordering and the order controls receive clicks? I know that the controls should be created in the correct order, but I can't in the script I am doing now.

Thanks

[EDIT] Solution is in post #5

Edited November 29, 2012 by jmon

[jmon 11]

So I tested other options, and this one doesn't work either:

#include <GUIConstantsEx.au3>
#include <WinAPIEx.au3>

$GUI = GUICreate("Test", 800, 600)
GUISetState()

$LABEL1 = GUICtrlCreateLabel("under", 20, 20, 500, 300)
GUICtrlSetBkColor(-1, 0xFF0000)
$LABEL2 = GUICtrlCreateLabel("above", 40, 60, 500, 300)
GUICtrlSetBkColor(-1, 0x00FF00)

_WinAPI_BringWindowToTop(GUICtrlGetHandle($LABEL1))

Do
Sleep(50)
Until GUIGetMsg() = -3
Exit

[EDIT]

This one doesn't seems to work either

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <APIConstants.au3>

$GUI = GUICreate("Test", 800, 600)
GUISetState()

$LABEL1 = GUICtrlCreateLabel("under", 20, 20, 500, 300)
GUICtrlSetBkColor(-1, 0xFF0000)
$LABEL2 = GUICtrlCreateLabel("above", 40, 60, 500, 300)
GUICtrlSetBkColor(-1, 0x00FF00)

$aPos = ControlGetPos(GUICtrlGetHandle($LABEL1), "", 0)
_WinAPI_SetWindowPos(GUICtrlGetHandle($LABEL1), $HWND_TOP, $aPos[0], $aPos[1], $aPos[2], $aPos[3], $SWP_NOMOVE)

Do
Sleep(50)
Until GUIGetMsg() = -3
Exit

[EDIT] Actually it works but with these parameters:

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <APIConstants.au3>

$GUI = GUICreate("Test", 800, 600)
GUISetState()

$LABEL1 = GUICtrlCreateLabel("under", 20, 20, 500, 300)
GUICtrlSetBkColor(-1, 0xFF0000)
$LABEL2 = GUICtrlCreateLabel("above", 40, 60, 500, 300)
GUICtrlSetBkColor(-1, 0x00FF00)

$aPos = ControlGetPos(GUICtrlGetHandle($LABEL1), "", 0)
_WinAPI_SetWindowPos(GUICtrlGetHandle($LABEL1), GUICtrlGetHandle($LABEL2), $aPos[0, $aPos[1], $aPos[2], $aPos[3], $SWP_NOCOPYBITS)

Do
Sleep(50)
Until GUIGetMsg() = -3
Exit

Now, even if this works, I'm still looking for a method that wouldn't move the control and that wouldn't need to tell which control to draw over.

Edited November 29, 2012 by jmon

[czardas 1,285]

It's possible Microsoft changed how the z-Index can be alterred (I may have read something like that - though I'm not entirely sure). Even if this is not the case, it does not automatically follow that the GUI controls will be automatically repainted (once again - I don't know). I do think that overlapping controls is generally best avoided. Depending on what you want to achieve, there may be a work around or an alternative method. You can always destroy your controls and create them again in reverse order.

Edited November 29, 2012 by czardas

[jmon 11]

@czardas : thank you for the information

I actually found the solution:

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <APIConstants.au3>

$GUI = GUICreate("Test", 800, 600)
GUISetState()

$LABEL1 = GUICtrlCreateLabel("under", 20, 20, 500, 300)
GUICtrlSetBkColor(-1, 0xFF0000)
$LABEL2 = GUICtrlCreateLabel("above", 40, 60, 500, 300)
GUICtrlSetBkColor(-1, 0x00FF00)

GuiCtrlSetOnTop($LABEL1)

Do
    Sleep(50)
Until GUIGetMsg() = -3
Exit

Func GuiCtrlSetOnTop($iCtrlID)
    ;Need to include <WinAPI.au3> and <APIConstants.au3>
    Local $hWnd = $iCtrlID
    If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($iCtrlID)
    Return _WinAPI_SetWindowPos($hWnd, $HWND_BOTTOM, 0, 0, 0, 0, $SWP_NOMOVE + $SWP_NOSIZE + $SWP_NOCOPYBITS)
EndFunc

This method doesn't require to tell the position or the control to be drawn ontop. I made a quick snippet that you can include in your scripts.

Edited November 29, 2012 by jmon

[czardas 1,285]

I actually need to check the information I posted above. I'm glad you managed to find a solution anyway.

[jmon 11]

Thanks.

I posted a snippet and for more information about SetWindowPos, check out MSDN. Maybe I should add some other flags?

[jmon 11]

So even though I found an answer to my question, I was wondering what was

GUICtrlSetState($LABEL1, $GUI_ONTOP)

supposed to do? What is this constant for is it's not to set a control on top?

[guinness 1,536]

So even though I found an answer to my question, I was wondering what was

GUICtrlSetState($LABEL1, $GUI_ONTOP)

supposed to do? What is this constant for is it's not to set a control on top?

Hmm, strange. Perhaps this is a bug?

[jmon 11]

Hmm, strange. Perhaps this is a bug?

Yes it looks like it. I haven't found any use for this constant...

[guinness 1,536]

If this is the case then report to Trac.

[jmon 11]

Ok, Done